CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.10)
   2 set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules")
   3
   4 project(CLN)
   5 file(STRINGS "${CMAKE_CURRENT_SOURCE_DIR}/include/cln/version.h" _cl_vinfo REGEX "^#define[\t ]+CL_VERSION_.*")
   6 string(REGEX REPLACE "^.*CL_VERSION_MAJOR[ \t]+([0-9]+).*" "\\1" CL_VERSION_MAJOR "${_cl_vinfo}")
   7 string(REGEX REPLACE "^.*CL_VERSION_MINOR[ \t]+([0-9]+).*" "\\1" CL_VERSION_MINOR "${_cl_vinfo}")
   8 string(REGEX REPLACE "^.*CL_VERSION_PATCHLEVEL[ \t]+([0-9]+).*" "\\1" CL_VERSION_PATCHLEVEL "${_cl_vinfo}")
   9 set(CL_VERSION "${CL_VERSION_MAJOR}.${CL_VERSION_MINOR}.${CL_VERSION_PATCHLEVEL}")
  10
  11 # Library
  12 file(STRINGS ${CMAKE_CURRENT_SOURCE_DIR}/include/cln/version.h _cl_vinfo REGEX "^#define[\t ]+CL_LT_.*")
  13 string(REGEX REPLACE "^.*CL_LT_CURRENT[ \t]+([0-9]+).*" "\\1" cl_lt_current "${_cl_vinfo}")
  14 string(REGEX REPLACE "^.*CL_LT_AGE[ \t]+([0-9]+).*" "\\1" cl_lt_age "${_cl_vinfo}")
  15 string(REGEX REPLACE "^.*CL_LT_REVISION[ \t]+([0-9]+).*" "\\1" cl_lt_revision "${_cl_vinfo}")
  16
  17 # XXX: CMake has no portable library versioning?
  18 math(EXPR libcln_soversion "${cl_lt_current} - ${cl_lt_age}")
  19 set(libcln_version ${libcln_soversion}.${cl_lt_age}.${cl_lt_revision})
  20 option(CLN_USE_GMP "Use GMP low level routines" ON)
  21
  22 if (EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/config.status
  23                 OR EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/libtool)
  24         message(FATAL_ERROR
  25                 "Source directory has been already configured by configure script. "
  26                 "Please run `make distclean` in ${CMAKE_CURRENT_SOURCE_DIR} and try again."
  27         )
  28 endif()
  29 include(GNUInstallDirs)
  30
  31 set(cl_config_files
  32         include/cln/config.h
  33         include/cln/host_cpu.h
  34         include/cln/intparam.h
  35         autoconf/cl_config.h
  36         src/base/cl_base_config.h
  37         src/base/cl_gmpconfig.h
  38         src/timing/cl_t_config.h
  39 )
  40 set(cln_generated_headers)
  41
  42 include(CheckIncludeFile)
  43 include(CheckLibraryExists)
  44 include(CheckTypeSize)
  45 include(TestBigEndian)
  46 include(CheckFunctionExists)
  47 include(CheckCXXSourceCompiles)
  48 include(CheckTypeAlign)
  49
  50 enable_testing()
  51 if (NOT TARGET check)
  52         add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND})
  53 endif()
  54 if (NOT TARGET test_suite)
  55         add_custom_target(test_suite)
  56 endif()
  57 if (NOT TARGET info)
  58         add_custom_target(info ALL)
  59 endif()
  60 if (NOT TARGET html)
  61         add_custom_target(html)
  62 endif()
  63 if (NOT TARGET pdf)
  64         add_custom_target(pdf)
  65 endif()
  66
  67 if (NOT DEFINED BUILD_SHARED_LIBS)
  68         if (NOT MSVC)
  69                 set(BUILD_SHARED_LIBS true)
  70         else()
  71                 set(BUILD_SHARED_LIBS false)
  72         endif()
  73 endif()
  74 if (WIN32)
  75         if (NOT DEFINED CMAKE_RUNTIME_OUTPUT_DIRECTORY)
  76                 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/bin)
  77         endif()
  78 endif()
  79
  80 if (CLN_USE_GMP)
  81 find_package(GMP REQUIRED)
  82 endif()
  83
  84 if (GMP_FOUND)
  85         set(CL_USE_GMP TRUE)
  86 endif()
  87
  88 if (GMP_FOUND)
  89         get_filename_component(GMP_LIBDIR ${GMP_LIBRARIES} PATH)
  90         include(GMPLimbSize)
  91 endif(GMP_FOUND)
  92
  93
  94 check_type_size("long long" LONGLONG)
  95 if (HAVE_LONGLONG)
  96         set(SIZEOF_LONGLONG ${LONGLONG})
  97 endif()
  98 check_type_size("short" SIZEOF_SHORT)
  99 check_type_size("int" SIZEOF_INT)
 100 check_type_size("long" SIZEOF_LONG)
 101 check_type_size("void *" SIZEOF_VOIDP)
 102 check_type_align("void *" ALIGNOF_VOIDP)
 103
 104 # not guaranteed by the C standard, but holds in practice
 105 set(cl_char_bitsize 8)
 106 math(EXPR x "${SIZEOF_SHORT} * ${cl_char_bitsize}")
 107 set(cl_short_bitsize ${x} CACHE INTERNAL "short_bitsize")
 108 math(EXPR cl_int_bitsize "${SIZEOF_INT} * ${cl_char_bitsize}")
 109 math(EXPR cl_long_bitsize "${SIZEOF_LONG} * ${cl_char_bitsize}")
 110 math(EXPR cl_pointer_bitsize "${SIZEOF_VOIDP} * ${cl_char_bitsize}")
 111 if (HAVE_LONGLONG)
 112         math(EXPR cl_long_long_bitsize "${SIZEOF_LONGLONG} * ${cl_char_bitsize}")
 113 endif()
 114
 115
 116 check_include_file("unistd.h" HAVE_UNISTD_H)
 117 check_function_exists(gettimeofday HAVE_GETTIMEOFDAY)
 118
 119 set(_save_required_includes ${CMAKE_REQUIRED_INCLUDES})
 120 set(_save_required_libraries ${CMAKE_REQUIRED_LIBRARIES})
 121 set(_save_required_flags ${CMAKE_REQUIRED_FLAGS})
 122 set(CMAKE_REQUIRED_FLAGS "-Werror")
 123 set(CMAKE_REQUIRED_INCLUDES "")
 124 set(CMAKE_REQUIRED_LIBRARIES "")
 125 CHECK_CXX_SOURCE_COMPILES("
 126         void f() __attribute__((flatten));
 127         int main() { return 0; }
 128         "
 129         CL_HAVE_ATTRIBUTE_FLATTEN
 130 )
 131 set(CMAKE_REQUIRED_FLAGS ${_save_required_flags})
 132 set(CMAKE_REQUIRED_INCLUDES ${_save_required_includes})
 133 set(CMAKE_REQUIRED_LIBRARIES ${_save_required_libraries})
 134
 135
 136 test_big_endian(cl_cv_bigendian_p)
 137 if(cl_cv_bigendian_p)
 138         set(short_big_endian 1 CACHE INTERNAL "CPU is big endian")
 139         set(int_big_endian 1 CACHE INTERNAL "CPU is big endian")
 140         set(long_big_endian 1 CACHE INTERNAL "CPU is big endian")
 141 else()
 142         set(short_little_endian 1 CACHE INTERNAL "CPU is little endian")
 143         set(int_little_endian 1 CACHE INTERNAL "CPU is little endian")
 144         set(long_little_endian 1 CACHE INTERNAL "CPU is little endian")
 145 endif()
 146
 147 include(AsmUnderscore)
 148 include(AsmNoexecstack)
 149
 150 set(GMP_LIBDIR_PC)
 151
 152 set(_cln_rpath_reloc "$ORIGIN/../lib")
 153 set(_wl_rpath "${CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG}")
 154 set(_wl_rpath_link "${CMAKE_SHARED_LIBRARY_RPATH_LINK_C_FLAG}")
 155
 156 # rpath for the pkg-config meta-data
 157 set(_libcln_rpath "${_cln_rpath_reloc}")
 158 set(_libcln_pc_rpath "${_wl_rpath}${_cln_rpath_reloc}")
 159
 160 list(FIND CMAKE_CXX_IMPLICIT_LINK_DIRECTORIES "${CMAKE_INSTALL_FULL_LIBDIR}" isSystemDir)
 161 if ("${isSystemDir}" STREQUAL "-1")
 162         set(_libcln_pc_rpath "${_libcln_pc_rpath} ${_wl_rpath}\${libdir}")
 163         list(APPEND _libcln_rpath ${CMAKE_INSTALL_FULL_LIBDIR})
 164 endif()
 165
 166 list(FIND CMAKE_CXX_IMPLICIT_LINK_DIRECTORIES "${GMP_LIBDIR}" isSystemDir)
 167 if ("${isSystemDir}" STREQUAL "-1")
 168         list(APPEND _libcln_rpath ${GMP_LIBDIR})
 169         set(_libcln_pc_rpath "${_libcln_pc_rpath} ${_wl_rpath_link}${GMP_LIBDIR}")
 170         set(GMP_LIBDIR_PC "-L${GMP_LIBDIR}")
 171 endif()
 172 string(REPLACE ";" ":" libcln_rpath "${_libcln_rpath}")
 173
 174 if (NOT DEFINED CMAKE_INSTALL_RPATH_USE_LINK_RPATH)
 175         set(CMAKE_INSTALL_RPATH_USE_LINK_RPATH TRUE)
 176 endif()
 177 if (NOT DEFINED CMAKE_INSTALL_RPATH)
 178         set(CMAKE_INSTALL_RPATH ${libcln_rpath})
 179         if (_wl_rpath)
 180                 set(CLN_PC_RPATH ${_libcln_pc_rpath})
 181         endif()
 182 endif()
 183 if (APPLE AND NOT DEFINED CMAKE_INSTALL_NAME_DIR)
 184         set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_FULL_LIBDIR})
 185 endif()
 186
 187 macro(cl_config_file relname)
 188         set(_dst ${CMAKE_CURRENT_BINARY_DIR}/${relname})
 189         configure_file(${CMAKE_CURRENT_SOURCE_DIR}/${relname}.cmake ${_dst})
 190         if ("${relname}" MATCHES "^include")
 191                 list(APPEND cln_generated_headers "${_dst}")
 192         endif()
 193 endmacro()
 194
 195 foreach(_cf ${cl_config_files})
 196         cl_config_file("${_cf}")
 197 endforeach()
 198 install(FILES ${cln_generated_headers} DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/cln")
 199
 200 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/cln.pc.cmake ${CMAKE_CURRENT_BINARY_DIR}/cln.pc @ONLY)
 201 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/cln.pc DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
 202
 203 include(CMakePackageConfigHelpers)
 204 write_basic_package_version_file(
 205         ${CMAKE_CURRENT_BINARY_DIR}/cln-config-version.cmake
 206         VERSION ${CL_VERSION}
 207         COMPATIBILITY AnyNewerVersion
 208 )
 209 configure_package_config_file(${CMAKE_CURRENT_LIST_DIR}/cmake/cln-config.cmake.in
 210         ${CMAKE_CURRENT_BINARY_DIR}/cln-config.cmake
 211         INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/cln
 212 )
 213 install(FILES
 214         ${CMAKE_CURRENT_LIST_DIR}/cmake/modules/FindGMP.cmake
 215         ${CMAKE_CURRENT_BINARY_DIR}/cln-config.cmake
 216         ${CMAKE_CURRENT_BINARY_DIR}/cln-config-version.cmake
 217         DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/cln
 218 )
 219
 220 add_subdirectory(src)
 221 add_subdirectory(tests)
 222 add_subdirectory(include)
 223 add_subdirectory(examples)
 224 add_subdirectory(doc)
 225