]> www.ginac.de Git - cln.git/blob - m4/general.m4
Enable modifying operators by default.
[cln.git] / m4 / general.m4
1 dnl Copyright (C) 1993-2008 Free Software Foundation, Inc.
2 dnl This file is free software, distributed under the terms of the GNU
3 dnl General Public License.  As a special exception to the GNU General
4 dnl Public License, this file may be distributed as part of a program
5 dnl that contains a configuration script generated by Autoconf, under
6 dnl the same distribution terms as the rest of that program.
7
8 dnl From Bruno Haible, Marcus Daniels, Sam Steingold.
9
10 AC_PREREQ(2.13)
11
12 dnl without AC_MSG_...:   with AC_MSG_... and caching:
13 dnl   AC_TRY_CPP          CL_CPP_CHECK
14 dnl   AC_TRY_COMPILE      CL_COMPILE_CHECK
15 dnl   AC_TRY_LINK         CL_LINK_CHECK
16 dnl   AC_TRY_RUN          CL_RUN_CHECK - would require cross-compiling support
17 dnl Usage:
18 dnl AC_TRY_CPP(INCLUDES,
19 dnl            ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND])
20 dnl CL_CPP_CHECK(ECHO-TEXT, CACHE-ID,
21 dnl              INCLUDES,
22 dnl              ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND])
23 dnl AC_TRY_xxx(INCLUDES, FUNCTION-BODY,
24 dnl            ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND])
25 dnl CL_xxx_CHECK(ECHO-TEXT, CACHE-ID,
26 dnl              INCLUDES, FUNCTION-BODY,
27 dnl              ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND])
28
29 AC_DEFUN([CL_CPP_CHECK],
30 [AC_MSG_CHECKING(for $1)
31 AC_CACHE_VAL($2,[
32 AC_TRY_CPP([$3], $2=yes, $2=no)
33 ])
34 AC_MSG_RESULT([$]$2)
35 if test [$]$2 = yes; then
36   ifelse([$4], , :, [$4])
37 ifelse([$5], , , [else
38   $5
39 ])dnl
40 fi
41 ])
42
43 AC_DEFUN([CL_COMPILE_CHECK],
44 [AC_MSG_CHECKING(for $1)
45 AC_CACHE_VAL($2,[
46 AC_TRY_COMPILE([$3],[$4], $2=yes, $2=no)
47 ])
48 AC_MSG_RESULT([$]$2)
49 if test [$]$2 = yes; then
50   ifelse([$5], , :, [$5])
51 ifelse([$6], , , [else
52   $6
53 ])dnl
54 fi
55 ])
56
57 AC_DEFUN([CL_LINK_CHECK],
58 [AC_MSG_CHECKING(for $1)
59 AC_CACHE_VAL($2,[
60 AC_TRY_LINK([$3],[$4], $2=yes, $2=no)
61 ])
62 AC_MSG_RESULT([$]$2)
63 if test [$]$2 = yes; then
64   ifelse([$5], , :, [$5])
65 ifelse([$6], , , [else
66   $6
67 ])dnl
68 fi
69 ])
70
71 dnl CL_SILENT(ACTION)
72 dnl performs ACTION, with AC_MSG_CHECKING and AC_MSG_RESULT being defined away.
73 AC_DEFUN([CL_SILENT],
74 [pushdef([AC_MSG_CHECKING],[:])dnl
75 pushdef([AC_CHECKING],[:])dnl
76 pushdef([AC_MSG_RESULT],[:])dnl
77 $1[]dnl
78 popdef([AC_MSG_RESULT])dnl
79 popdef([AC_CHECKING])dnl
80 popdef([AC_MSG_CHECKING])dnl
81 ])
82
83 dnl Expands to the "extern ..." prefix used for system declarations.
84 dnl AC_LANG_EXTERN()
85 AC_DEFUN([AC_LANG_EXTERN],
86 [extern
87 #ifdef __cplusplus
88 "C"
89 #endif
90 ])
91
92 AC_DEFUN([CL_CC_WORKS],
93 [AC_CACHE_CHECK(whether CC works at all, cl_cv_prog_cc_works, [
94 AC_LANG_SAVE()
95 AC_LANG_C()
96 AC_TRY_RUN([
97 #include <stdlib.h>
98 int main() { exit(0); }
99 ],
100 cl_cv_prog_cc_works=yes, cl_cv_prog_cc_works=no,
101 AC_TRY_LINK([], [], cl_cv_prog_cc_works=yes, cl_cv_prog_cc_works=no))
102 AC_LANG_RESTORE()
103 ])
104 case "$cl_cv_prog_cc_works" in
105   *no) echo "Installation or configuration problem: C compiler cannot create executables."; exit 1;;
106   *yes) ;;
107 esac
108 ])
109
110 AC_DEFUN([CL_CONFIG_SUBDIRS],
111 [dnl No AC_CONFIG_AUX_DIR_DEFAULT, so we don't need install.sh.
112 AC_PROVIDE([AC_CONFIG_AUX_DIR_DEFAULT])
113 AC_CONFIG_SUBDIRS([$1])dnl
114 ])
115
116 AC_DEFUN([CL_CANONICAL_HOST],
117 [AC_REQUIRE([AC_PROG_CC]) dnl Actually: AC_REQUIRE([CL_CC_WORKS])
118 dnl Set ac_aux_dir before the cache check, because AM_PROG_LIBTOOL needs it.
119 ac_aux_dir=${srcdir}/$1
120 dnl A substitute for AC_CONFIG_AUX_DIR_DEFAULT, so we don't need install.sh.
121 ac_config_guess="$SHELL $ac_aux_dir/config.guess"
122 ac_config_sub="$SHELL $ac_aux_dir/config.sub"
123 dnl We have defined $ac_aux_dir.
124 AC_PROVIDE([AC_CONFIG_AUX_DIR_DEFAULT])dnl
125 dnl In autoconf-2.52, a single AC_CANONICAL_HOST has the effect of inserting
126 dnl the code of AC_CANONICAL_BUILD *before* CL_CANONICAL_HOST, i.e. before
127 dnl ac_aux_dir has been set. To work around this, we list AC_CANONICAL_BUILD
128 dnl explicitly.
129 AC_CANONICAL_BUILD
130 AC_CANONICAL_HOST
131 ])
132
133 AC_DEFUN([CL_CANONICAL_HOST_CPU],
134 [AC_REQUIRE([CL_CANONICAL_HOST])AC_REQUIRE([AC_PROG_CC])
135 case "$host_cpu" in
136 changequote(,)dnl
137   i[4567]86 )
138     host_cpu=i386
139     ;;
140   alphaev[4-8] | alphaev56 | alphapca5[67] | alphaev6[78] )
141     host_cpu=alpha
142     ;;
143   hppa1.0 | hppa1.1 | hppa2.0* | hppa64 )
144     host_cpu=hppa
145     ;;
146   powerpc )
147     host_cpu=rs6000
148     ;;
149   c1 | c2 | c32 | c34 | c38 | c4 )
150     host_cpu=convex
151     ;;
152   arm* )
153     host_cpu=arm
154     ;;
155 changequote([,])dnl
156   mips )
157     AC_CACHE_CHECK([for 64-bit MIPS], cl_cv_host_mips64, [
158 AC_EGREP_CPP(yes,
159 [#if defined(_MIPS_SZLONG)
160 #if (_MIPS_SZLONG == 64)
161 /* We should also check for (_MIPS_SZPTR == 64), but gcc keeps this at 32. */
162   yes
163 #endif
164 #endif
165 ], cl_cv_host_mips64=yes, cl_cv_host_mips64=no)
166 ])
167 if test $cl_cv_host_mips64 = yes; then
168   host_cpu=mips64
169 fi
170     ;;
171 dnl UltraSPARCs running Linux have `uname -m` = "sparc64", but the C compiler
172 dnl still generates 32-bit code.
173   sparc | sparc64 )
174     AC_CACHE_CHECK([for 64-bit SPARC], cl_cv_host_sparc64, [
175 AC_EGREP_CPP(yes,
176 [#if defined(__sparcv9) || defined(__arch64__)
177   yes
178 #endif
179 ], cl_cv_host_sparc64=yes, cl_cv_host_sparc64=no)
180 ])
181 if test $cl_cv_host_sparc64 = yes; then
182   host_cpu=sparc64
183 else
184   host_cpu=sparc
185 fi
186     ;;
187 dnl MacOS X 10.5 machines on x86_64 platforms have 'uname -m' = "i386" even
188 dnl if 64-bit programs are fully supported.
189 dnl AMD64 running Linux have 'uname -m' = "x86_64" even if userland is purely
190 dnl 32-bit.
191   i386 | x86_64 )
192     AC_CACHE_CHECK([for 64-bit userland on x86-64], cl_cv_host_x86_64, [
193 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
194 [[#if !defined __x86_64__
195 # error __x86_64__ not defined
196 #endif
197 ]])
198 ], [cl_cv_host_x86_64=yes], [cl_cv_host_x86_64=no])
199 ])
200 if test $cl_cv_host_x86_64 = yes; then
201   host_cpu=x86_64
202 else
203   host_cpu=i386
204 fi
205   ;;
206 dnl PowerPC64 is another case where 'uname -m' and userland may disagree.
207   powerpc64 )
208     AC_CACHE_CHECK([for 64-bit userland on PowerPC64], cl_cv_host_powerpc64, [
209 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
210 [[#if !defined __powerpc64__
211 # error __powerpc64__ not defined
212 #endif
213 ]])
214 ], [cl_cv_host_powerpc64=yes], [cl_cv_host_powerpc64=no])
215 ])
216 if test $cl_cv_host_powerpc64 = yes; then
217   host_cpu=powerpc64
218 else
219   host_cpu=rs6000
220 fi
221   ;;
222 esac
223 dnl was AC_DEFINE_UNQUOTED(__${host_cpu}__) but KAI C++ 3.2d doesn't like this
224 cat >> confdefs.h <<EOF
225 #ifndef __${host_cpu}__
226 #define __${host_cpu}__ 1
227 #endif
228 EOF
229 ])
230
231 AC_DEFUN([CL_CANONICAL_HOST_CPU_FOR_FFCALL],
232 [AC_REQUIRE([CL_CANONICAL_HOST])AC_REQUIRE([AC_PROG_CC])
233 case "$host_cpu" in
234 changequote(,)dnl
235   i[4567]86 )
236     host_cpu=i386
237     ;;
238   alphaev[4-8] | alphaev56 | alphapca5[67] | alphaev6[78] )
239     host_cpu=alpha
240     ;;
241   hppa1.0 | hppa1.1 | hppa2.0* | hppa64 )
242     host_cpu=hppa
243     ;;
244   powerpc )
245     host_cpu=rs6000
246     ;;
247   c1 | c2 | c32 | c34 | c38 | c4 )
248     host_cpu=convex
249     ;;
250   arm* )
251     host_cpu=arm
252     ;;
253 changequote([,])dnl
254   mips )
255     AC_CACHE_CHECK([for 64-bit MIPS], cl_cv_host_mips64, [
256 AC_EGREP_CPP(yes,
257 [#if defined(_MIPS_SZLONG)
258 #if (_MIPS_SZLONG == 64)
259 /* We should also check for (_MIPS_SZPTR == 64), but gcc keeps this at 32. */
260   yes
261 #endif
262 #endif
263 ], cl_cv_host_mips64=yes, cl_cv_host_mips64=no)
264 ])
265 if test $cl_cv_host_mips64 = yes; then
266   host_cpu=mips64
267 else
268   AC_CACHE_CHECK([for MIPS with n32 ABI], cl_cv_host_mipsn32, [
269 dnl Strictly speaking, the MIPS ABI (-32 or -n32) is independent from the CPU
270 dnl identification (-mips[12] or -mips[34]). But -n32 is commonly used together
271 dnl with -mips3, and it's easier to test the CPU identification.
272 AC_EGREP_CPP(yes,
273 [#if __mips >= 3
274   yes
275 #endif
276 ], cl_cv_host_mipsn32=yes, cl_cv_host_mipsn32=no)
277 ])
278 if test $cl_cv_host_mipsn32 = yes; then
279   host_cpu=mipsn32
280 fi
281 fi
282     ;;
283 dnl UltraSPARCs running Linux have `uname -m` = "sparc64", but the C compiler
284 dnl still generates 32-bit code.
285   sparc | sparc64 )
286     AC_CACHE_CHECK([for 64-bit SPARC], cl_cv_host_sparc64, [
287 AC_EGREP_CPP(yes,
288 [#if defined(__sparcv9) || defined(__arch64__)
289   yes
290 #endif
291 ], cl_cv_host_sparc64=yes, cl_cv_host_sparc64=no)
292 ])
293 if test $cl_cv_host_sparc64 = yes; then
294   host_cpu=sparc64
295 else
296   host_cpu=sparc
297 fi
298     ;;
299 esac
300 dnl was AC_DEFINE_UNQUOTED(__${host_cpu}__) but KAI C++ 3.2d doesn't like this
301 cat >> confdefs.h <<EOF
302 #ifndef __${host_cpu}__
303 #define __${host_cpu}__ 1
304 #endif
305 EOF
306 ])