configure.ac

   1 dnl  AUTOCONF configuration for CLN
   2 dnl
   3 dnl  configure.ac ---<autoconf>--->> configure
   4 dnl
   5 dnl  configure    ---<sh>--->> config.status
   6 dnl                      --->> include/cln/config.h
   7 dnl        cln-config.in --->> cln-config
   8 dnl          Makefile.in --->> Makefile
   9 dnl      src/Makefile.in --->> src/Makefile
  10 dnl
  11 dnl  Makefile   ---<make>--->> libcln.a
  12 dnl
  13 dnl
  14 AC_INIT(src/integer/gcd/cl_I_gcd.cc)
  15 AC_CONFIG_AUX_DIR(autoconf)
  16 AC_CONFIG_HEADER(include/cln/config.h include/cln/version.h src/base/cl_base_config.h src/base/cl_gmpconfig.h src/float/cl_float_config.h src/timing/cl_t_config.h)
  17 AC_PROG_MAKE_SET
  18 dnl This piece of sed script replaces every line containing '@subdir@'
  19 dnl by several consecutive lines, each referencing one subdir.
  20 extrasub="$extrasub"'
  21 /@subdir@/{
  22 h
  23 g
  24 s/@subdir@/src/
  25 p
  26 g
  27 s/@subdir@/tests/
  28 p
  29 g
  30 s/@subdir@/benchmarks/
  31 p
  32 g
  33 s/@subdir@/examples/
  34 p
  35 g
  36 s/@subdir@/doc/
  37 p
  38 d
  39 }
  40 '
  41 dnl
  42 dnl           checks for programs
  43 dnl
  44 AC_PROG_CC
  45                       dnl sets variable CC
  46 AC_PROG_CPP
  47                       dnl sets variable CPP
  48 AC_PROG_CXX
  49                       dnl sets variable CXX
  50 AC_PROG_CXXCPP
  51                       dnl sets variable CXXCPP
  52 CL_AS_UNDERSCORE
  53                       dnl sets variable AS_UNDERSCORE, DEFS ASM_UNDERSCORE
  54 CL_PROG_RANLIB
  55                       dnl sets variable RANLIB
  56 CL_PROG_INSTALL
  57                       dnl sets variables INSTALL, INSTALL_DATA, INSTALL_PROGRAM
  58 dnl
  59 dnl           check for host type
  60 dnl
  61 CL_CANONICAL_HOST(autoconf)
  62                       dnl sets variables host, host_cpu, host_vendor, host_os
  63 CL_CANONICAL_HOST_CPU
  64                       dnl DEFS __${host_cpu}__
  65 dnl
  66 dnl           check for build configuration
  67 dnl
  68                       dnl libcln depends on libm
  69 PACKAGE=cln
  70                       dnl libtool wants PACKAGE
  71 AC_PROG_LIBTOOL
  72                       dnl sets variable LIBTOOL
  73
  74 dnl Libtool's library version information for CLN.
  75 dnl (Not to be confused with CLN's release version.)
  76 dnl Making new releases:
  77 dnl * increment CL_REVISION,
  78 dnl * if any functions/classes have been added, removed or changed, increment
  79 dnl   CL_CURRENT and set CL_REVISION to 0,
  80 dnl * if any functions/classes have been added, increment CL_AGE,
  81 dnl * if backwards compatibility has been broken, set CL_AGE to 0.
  82 CL_CURRENT=2
  83 CL_REVISION=3
  84 CL_AGE=0
  85 dnl make substitutions
  86 AC_SUBST(CL_CURRENT)
  87 AC_SUBST(CL_REVISION)
  88 AC_SUBST(CL_AGE)
  89 dnl release version
  90 CL_VERSION_MAJOR=1
  91 CL_VERSION_MINOR=1
  92 CL_VERSION_PATCHLEVEL=4
  93 dnl release version for cln/config.h, so it can be tested by the preprocessor
  94 AC_DEFINE_UNQUOTED(CL_VERSION_MAJOR, $CL_VERSION_MAJOR)
  95 AC_DEFINE_UNQUOTED(CL_VERSION_MINOR, $CL_VERSION_MINOR)
  96 AC_DEFINE_UNQUOTED(CL_VERSION_PATCHLEVEL, $CL_VERSION_PATCHLEVEL)
  97 dnl concatenated release version
  98 CL_VERSION=$CL_VERSION_MAJOR.$CL_VERSION_MINOR.$CL_VERSION_PATCHLEVEL
  99 AC_DEFINE_UNQUOTED(CL_VERSION, $CL_VERSION)
 100 AC_SUBST(CL_VERSION)
 101
 102 dnl
 103 dnl           checks for compiler characteristics
 104 dnl
 105 AC_LANG_CPLUSPLUS
 106 dnl
 107 CL_BOOL
 108                       dnl DEFS HAVE_BOOL, bool
 109 CL_LONGLONG
 110                       dnl DEFS HAVE_LONGLONG
 111 CL_LONGDOUBLE
 112                       dnl DEFS HAVE_LONGDOUBLE
 113 CL_TEMPLATE_NULL
 114                       dnl DEFS HAVE_TEMPLATE_NULL
 115 CL_GLOBAL_CONSTRUCTORS
 116                       dnl DEFS CL_GLOBAL_CONSTRUCTOR_PREFIX, CL_GLOBAL_DESTRUCTOR_PREFIX
 117 dnl
 118 dnl           checks for header files
 119 dnl
 120 CL_UNISTD_H
 121                       dnl DEFS HAVE_UNISTD_H if exist unistd.h
 122 dnl
 123 dnl           checks for typedefs
 124 dnl
 125 dnl
 126 dnl           checks for functions and declarations
 127 dnl
 128 CL_ALLOCA
 129                       dnl set variable ALLOCA, DEFS NO_ALLOCA
 130 CL_FPU_CONTROL
 131                       dnl DEFS HAVE_FPU_CONTROL_T, HAVE_SETFPUCW
 132 CL_GETTIMEOFDAY
 133                       dnl DEFS HAVE_GETTIMEOFDAY, GETTIMEOFDAY_DOTS, GETTIMEOFDAY_TZP_T
 134 CL_FTIME
 135                       dnl DEFS HAVE_FTIME
 136 CL_TIMES_CLOCK
 137                       dnl DEFS HAVE_TIMES_CLOCK
 138 CL_RUSAGE
 139                       dnl DEFS HAVE_SYS_RESOURCE_H, HAVE_GETRUSAGE, HAVE_SYS_TIMES_H
 140 CL_PERROR
 141                       dnl DEFS HAVE_PERROR_DECL
 142 dnl
 143 dnl           checks for compiler characteristics
 144 dnl
 145 CL_CHAR_UNSIGNED
 146                       dnl DEFS __CHAR_UNSIGNED__ if char is unsigned
 147 test -d 'include/cln' || mkdir -p 'include/cln'
 148 CL_MACHINE([integer types and behaviour],${srcdir}/autoconf/intparam.c,include/cln/intparam.h,cl_cv_file_intparam_h)
 149                       dnl builds include/cln/intparam.h
 150 CL_MACHINE([floating-point types and behaviour],${srcdir}/autoconf/floatparam.c,include/cln/floatparam.h,cl_cv_file_floatparam_h)
 151                       dnl builds include/cln/floatparam.h
 152 dnl
 153 dnl           interfacing to GNU gmp (must be at least version 3)
 154 dnl
 155 AC_ARG_WITH(gmp, [  --with-gmp              use external fast low-level functions from GNU MP 3.
 156                           [default=yes]], ,with_gmp="yes")
 157 if test "$with_gmp" = yes; then
 158   CL_GMP_H_VERSION
 159   if test "$cl_cv_new_gmp_h" = no; then with_gmp="no"; fi
 160   if test "$with_gmp" = yes; then
 161     CL_GMP_CHECK
 162     if test "$cl_cv_new_libgmp" = no; then with_gmp="no"; fi
 163   fi
 164 fi
 165 if test "$with_gmp" = yes; then
 166   CL_GMP_SET_UINTD
 167   AC_DEFINE(CL_USE_GMP)
 168 else
 169   AC_MSG_WARN([disabling external GNU MP library])
 170 fi
 171 dnl
 172 dnl           That's it.
 173 dnl
 174 for f in 'tests/.gdbinit'; do
 175   if test '!' -f "$f"; then
 176     echo "creating $f"
 177 changequote(,)dnl
 178     g=`echo "$f" | sed -e 's,/[^/]*$,,'`
 179 changequote([,])dnl
 180     test "$g" = "$f" || test -d "$g" || mkdir "$g"
 181     cp "$srcdir/$f" "$f"
 182   fi
 183 done
 184 AC_OUTPUT([Makefile src/Makefile tests/Makefile benchmarks/Makefile examples/Makefile doc/Makefile cln-config cln-config.1 cln.spec], [chmod +x cln-config])