configure.ac

   1 dnl  AUTOCONF configuration for CLN
   2 dnl
   3 dnl  configure.ac ---<autoconf>--->> configure
   4 dnl
   5 dnl  configure    ---<sh>--->> config.status
   6 dnl                      --->> include/cln/config.h
   7 dnl        cln-config.in --->> cln-config
   8 dnl          Makefile.in --->> Makefile
   9 dnl      src/Makefile.in --->> src/Makefile
  10 dnl
  11 dnl  Makefile   ---<make>--->> libcln.a
  12 dnl
  13 dnl
  14 AC_INIT(src/integer/gcd/cl_I_gcd.cc)
  15 AC_CONFIG_AUX_DIR(autoconf)
  16 AC_CONFIG_HEADER(include/cln/config.h include/cln/version.h src/base/cl_base_config.h src/base/cl_gmpconfig.h src/float/cl_float_config.h src/timing/cl_t_config.h)
  17 AC_PROG_MAKE_SET
  18 dnl This piece of sed script replaces every line containing '@subdir@'
  19 dnl by several consecutive lines, each referencing one subdir.
  20 extrasub="$extrasub"'
  21 /@subdir@/{
  22 h
  23 g
  24 s/@subdir@/src/
  25 p
  26 g
  27 s/@subdir@/tests/
  28 p
  29 g
  30 s/@subdir@/benchmarks/
  31 p
  32 g
  33 s/@subdir@/examples/
  34 p
  35 g
  36 s/@subdir@/doc/
  37 p
  38 d
  39 }
  40 '
  41 dnl
  42 dnl           checks for programs
  43 dnl
  44 CL_PROG_CC
  45                       dnl sets variable CC
  46 AC_PROG_CPP
  47                       dnl sets variable CPP
  48 CL_PROG_CXX
  49                       dnl sets variable CXX
  50 AC_PROG_CXXCPP
  51                       dnl sets variable CXXCPP
  52 CL_AS_UNDERSCORE
  53                       dnl sets variable AS_UNDERSCORE, DEFS ASM_UNDERSCORE
  54 AC_PROG_RANLIB
  55                       dnl sets variable RANLIB
  56 AC_PROG_INSTALL
  57                       dnl sets variables INSTALL, INSTALL_DATA, INSTALL_PROGRAM
  58 dnl
  59 dnl           check for host type
  60 dnl
  61 CL_CANONICAL_HOST(autoconf)
  62                       dnl sets variables host, host_cpu, host_vendor, host_os
  63 CL_CANONICAL_HOST_CPU
  64                       dnl DEFS __${host_cpu}__
  65 dnl
  66 dnl           check for build configuration
  67 dnl
  68 PACKAGE=cln
  69                       dnl libtool wants PACKAGE
  70 AC_PROG_LIBTOOL
  71                       dnl sets variable LIBTOOL
  72
  73 dnl Libtool's library version information for CLN.
  74 dnl (Not to be confused with CLN's release version.)
  75 dnl Making new releases:
  76 dnl * increment CL_REVISION,
  77 dnl * if any functions/classes have been added, removed or changed, increment
  78 dnl   CL_CURRENT and set CL_REVISION to 0,
  79 dnl * if any functions/classes have been added, increment CL_AGE,
  80 dnl * if backwards compatibility has been broken, set CL_AGE to 0.
  81 CL_CURRENT=3
  82 CL_REVISION=3
  83 CL_AGE=0
  84 dnl make substitutions
  85 AC_SUBST(CL_CURRENT)
  86 AC_SUBST(CL_REVISION)
  87 AC_SUBST(CL_AGE)
  88 dnl release version
  89 CL_VERSION_MAJOR=1
  90 CL_VERSION_MINOR=1
  91 CL_VERSION_PATCHLEVEL=9
  92 dnl release version for cln/config.h, so it can be tested by the preprocessor
  93 AC_DEFINE_UNQUOTED(CL_VERSION_MAJOR, $CL_VERSION_MAJOR)
  94 AC_DEFINE_UNQUOTED(CL_VERSION_MINOR, $CL_VERSION_MINOR)
  95 AC_DEFINE_UNQUOTED(CL_VERSION_PATCHLEVEL, $CL_VERSION_PATCHLEVEL)
  96 dnl concatenated release version
  97 CL_VERSION=$CL_VERSION_MAJOR.$CL_VERSION_MINOR.$CL_VERSION_PATCHLEVEL
  98 AC_DEFINE_UNQUOTED(CL_VERSION, $CL_VERSION)
  99 AC_SUBST(CL_VERSION)
 100
 101 dnl
 102 dnl           checks for compiler characteristics
 103 dnl
 104 AC_LANG_CPLUSPLUS
 105 dnl
 106 CL_LONGLONG
 107                       dnl DEFS HAVE_LONGLONG
 108 CL_LONGDOUBLE
 109                       dnl DEFS HAVE_LONGDOUBLE
 110 CL_GLOBAL_CONSTRUCTORS
 111                       dnl DEFS CL_GLOBAL_CONSTRUCTOR_PREFIX, CL_GLOBAL_DESTRUCTOR_PREFIX
 112 dnl
 113 dnl           checks for header files
 114 dnl
 115 AC_CHECK_HEADERS([unistd.h])
 116                       dnl DEFS HAVE_UNISTD_H if exist unistd.h
 117 dnl
 118 dnl           checks for typedefs
 119 dnl
 120 dnl
 121 dnl           checks for functions and declarations
 122 dnl
 123 CL_ALLOCA
 124                       dnl set variable ALLOCA, DEFS NO_ALLOCA
 125 CL_FPU_CONTROL
 126                       dnl DEFS HAVE_FPU_CONTROL_T, HAVE_SETFPUCW
 127 CL_GETTIMEOFDAY
 128                       dnl DEFS HAVE_GETTIMEOFDAY, GETTIMEOFDAY_DOTS, GETTIMEOFDAY_TZP_T
 129 ac_cv_func_ftime=no
 130                       dnl don't use ftime(3) even if it's available
 131 CL_TIMES_CLOCK
 132                       dnl DEFS HAVE_TIMES_CLOCK
 133 CL_RUSAGE
 134                       dnl DEFS HAVE_SYS_RESOURCE_H, HAVE_GETRUSAGE, HAVE_SYS_TIMES_H
 135 CL_PERROR
 136                       dnl DEFS HAVE_PERROR_DECL
 137 dnl
 138 dnl           checks for compiler characteristics
 139 dnl
 140 AC_C_CHAR_UNSIGNED
 141                       dnl DEFS __CHAR_UNSIGNED__ if char is unsigned
 142 test -d 'include/cln' || mkdir -p 'include/cln'
 143 CL_MACHINE([integer types and behaviour],${srcdir}/autoconf/intparam.c,include/cln/intparam.h,cl_cv_file_intparam_h)
 144                       dnl builds include/cln/intparam.h
 145 CL_MACHINE([floating-point types and behaviour],${srcdir}/autoconf/floatparam.c,include/cln/floatparam.h,cl_cv_file_floatparam_h)
 146                       dnl builds include/cln/floatparam.h
 147 dnl
 148 dnl           interfacing to GNU gmp (must be at least version 3)
 149 dnl
 150 AC_ARG_WITH(gmp, [  --with-gmp              use external fast low-level functions from GNU MP 3.
 151                           [default=yes]], ,with_gmp="yes")
 152 if test "$with_gmp" = yes; then
 153   CL_GMP_H_VERSION
 154   if test "$cl_cv_new_gmp_h" = no; then with_gmp="no"; fi
 155   if test "$with_gmp" = yes; then
 156     CL_GMP_CHECK
 157     if test "$cl_cv_new_libgmp" = no; then with_gmp="no"; fi
 158   fi
 159 fi
 160 if test "$with_gmp" = yes; then
 161   CL_GMP_SET_UINTD
 162   AC_DEFINE(CL_USE_GMP)
 163 else
 164   AC_MSG_WARN([disabling external GNU MP library])
 165 fi
 166 dnl
 167 dnl           That's it.
 168 dnl
 169 for f in 'tests/.gdbinit'; do
 170   if test '!' -f "$f"; then
 171     echo "creating $f"
 172 changequote(,)dnl
 173     g=`echo "$f" | sed -e 's,/[^/]*$,,'`
 174 changequote([,])dnl
 175     test "$g" = "$f" || test -d "$g" || mkdir "$g"
 176     cp "$srcdir/$f" "$f"
 177   fi
 178 done
 179 AC_OUTPUT([Makefile src/Makefile tests/Makefile benchmarks/Makefile examples/Makefile doc/Makefile cln-config cln-config.1 cln.spec cln.pc], [chmod +x cln-config])