dnl Process this file with autoconf to produce a configure script.

AC_INIT(ginac/basic.cpp)
AM_CONFIG_HEADER(config.h)
AC_PREREQ(2.12)

dnl This defines PACKAGE and VERSION
AM_INIT_AUTOMAKE([GiNaC], [0.4])
AM_MAINTAINER_MODE

dnl ===========================================================================
dnl Check for the compiler and all the utilities needed for the build:
dnl ===========================================================================
AC_PROG_CXX
AC_PROG_CXXCPP
AM_PROG_INSTALL
AM_PROG_LIBTOOL
AM_PROG_LEX
AC_PROG_YACC

dnl Switch to C++ language mode for the following libraries and headers:
AC_LANG_CPLUSPLUS

dnl Make sure the following libraries work by testing for symbols therein. 
dnl They are automatically added the the variable $LIBS and thus passed into
dnl the Makefile:
AC_CHECK_LIB(stdc++, cout)

dnl Make sure all the necessary new-style headers are installed on the system.
dnl If one of them cannot be found the system is probably not ANSI-conform
dnl enough so trying the .h-style headers is a waste of time.
AC_CHECK_HEADERS(iostream vector map string list typeinfo iterator strstream stdexcept algorithm, ,
    AC_MSG_ERROR(need to have ANSI compliant headers))

dnl We need to have Bruno Haible's CLN installed (macros are in aclocal.m4):
GINAC_CHECK_CLN_H
GINAC_CHECK_LIBCLN

dnl Check for stuff needed for building the GiNaC interactive shell (ginsh):
AC_CHECK_HEADERS(unistd.h)
AC_REPLACE_FUNCS(strdup)
AC_CHECK_HEADERS(readline/readline.h readline/history.h)
AC_CHECK_LIB(readline, readline)

dnl Check for utilities needed by the different kinds of documentation.
dnl Documantation needs only be built when extending it, so never mind if it
dnl cannot find those helpers:
AC_PATH_PROG(DOXYGEN, doxygen, "")
AC_PATH_PROG(LATEX, latex, "")
AC_PATH_PROG(MAKEINDEX, makeindex, "")
AC_PATH_PROG(DVIPS, dvips, "")
AC_PATH_PROG(FIG2DEV, fig2dev, "")
AC_PATH_PROG(JADE, jade, "")
AC_PATH_PROG(JADETEX, jadetex, "")

dnl ===========================================================================
dnl Produce a Makefile from Makefile.in:
dnl ===========================================================================
AC_OUTPUT([Makefile ginac/Makefile check/Makefile ginsh/Makefile doc/Makefile])
echo "Configuration done. Now type \"make\"."