m4/longlong.m4

   1 dnl -*- Autoconf -*-
   2 dnl Copyright (C) 1993-2005 Free Software Foundation, Inc.
   3 dnl This file is free software, distributed under the terms of the GNU
   4 dnl General Public License.  As a special exception to the GNU General
   5 dnl Public License, this file may be distributed as part of a program
   6 dnl that contains a configuration script generated by Autoconf, under
   7 dnl the same distribution terms as the rest of that program.
   8
   9 dnl From Bruno Haible, Marcus Daniels, Sam Steingold, Paul Eggert.
  10
  11 AC_PREREQ(2.57)
  12
  13 AC_DEFUN([CL_LONGLONG],
  14 [AC_CACHE_CHECK(for long long type, cl_cv_c_longlong, [
  15 AC_TRY_RUN([int main()
  16 {
  17 /* long longs don't work right with gcc-2.7.2 on m68k */
  18 /* long longs don't work right with gcc-2.7.2 on rs6000: avcall/tests.c gets
  19    miscompiled. */
  20 #if defined(__m68k__) || (defined(_IBMR2) || defined(__powerpc))
  21 #if defined(__GNUC__) && (__GNUC__ == 2) && (__GNUC_MINOR__ <= 7)
  22   exit(1);
  23 #endif
  24 #endif
  25   { long x = 944938507; long y = 737962842; long z = 162359677;
  26     exit(!(((long long) x)*((long long) y)>>32 == z));
  27   }
  28 }],
  29 cl_cv_c_longlong=yes, cl_cv_c_longlong=no, [
  30 dnl When cross-compiling, use the test from gnulib.
  31 AC_TRY_LINK([long long ll = 1LL; int i = 63;],
  32   [long long llmax = (long long) -1;
  33    return ll << i | ll >> i | llmax / ll | llmax % ll;],
  34   cl_cv_c_longlong=yes,
  35   cl_cv_c_longlong=no)])
  36 ])
  37 if test $cl_cv_c_longlong = yes; then
  38   AC_DEFINE(HAVE_LONGLONG,,[compiler supports the `long long' type])
  39 fi
  40 ])