configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl GiNaC version number
   4 m4_define([ginac_major_version], GINAC_GET_VERSION([MAJOR]))
   5 m4_define([ginac_minor_version], GINAC_GET_VERSION([MINOR]))
   6 m4_define([ginac_micro_version], GINAC_GET_VERSION([MICRO]))
   7 m4_define([ginac_version], [ginac_major_version.ginac_minor_version.ginac_micro_version])
   8 m4_define([ginac_release], [ginac_major_version.ginac_minor_version])
   9
  10 dnl GiNaC library version information. It has very little to do with GiNaC
  11 dnl version number. In particular, library version is OS dependent.
  12 dnl
  13 dnl When making releases, do
  14 dnl 1. Increment ginac_lt_revision
  15 dnl 2. If any interfaces have been added, removed, or changed since the last
  16 dnl    release, increment ginac_lt_current and set ginac_lt_revision to 0.
  17 dnl 3. If any interfaces have been added since the last release, increment
  18 dnl    ginac_lt_age.
  19 dnl 4. If any interfaces have been removed since the last release, set
  20 dnl    ginac_lt_age to 0.
  21 dnl
  22 dnl Please note: the libtool naming scheme cannot guarantee that on all
  23 dnl systems, the numbering is consecutive. It only guarantees that it is
  24 dnl increasing. This doesn't matter, though: there is not incurred cost
  25 dnl for numbers that are omitted, except for shrinking the available space
  26 dnl of leftover numbers. Not something we need to worry about yet. ;-)
  27 m4_define([ginac_lt_current], [3])
  28 m4_define([ginac_lt_revision], [0])
  29 m4_define([ginac_lt_age], [1])
  30
  31 AC_INIT([GiNaC], ginac_version, [ginac-list@ginac.de], [ginac], [http://www.ginac.de/])
  32 AC_PREREQ(2.59)
  33 AC_CONFIG_SRCDIR(ginac/basic.cpp)
  34 AC_CONFIG_AUX_DIR([config])
  35 AC_CONFIG_HEADERS([config/config.h])
  36 AC_CONFIG_MACRO_DIR([m4])
  37 dnl This defines PACKAGE and VERSION.
  38 AM_INIT_AUTOMAKE([gnu 1.8 dist-bzip2])
  39
  40 dnl GiNaC archive file version information.
  41 dnl
  42 dnl If properties have been added, ARCHIVE_VERSION += 1, ARCHIVE_AGE += 1.
  43 dnl If backwards compatibility has been broken, set ARCHIVE_AGE to 0.
  44 dnl
  45 dnl The version number in newly created archives will be ARCHIVE_VERSION.
  46 dnl Archives version (ARCHIVE_VERSION-ARCHIVE_AGE) thru ARCHIVE_VERSION can
  47 dnl be read by this version of the GiNaC library.
  48
  49 ARCHIVE_VERSION=3
  50 ARCHIVE_AGE=3
  51
  52 AC_SUBST(ARCHIVE_VERSION)
  53 AC_SUBST(ARCHIVE_AGE)
  54 AC_DEFINE_UNQUOTED(ARCHIVE_VERSION, $ARCHIVE_VERSION, [Current GiNaC archive file version number])
  55 AC_DEFINE_UNQUOTED(ARCHIVE_AGE, $ARCHIVE_AGE, [GiNaC archive file version age])
  56
  57 dnl libtool versioning
  58 LT_VERSION_INFO="ginac_lt_current:ginac_lt_revision:ginac_lt_age"
  59 AC_SUBST(LT_VERSION_INFO)
  60
  61 dnl Check for the compiler and all the utilities needed for the build.
  62 AC_PROG_CXX
  63 AC_PROG_CXXCPP
  64 AC_PROG_INSTALL
  65 AM_PROG_LIBTOOL
  66 AC_PROG_LEX
  67 AC_PROG_YACC
  68 AC_PATH_PROG(YACCEXE, $YACC, "")
  69 AS_IF([test "x$LEX" = "x:" -a ! -f $srcdir/ginsh/ginsh_lexer.cc],
  70       [GINAC_WARNING([ginsh will not compile, because lex/flex is missing])])
  71 AS_IF([test -z "$YACCEXE" -a ! -f $srcdir/ginsh/ginsh_parser.h],
  72       [GINAC_WARNING([ginsh will not compile, because yacc/bison is missing])])
  73
  74 dnl Switch to C++ language mode for the following libraries and headers.
  75 AC_LANG([C++])
  76
  77 dnl Make sure all the necessary standard headers are installed on the system.
  78 GINAC_STD_CXX_HEADERS
  79
  80 dnl We need to have CLN installed.
  81 PKG_CHECK_MODULES(CLN, cln >= 1.2.2)
  82 AC_LIB_LINKFLAGS_FROM_LIBS([CLN_RPATH], [$CLN_LIBS])
  83 LIBS="$LIBS $CLN_LIBS $CLN_RPATH"
  84 CPPFLAGS="$CPPFLAGS $CLN_CFLAGS"
  85 dnl Include proper rpath into pkg-config meta data, so
  86 dnl g++ `pkg-config --cflags --libs ginac`
  87 dnl actually works
  88 GINACLIB_LIBS='-L${libdir} -lginac'
  89 AC_LIB_LINKFLAGS_FROM_LIBS([GINACLIB_RPATH], [$GINACLIB_LIBS])
  90
  91 dnl Check for data types which are needed by the hash function
  92 dnl (golden_ratio_hash).
  93 AC_CHECK_TYPE(long long)
  94
  95 dnl Check for stuff needed for building the GiNaC interactive shell (ginsh).
  96 AC_CHECK_HEADERS(unistd.h)
  97 GINAC_HAVE_RUSAGE
  98 GINAC_READLINE
  99 dnl Python is necessary for building function.{cpp,h}
 100 AC_PATH_PROG(PYTHON, python, "")
 101 AS_IF([test -z "$PYTHON" -a ! -f "$srcdir/ginac/function.cpp"],
 102       [AC_MSG_ERROR([GiNaC will not compile because Python is missing])])
 103
 104 dnl Check for dl library (needed for GiNaC::compile).
 105 GINAC_EXCOMPILER
 106 AM_CONDITIONAL(CONFIG_EXCOMPILER, [test "x${CONFIG_EXCOMPILER}" = "xyes"])
 107
 108 dnl Check for utilities needed by the different kinds of documentation.
 109 dnl Documentation needs only be built when extending it, so never mind if it
 110 dnl cannot find those helpers:
 111 AC_PATH_PROG(DOXYGEN, doxygen, "")
 112 AM_CONDITIONAL(CONFIG_DOXYGEN, [test ! -z "$DOXYGEN"])
 113 AC_PATH_PROG(LATEX, latex, "")
 114 AC_PATH_PROG(PDFLATEX, pdflatex, "")
 115 AC_PATH_PROG(MAKEINDEX, makeindex, "")
 116 AC_PATH_PROG(MAKEINFO, makeinfo, "")
 117 AC_PATH_PROG(DVIPS, dvips, "")
 118 AM_CONDITIONAL(CONFIG_TEX, [test ! \( -z "$LATEX" -o -z $"PDFLATEX" -o -z "$MAKEINDEX" -o -z "$DVIPS" \)])
 119 AC_PATH_PROG(FIG2DEV, fig2dev, "")
 120 AM_CONDITIONAL(CONFIG_FIG2DEV, [test ! -z "$FIG2DEV"])
 121 AS_IF([test -z "$FIG2DEV" -o -z "$MAKEINFO"],
 122           [GINAC_WARNING([Documentation may not build, because fig2dev/texinfo is missing.])])
 123 AS_IF([test -z "$DOXYGEN"],
 124           [GINAC_WARNING([Reference manual will not build, because doxygen is missing.])])
 125 AS_IF([test -z "$LATEX" -o -z "$PDFLATEX" -o -z "$DVIPS"],
 126           [GINAC_WARNING([Some documentation formats may not build, because latex/pdflatex/dvips is missing.])])
 127
 128 dnl Output makefiles etc.
 129 AC_CONFIG_FILES([
 130 Makefile
 131 GiNaC.spec
 132 ginac.pc
 133 ginac/Makefile
 134 check/Makefile
 135 ginsh/Makefile
 136 ginsh/ginsh.1
 137 tools/Makefile
 138 tools/viewgar.1
 139 tools/ginac-excompiler
 140 doc/Makefile
 141 doc/examples/Makefile
 142 doc/tutorial/Makefile
 143 doc/reference/Makefile
 144 doc/reference/DoxyfileHTML
 145 doc/reference/DoxyfileTEX
 146 doc/reference/DoxyfilePDF
 147 doc/reference/Doxyfooter
 148 ])
 149 AC_OUTPUT
 150
 151 dnl Display a final warning if there has been a GINAC_ERROR or a GINAC_WARNING
 152 GINAC_CHECK_ERRORS