moved some common code to the 'tensor' class
[ginac.git] / ginsh / ginsh_lexer.ll
1 /** @file ginsh_lexer.ll
2  *
3  *  Lexical analyzer definition for ginsh.
4  *  This file must be processed with flex. */
5
6 /*
7  *  GiNaC Copyright (C) 1999-2002 Johannes Gutenberg University Mainz, Germany
8  *
9  *  This program is free software; you can redistribute it and/or modify
10  *  it under the terms of the GNU General Public License as published by
11  *  the Free Software Foundation; either version 2 of the License, or
12  *  (at your option) any later version.
13  *
14  *  This program is distributed in the hope that it will be useful,
15  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
16  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17  *  GNU General Public License for more details.
18  *
19  *  You should have received a copy of the GNU General Public License
20  *  along with this program; if not, write to the Free Software
21  *  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
22  */
23
24
25 /*
26  *  Definitions
27  */
28
29 %{
30 #include "config.h"
31
32 #include "ginsh.h"
33 #include "ginsh_parser.h"
34
35 #define YY_INPUT(buf, result, max_size) (result = ginsh_input(buf, max_size))
36
37 // Table of all used symbols
38 sym_tab syms;
39
40 // lex input function
41 static int ginsh_input(char *buf, int max_size);
42 %}
43
44         /* Abbreviations */
45 D       [0-9]
46 E       [elEL][-+]?{D}+
47 A       [a-zA-Z_]
48 AN      [0-9a-zA-Z_]
49
50
51 /*
52  *  Lexical rules
53  */
54
55 %%
56 [ \t\n]+                /* skip whitespace */
57 \\$                     /* skip line continuations */
58 "//".*                  /* skip comments starting with "//" */
59 ^"#".*                  /* skip lines starting with "#" */
60 ^"!".*                  system(yytext + 1);     /* execute shell command */
61
62                         /* special values */
63 Pi                      yylval = Pi; return T_LITERAL;
64 Euler                   yylval = Euler; return T_LITERAL;
65 Catalan                 yylval = Catalan; return T_LITERAL;
66 FAIL                    yylval = *new fail(); return T_LITERAL;
67 I                       yylval = I; return T_NUMBER;
68 Digits                  yylval = (long)Digits; return T_DIGITS;
69
70                         /* keywords */
71 quit|exit               return T_QUIT;
72 warranty                return T_WARRANTY;
73 print                   return T_PRINT;
74 iprint                  return T_IPRINT;
75 time                    return T_TIME;
76 xyzzy                   return T_XYZZY;
77 inventory               return T_INVENTORY;
78 look                    return T_LOOK;
79 score                   return T_SCORE;
80
81                         /* comparison */
82 "=="                    return T_EQUAL;
83 "!="                    return T_NOTEQ;
84 "<="                    return T_LESSEQ;
85 ">="                    return T_GREATEREQ;
86
87                         /* last 1..3 expressions */
88 \"                      return T_QUOTE;
89 \"\"                    return T_QUOTE2;
90 \"\"\"                  return T_QUOTE3;
91 \%                      return T_QUOTE;
92 \%\%                    return T_QUOTE2;
93 \%\%\%                  return T_QUOTE3;
94
95                         /* numbers */
96 {D}+                    |
97 "#"{D}+"R"{AN}+         |
98 "#b"([01])+             |
99 "#o"[0-7]+              |
100 "#x"[0-9a-fA-F]+        |
101 {D}+"."{D}*({E})?       |
102 {D}*"."{D}+({E})?       |
103 {D}+{E}                 yylval = numeric(yytext); return T_NUMBER;
104
105                         /* symbols */
106 {A}{AN}*                {
107                                 sym_tab::const_iterator i = syms.find(yytext);
108                                 if (i == syms.end()) {
109                                         yylval = syms[yytext] = *(new symbol(yytext));
110                                 } else
111                                         yylval = i->second;
112                                 return T_SYMBOL;
113                         }
114
115                         /* wildcards */
116 \${D}+                  yylval = wild(atoi(yytext + 1)); return T_LITERAL;
117
118                         /* everything else */
119 .                       return *yytext;
120
121 %%
122
123
124 /*
125  *  Routines
126  */
127
128 static int line_length = 0;
129 static char *line_read = NULL;
130 static char *line_ptr;
131
132 // Input function that uses libreadline for interactive input
133 static int ginsh_input(char *buf, int max_size)
134 {
135         int result;
136         if (yy_current_buffer->yy_is_interactive) {
137 #ifdef HAVE_LIBREADLINE
138                 // Do we need to read a new line?
139                 int actual;
140                 if (line_length == 0) {
141
142                         // Free old line
143                         if (line_read)
144                                 free(line_read);
145
146                         // Read new line, prompt "> "
147                         line_read = line_ptr = readline("> ");
148
149                         // EOF?
150                         if (!line_read) {
151                                 line_length = 0;
152                                 return YY_NULL;
153                         }
154
155                         // Add non-empty lines to history
156                         line_length = strlen(line_read) + 1;
157                         if (line_length > 1)
158                                 add_history(line_read);
159
160                         // Reappend trailing '\n' which is stripped by readline()
161                         line_read[line_length - 1] = '\n';
162                 }
163
164                 // Copy data to lex buffer
165                 actual = line_length > max_size ? max_size : line_length;
166                 memcpy(buf, line_ptr, actual);
167                 line_length -= actual;
168                 line_ptr += actual;
169                 result = actual;
170 #else
171                 printf("> "); fflush(stdout);
172                 int c = '*', n;
173                 for (n = 0; n < max_size && (c = getc(yyin)) != EOF && c != '\n'; ++n)
174                         buf[n] = (char)c;
175                 if (c == '\n')
176                         buf[n++] = (char)c;
177                 if (c == EOF && ferror(yyin))
178                         YY_FATAL_ERROR("input in flex scanner failed");
179                 result = n;
180 #endif
181         } else if (((result = fread(buf, 1, max_size, yyin)) == 0) && ferror(yyin))
182                 YY_FATAL_ERROR("input in flex scanner failed");
183
184         return result;
185 }
186
187 // List of input files to be processed
188 int num_files = 0;
189 char **file_list = NULL;
190
191 // EOF encountered, connect to next file. If this was the last file,
192 // connect to stdin. If this was stdin, terminate the scanner.
193 int yywrap()
194 {
195         if (yyin == stdin)
196                 return 1;
197
198         fclose(yyin);
199         if (num_files) {
200                 yyin = fopen(*file_list, "r");
201                 if (yyin == NULL) {
202                         cerr << "Can't open " << *file_list << endl;
203                         return 1;
204                 }
205                 num_files--;
206                 file_list++;
207         } else
208                 yyin = stdin;
209         return 0;
210 }