602a844847ef6762644c86d38a7689af54c68a93
[ginac.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2
3 dnl GiNaC version number
4 m4_define([ginac_major_version], [1])
5 m4_define([ginac_minor_version], [5])
6 m4_define([ginac_micro_version], [8])
7 m4_define([ginac_version], [ginac_major_version.ginac_minor_version.ginac_micro_version])
8 m4_define([ginac_release], [ginac_major_version.ginac_minor_version])
9
10 dnl GiNaC library version information. It has very little to do with GiNaC
11 dnl version number. In particular, library version is OS dependent. 
12 dnl
13 dnl When making releases, do
14 dnl 1. Increment ginac_lt_revision
15 dnl 2. If any interfaces have been added, removed, or changed since the last
16 dnl    release, increment ginac_lt_current and set ginac_lt_revision to 0.
17 dnl 3. If any interfaces have been added since the last release, increment
18 dnl    ginac_lt_age.
19 dnl 4. If any interfaces have been removed since the last release, set 
20 dnl    ginac_lt_age to 0.
21 dnl
22 dnl Please note: the libtool naming scheme cannot guarantee that on all
23 dnl systems, the numbering is consecutive. It only guarantees that it is
24 dnl increasing. This doesn't matter, though: there is not incurred cost
25 dnl for numbers that are omitted, except for shrinking the available space
26 dnl of leftover numbers. Not something we need to worry about yet. ;-)
27 m4_define([ginac_lt_current], [2])
28 m4_define([ginac_lt_revision], [0])
29 m4_define([ginac_lt_age], [2])
30
31 AC_INIT([GiNaC], ginac_version, [ginac-list@ginac.de], [ginac], [http://www.ginac.de/])
32 AC_PREREQ(2.59)
33 AC_CONFIG_SRCDIR(ginac/basic.cpp)
34 AC_CONFIG_AUX_DIR([config])
35 AC_CONFIG_HEADERS([config/config.h ginac/version.h])
36 AC_CONFIG_MACRO_DIR([m4])
37 dnl This defines PACKAGE and VERSION.
38 AM_INIT_AUTOMAKE([gnu 1.8 dist-bzip2])
39
40 dnl Process GiNaC version information
41 AC_DEFINE([GINACLIB_MAJOR_VERSION], ginac_major_version, [Major version of GiNaC])
42 AC_DEFINE([GINACLIB_MINOR_VERSION], ginac_minor_version, [Minor version of GiNaC])
43 AC_DEFINE([GINACLIB_MICRO_VERSION], ginac_micro_version, [Micro version of GiNaC])
44
45 dnl GiNaC archive file version information.
46 dnl
47 dnl If properties have been added, ARCHIVE_VERSION += 1, ARCHIVE_AGE += 1.
48 dnl If backwards compatibility has been broken, set ARCHIVE_AGE to 0.
49 dnl
50 dnl The version number in newly created archives will be ARCHIVE_VERSION.
51 dnl Archives version (ARCHIVE_VERSION-ARCHIVE_AGE) thru ARCHIVE_VERSION can
52 dnl be read by this version of the GiNaC library.
53
54 ARCHIVE_VERSION=3
55 ARCHIVE_AGE=3
56
57 AC_SUBST(ARCHIVE_VERSION)
58 AC_SUBST(ARCHIVE_AGE)
59 AC_DEFINE_UNQUOTED(ARCHIVE_VERSION, $ARCHIVE_VERSION, [Current GiNaC archive file version number])
60 AC_DEFINE_UNQUOTED(ARCHIVE_AGE, $ARCHIVE_AGE, [GiNaC archive file version age])
61
62 dnl libtool versioning
63 LT_VERSION_INFO="ginac_lt_current:ginac_lt_revision:ginac_lt_age"
64 dnl TODO: remove LT_RELEASE after ABI gets changed. We used to set
65 dnl LT_RELEASE (for no good reason), omitting it right now would
66 dnl result in a spurious SONAME change.
67 LT_RELEASE="1.5"
68
69 AC_SUBST(LT_VERSION_INFO)
70 AC_SUBST(LT_RELEASE)
71
72
73 dnl Check for the compiler and all the utilities needed for the build.
74 AC_PROG_CXX
75 AC_PROG_CXXCPP
76 AC_PROG_INSTALL
77 AM_PROG_LIBTOOL
78 AM_PROG_LEX
79 AC_PROG_YACC
80
81
82 dnl Switch to C++ language mode for the following libraries and headers.
83 AC_LANG([C++])
84
85 dnl Make sure all the necessary standard headers are installed on the system.
86 GINAC_STD_CXX_HEADERS
87
88 dnl We need to have CLN installed.
89 PKG_CHECK_MODULES(CLN, cln >= 1.2.2)
90 AC_LIB_LINKFLAGS_FROM_LIBS([CLN_RPATH], [$CLN_LIBS], [1])
91 LIBS="$LIBS $CLN_LIBS $CLN_RPATH"
92 CPPFLAGS="$CPPFLAGS $CLN_CFLAGS"
93 dnl Include proper rpath into pkg-config meta data, so
94 dnl g++ `pkg-config --cflags --libs ginac`
95 dnl actually works
96 GINACLIB_LIBS='-L${libdir} -lginac'
97 AC_LIB_LINKFLAGS_FROM_LIBS([GINACLIB_RPATH], [$GINACLIB_LIBS])
98
99 dnl Check for data types which are needed by the hash function 
100 dnl (golden_ratio_hash).
101 AC_CHECK_TYPE(long long)
102
103 dnl Check for stuff needed for building the GiNaC interactive shell (ginsh).
104 AC_CHECK_HEADERS(unistd.h)
105 GINAC_HAVE_RUSAGE
106 GINAC_READLINE
107
108 dnl Check for dl library (needed for GiNaC::compile).
109 GINAC_EXCOMPILER
110 AM_CONDITIONAL(CONFIG_EXCOMPILER, [test "x${CONFIG_EXCOMPILER}" = "xyes"])
111
112 dnl Check for utilities needed by the different kinds of documentation.
113 dnl Documentation needs only be built when extending it, so never mind if it
114 dnl cannot find those helpers:
115 AC_PATH_PROG(DOXYGEN, doxygen, "")
116 AM_CONDITIONAL(CONFIG_DOXYGEN, [test ! -z "$DOXYGEN"])
117 AC_PATH_PROG(LATEX, latex, "")
118 AC_PATH_PROG(PDFLATEX, pdflatex, "")
119 AC_PATH_PROG(MAKEINDEX, makeindex, "")
120 AC_PATH_PROG(DVIPS, dvips, "")
121 AM_CONDITIONAL(CONFIG_TEX, [test ! \( -z "$LATEX" -o -z $"PDFLATEX" -o -z "$MAKEINDEX" -o -z "$DVIPS" \)])
122 AC_PATH_PROG(FIG2DEV, fig2dev, "")
123 AM_CONDITIONAL(CONFIG_FIG2DEV, [test ! -z "$FIG2DEV"])
124
125 dnl generate boilerplate code for the (new) parser.
126 dnl Only developers need this tool.
127 AC_PATH_PROG(AUTOGEN, autogen, "")
128
129 dnl Output makefiles etc.
130 AC_CONFIG_FILES([
131 Makefile
132 GiNaC.spec
133 ginac.pc
134 ginac/Makefile
135 check/Makefile
136 ginsh/Makefile
137 ginsh/ginsh.1
138 tools/Makefile
139 tools/viewgar.1
140 tools/ginac-excompiler
141 doc/Makefile
142 doc/examples/Makefile
143 doc/tutorial/Makefile
144 doc/reference/Makefile
145 doc/reference/DoxyfileHTML
146 doc/reference/DoxyfileTEX
147 doc/reference/DoxyfilePDF
148 doc/reference/Doxyfooter
149 ])
150 AC_OUTPUT
151 dnl Display a final warning if there has been a GINAC_ERROR or a GINAC_WARNING
152 GINAC_CHECK_ERRORS