configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl GiNaC version number
   4 m4_define([ginac_major_version], [1])
   5 m4_define([ginac_minor_version], [6])
   6 m4_define([ginac_micro_version], [0])
   7 m4_define([ginac_version], [ginac_major_version.ginac_minor_version.ginac_micro_version])
   8 m4_define([ginac_release], [ginac_major_version.ginac_minor_version])
   9
  10 dnl GiNaC library version information. It has very little to do with GiNaC
  11 dnl version number. In particular, library version is OS dependent.
  12 dnl
  13 dnl When making releases, do
  14 dnl 1. Increment ginac_lt_revision
  15 dnl 2. If any interfaces have been added, removed, or changed since the last
  16 dnl    release, increment ginac_lt_current and set ginac_lt_revision to 0.
  17 dnl 3. If any interfaces have been added since the last release, increment
  18 dnl    ginac_lt_age.
  19 dnl 4. If any interfaces have been removed since the last release, set
  20 dnl    ginac_lt_age to 0.
  21 dnl
  22 dnl Please note: the libtool naming scheme cannot guarantee that on all
  23 dnl systems, the numbering is consecutive. It only guarantees that it is
  24 dnl increasing. This doesn't matter, though: there is not incurred cost
  25 dnl for numbers that are omitted, except for shrinking the available space
  26 dnl of leftover numbers. Not something we need to worry about yet. ;-)
  27 m4_define([ginac_lt_current], [2])
  28 m4_define([ginac_lt_revision], [0])
  29 m4_define([ginac_lt_age], [0])
  30
  31 AC_INIT([GiNaC], ginac_version, [ginac-list@ginac.de], [ginac], [http://www.ginac.de/])
  32 AC_PREREQ(2.59)
  33 AC_CONFIG_SRCDIR(ginac/basic.cpp)
  34 AC_CONFIG_AUX_DIR([config])
  35 AC_CONFIG_HEADERS([config/config.h ginac/version.h])
  36 AC_CONFIG_MACRO_DIR([m4])
  37 dnl This defines PACKAGE and VERSION.
  38 AM_INIT_AUTOMAKE([gnu 1.8 dist-bzip2])
  39
  40 dnl Process GiNaC version information
  41 AC_DEFINE([GINACLIB_MAJOR_VERSION], ginac_major_version, [Major version of GiNaC])
  42 AC_DEFINE([GINACLIB_MINOR_VERSION], ginac_minor_version, [Minor version of GiNaC])
  43 AC_DEFINE([GINACLIB_MICRO_VERSION], ginac_micro_version, [Micro version of GiNaC])
  44
  45 dnl GiNaC archive file version information.
  46 dnl
  47 dnl If properties have been added, ARCHIVE_VERSION += 1, ARCHIVE_AGE += 1.
  48 dnl If backwards compatibility has been broken, set ARCHIVE_AGE to 0.
  49 dnl
  50 dnl The version number in newly created archives will be ARCHIVE_VERSION.
  51 dnl Archives version (ARCHIVE_VERSION-ARCHIVE_AGE) thru ARCHIVE_VERSION can
  52 dnl be read by this version of the GiNaC library.
  53
  54 ARCHIVE_VERSION=3
  55 ARCHIVE_AGE=3
  56
  57 AC_SUBST(ARCHIVE_VERSION)
  58 AC_SUBST(ARCHIVE_AGE)
  59 AC_DEFINE_UNQUOTED(ARCHIVE_VERSION, $ARCHIVE_VERSION, [Current GiNaC archive file version number])
  60 AC_DEFINE_UNQUOTED(ARCHIVE_AGE, $ARCHIVE_AGE, [GiNaC archive file version age])
  61
  62 dnl libtool versioning
  63 LT_VERSION_INFO="ginac_lt_current:ginac_lt_revision:ginac_lt_age"
  64 AC_SUBST(LT_VERSION_INFO)
  65
  66 dnl Check for the compiler and all the utilities needed for the build.
  67 AC_PROG_CXX
  68 AC_PROG_CXXCPP
  69 AC_PROG_INSTALL
  70 AM_PROG_LIBTOOL
  71 AC_PROG_LEX
  72 AC_PROG_YACC
  73 AC_PATH_PROG(YACCEXE, $YACC, "")
  74
  75 dnl Switch to C++ language mode for the following libraries and headers.
  76 AC_LANG([C++])
  77
  78 dnl Make sure all the necessary standard headers are installed on the system.
  79 GINAC_STD_CXX_HEADERS
  80
  81 dnl We need to have CLN installed.
  82 PKG_CHECK_MODULES(CLN, cln >= 1.2.2)
  83 AC_LIB_LINKFLAGS_FROM_LIBS([CLN_RPATH], [$CLN_LIBS], [1])
  84 LIBS="$LIBS $CLN_LIBS $CLN_RPATH"
  85 CPPFLAGS="$CPPFLAGS $CLN_CFLAGS"
  86 dnl Include proper rpath into pkg-config meta data, so
  87 dnl g++ `pkg-config --cflags --libs ginac`
  88 dnl actually works
  89 GINACLIB_LIBS='-L${libdir} -lginac'
  90 AC_LIB_LINKFLAGS_FROM_LIBS([GINACLIB_RPATH], [$GINACLIB_LIBS])
  91
  92 dnl Check for data types which are needed by the hash function
  93 dnl (golden_ratio_hash).
  94 AC_CHECK_TYPE(long long)
  95
  96 dnl Check for stuff needed for building the GiNaC interactive shell (ginsh).
  97 AC_CHECK_HEADERS(unistd.h)
  98 GINAC_HAVE_RUSAGE
  99 GINAC_READLINE
 100
 101 dnl Check for dl library (needed for GiNaC::compile).
 102 GINAC_EXCOMPILER
 103 AM_CONDITIONAL(CONFIG_EXCOMPILER, [test "x${CONFIG_EXCOMPILER}" = "xyes"])
 104
 105 dnl Check for utilities needed by the different kinds of documentation.
 106 dnl Documentation needs only be built when extending it, so never mind if it
 107 dnl cannot find those helpers:
 108 AC_PATH_PROG(DOXYGEN, doxygen, "")
 109 AM_CONDITIONAL(CONFIG_DOXYGEN, [test ! -z "$DOXYGEN"])
 110 AC_PATH_PROG(LATEX, latex, "")
 111 AC_PATH_PROG(PDFLATEX, pdflatex, "")
 112 AC_PATH_PROG(MAKEINDEX, makeindex, "")
 113 AC_PATH_PROG(MAKEINFO, makeinfo, "")
 114 AC_PATH_PROG(DVIPS, dvips, "")
 115 AM_CONDITIONAL(CONFIG_TEX, [test ! \( -z "$LATEX" -o -z $"PDFLATEX" -o -z "$MAKEINDEX" -o -z "$DVIPS" \)])
 116 AC_PATH_PROG(FIG2DEV, fig2dev, "")
 117 AM_CONDITIONAL(CONFIG_FIG2DEV, [test ! -z "$FIG2DEV"])
 118 AS_IF([test -z "$FIG2DEV" -o -z "$MAKEINFO"],
 119           [GINAC_WARNING([Documentation may not build, because fig2dev/texinfo is missing.])])
 120 AS_IF([test -z "$DOXYGEN"],
 121           [GINAC_WARNING([Reference manual will not build, because doxygen is missing.])])
 122 AS_IF([test -z "$LATEX" -o -z "$PDFLATEX" -o -z "$DVIPS"],
 123           [GINAC_WARNING([Some documentation formats may not build, because latex/pdflatex/dvips is missing.])])
 124
 125 dnl Output makefiles etc.
 126 AC_CONFIG_FILES([
 127 Makefile
 128 GiNaC.spec
 129 ginac.pc
 130 ginac/Makefile
 131 check/Makefile
 132 ginsh/Makefile
 133 ginsh/ginsh.1
 134 tools/Makefile
 135 tools/viewgar.1
 136 tools/ginac-excompiler
 137 doc/Makefile
 138 doc/examples/Makefile
 139 doc/tutorial/Makefile
 140 doc/reference/Makefile
 141 doc/reference/DoxyfileHTML
 142 doc/reference/DoxyfileTEX
 143 doc/reference/DoxyfilePDF
 144 doc/reference/Doxyfooter
 145 ])
 146 AC_OUTPUT
 147
 148 dnl Display a final warning if there has been a GINAC_ERROR or a GINAC_WARNING
 149 GINAC_CHECK_ERRORS