configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl GiNaC library version information.
   4 dnl
   5 dnl Making releases:
   6 dnl   ginac_micro_version += 1;
   7 dnl   ginac_interface_age += 1;
   8 dnl   ginac_binary_age += 1;
   9 dnl if any functions have been added, set ginac_interface_age to 0.
  10 dnl if backwards compatibility has been broken,
  11 dnl set ginac_binary_age and ginac_interface_age to 0.
  12
  13 m4_define([ginac_major_version], [1])
  14 m4_define([ginac_minor_version], [4])
  15 m4_define([ginac_micro_version], [4])
  16 m4_define([ginac_version], [ginac_major_version.ginac_minor_version.ginac_micro_version])
  17 m4_define([ginac_release], [ginac_major_version.ginac_minor_version])
  18 m4_define([ginac_interface_age], [4])
  19 m4_define([ginac_binary_age], [4])
  20
  21 AC_INIT([GiNaC], ginac_version, [<ginac-list@ginac.de>])
  22 AC_PREREQ(2.59)
  23 AC_CONFIG_SRCDIR(ginac/basic.cpp)
  24 AC_CONFIG_AUX_DIR([config])
  25 AC_CONFIG_HEADERS([config/config.h ginac/version.h])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 dnl This defines PACKAGE and VERSION.
  28 AM_INIT_AUTOMAKE([gnu 1.7 dist-bzip2])
  29
  30 dnl Process GiNaC version information
  31 AC_DEFINE([GINACLIB_MAJOR_VERSION], ginac_major_version, [Major version of GiNaC])
  32 AC_DEFINE([GINACLIB_MINOR_VERSION], ginac_minor_version, [Minor version of GiNaC])
  33 AC_DEFINE([GINACLIB_MICRO_VERSION], ginac_minor_version, [Micro version of GiNaC])
  34
  35 dnl GiNaC archive file version information.
  36 dnl
  37 dnl If properties have been added, ARCHIVE_VERSION += 1, ARCHIVE_AGE += 1.
  38 dnl If backwards compatibility has been broken, set ARCHIVE_AGE to 0.
  39 dnl
  40 dnl The version number in newly created archives will be ARCHIVE_VERSION.
  41 dnl Archives version (ARCHIVE_VERSION-ARCHIVE_AGE) thru ARCHIVE_VERSION can
  42 dnl be read by this version of the GiNaC library.
  43
  44 ARCHIVE_VERSION=3
  45 ARCHIVE_AGE=3
  46
  47 AC_SUBST(ARCHIVE_VERSION)
  48 AC_SUBST(ARCHIVE_AGE)
  49 AC_DEFINE_UNQUOTED(ARCHIVE_VERSION, $ARCHIVE_VERSION, [Current GiNaC archive file version number])
  50 AC_DEFINE_UNQUOTED(ARCHIVE_AGE, $ARCHIVE_AGE, [GiNaC archive file version age])
  51
  52 dnl libtool versioning
  53 m4_define([lt_revision], [ginac_interface_age])
  54 m4_define([lt_current], [m4_eval(ginac_micro_version - ginac_interface_age)])
  55 m4_define([lt_age], [m4_eval(ginac_binary_age - ginac_interface_age)])
  56 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
  57 LT_RELEASE="ginac_release"
  58
  59 AC_SUBST(LT_VERSION_INFO)
  60 AC_SUBST(LT_RELEASE)
  61
  62
  63 dnl Check for the compiler and all the utilities needed for the build.
  64 AC_PROG_CXX
  65 AC_PROG_CXXCPP
  66 AC_PROG_INSTALL
  67 AM_PROG_LIBTOOL
  68 AM_PROG_LEX
  69 AC_PROG_YACC
  70
  71
  72 dnl Switch to C++ language mode for the following libraries and headers.
  73 AC_LANG([C++])
  74
  75 dnl Make sure all the necessary standard headers are installed on the system.
  76 GINAC_STD_CXX_HEADERS
  77
  78 dnl We need to have Bruno Haible's CLN installed.
  79 dnl (pkg-config must have installed pkg.m4 at a visible place, which provides
  80 dnl this macro. CLN >= 1.1.6 must have installed cln.pc at a visible place,
  81 dnl which provides the actual dependency information.)
  82 PKG_CHECK_MODULES(CLN, cln >= 1.1.6)
  83 AC_LIB_LINKFLAGS_FROM_LIBS([CLN_RPATH], [$CLN_LIBS], [1])
  84 LIBS="$LIBS $CLN_LIBS $CLN_RPATH"
  85 CPPFLAGS="$CPPFLAGS $CLN_CFLAGS"
  86 dnl Include proper rpath into pkg-config meta data, so
  87 dnl g++ `pkg-config --cflags --libs ginac`
  88 dnl actually works
  89 GINACLIB_LIBS='-L${libdir} -lginac'
  90 AC_LIB_LINKFLAGS_FROM_LIBS([GINACLIB_RPATH], [$GINACLIB_LIBS])
  91
  92 dnl Check for data types which are needed by the hash function
  93 dnl (golden_ratio_hash).
  94 AC_CHECK_TYPE(long long)
  95
  96 dnl Check for stuff needed for building the GiNaC interactive shell (ginsh).
  97 AC_CHECK_HEADERS(unistd.h)
  98 GINAC_HAVE_RUSAGE
  99 GINAC_READLINE
 100
 101 dnl Check for dl library (needed for GiNaC::compile).
 102 GINAC_EXCOMPILER
 103
 104 dnl Check for utilities needed by the different kinds of documentation.
 105 dnl Documentation needs only be built when extending it, so never mind if it
 106 dnl cannot find those helpers:
 107 AC_PATH_PROG(DOXYGEN, doxygen, "")
 108 AM_CONDITIONAL(CONFIG_DOXYGEN, [test ! -z "$DOXYGEN"])
 109 AC_PATH_PROG(LATEX, latex, "")
 110 AC_PATH_PROG(PDFLATEX, pdflatex, "")
 111 AC_PATH_PROG(MAKEINDEX, makeindex, "")
 112 AC_PATH_PROG(DVIPS, dvips, "")
 113 AM_CONDITIONAL(CONFIG_TEX, [test ! \( -z "$LATEX" -o -z $"PDFLATEX" -o -z "$MAKEINDEX" -o -z "$DVIPS" \)])
 114 AC_PATH_PROG(FIG2DEV, fig2dev, "")
 115 AM_CONDITIONAL(CONFIG_FIG2DEV, [test ! -z "$FIG2DEV"])
 116
 117 dnl Output makefiles etc.
 118 AC_CONFIG_FILES([
 119 Makefile
 120 GiNaC.spec
 121 ginac.pc
 122 ginac/Makefile
 123 check/Makefile
 124 ginsh/Makefile
 125 ginsh/ginsh.1
 126 tools/Makefile
 127 tools/viewgar.1
 128 tools/ginac-excompiler
 129 doc/Makefile
 130 doc/examples/Makefile
 131 doc/tutorial/Makefile
 132 doc/reference/Makefile
 133 doc/reference/DoxyfileHTML
 134 doc/reference/DoxyfileTEX
 135 doc/reference/DoxyfilePDF
 136 doc/reference/Doxyfooter
 137 ])
 138 AC_OUTPUT
 139 dnl Display a final warning if there has been a GINAC_ERROR or a GINAC_WARNING
 140 GINAC_CHECK_ERRORS