ginsh/ginsh_parser.yy

   1 /** @file ginsh_parser.yy
   2  *
   3  *  Input grammar definition for ginsh.
   4  *  This file must be processed with yacc/bison. */
   5
   6 /*
   7  *  GiNaC Copyright (C) 1999-2001 Johannes Gutenberg University Mainz, Germany
   8  *
   9  *  This program is free software; you can redistribute it and/or modify
  10  *  it under the terms of the GNU General Public License as published by
  11  *  the Free Software Foundation; either version 2 of the License, or
  12  *  (at your option) any later version.
  13  *
  14  *  This program is distributed in the hope that it will be useful,
  15  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  *  GNU General Public License for more details.
  18  *
  19  *  You should have received a copy of the GNU General Public License
  20  *  along with this program; if not, write to the Free Software
  21  *  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  22  */
  23
  24
  25 /*
  26  *  Definitions
  27  */
  28
  29 %{
  30 #include "config.h"
  31
  32 #include <sys/resource.h>
  33
  34 #if HAVE_UNISTD_H
  35 #include <sys/types.h>
  36 #include <unistd.h>
  37 #endif
  38
  39 #include <stdexcept>
  40
  41 #include "ginsh.h"
  42
  43 #define YYERROR_VERBOSE 1
  44
  45 // Original readline settings
  46 static int orig_completion_append_character;
  47 static char *orig_basic_word_break_characters;
  48
  49 // Expression stack for ", "" and """
  50 static void push(const ex &e);
  51 static ex exstack[3];
  52
  53 // Start and end time for the time() function
  54 static struct rusage start_time, end_time;
  55
  56 // Table of functions (a multimap, because one function may appear with different
  57 // numbers of parameters)
  58 typedef ex (*fcnp)(const exprseq &e);
  59 typedef ex (*fcnp2)(const exprseq &e, int serial);
  60
  61 struct fcn_desc {
  62         fcn_desc() : p(NULL), num_params(0) {}
  63         fcn_desc(fcnp func, int num) : p(func), num_params(num), is_ginac(false) {}
  64         fcn_desc(fcnp2 func, int num, int ser) : p((fcnp)func), num_params(num), is_ginac(true), serial(ser) {}
  65
  66         fcnp p;         // Pointer to function
  67         int num_params; // Number of parameters (0 = arbitrary)
  68         bool is_ginac;  // Flag: function is GiNaC function
  69         int serial;     // GiNaC function serial number (if is_ginac == true)
  70 };
  71
  72 typedef multimap<string, fcn_desc> fcn_tab;
  73 static fcn_tab fcns;
  74
  75 static fcn_tab::const_iterator find_function(const ex &sym, int req_params);
  76
  77 // Table to map help topics to help strings
  78 typedef multimap<string, string> help_tab;
  79 static help_tab help;
  80
  81 static void print_help(const string &topic);
  82 static void print_help_topics(void);
  83 %}
  84
  85 /* Tokens (T_LITERAL means a literal value returned by the parser, but not
  86    of class numeric or symbol (e.g. a constant or the FAIL object)) */
  87 %token T_NUMBER T_SYMBOL T_LITERAL T_DIGITS T_QUOTE T_QUOTE2 T_QUOTE3
  88 %token T_EQUAL T_NOTEQ T_LESSEQ T_GREATEREQ T_MATRIX_BEGIN T_MATRIX_END
  89
  90 %token T_QUIT T_WARRANTY T_PRINT T_IPRINT T_TIME T_XYZZY T_INVENTORY T_LOOK T_SCORE
  91
  92 /* Operator precedence and associativity */
  93 %right '='
  94 %left T_EQUAL T_NOTEQ
  95 %left '<' '>' T_LESSEQ T_GREATEREQ
  96 %left '+' '-'
  97 %left '*' '/' '%'
  98 %nonassoc NEG
  99 %right '^'
 100 %nonassoc '!'
 101
 102 %start input
 103
 104
 105 /*
 106  *  Grammar rules
 107  */
 108
 109 %%
 110 input   : /* empty */
 111         | input line
 112         ;
 113
 114 line    : ';'
 115         | exp ';' {
 116                 try {
 117                         cout << $1 << endl;
 118                         push($1);
 119                 } catch (exception &e) {
 120                         cerr << e.what() << endl;
 121                         YYERROR;
 122                 }
 123         }
 124         | exp ':' {
 125                 try {
 126                         push($1);
 127                 } catch (exception &e) {
 128                         cerr << e.what() << endl;
 129                         YYERROR;
 130                 }
 131         }
 132         | T_PRINT '(' exp ')' ';' {
 133                 try {
 134                         $3.printtree(cout);
 135                 } catch (exception &e) {
 136                         cerr << e.what() << endl;
 137                         YYERROR;
 138                 }
 139         }
 140         | T_IPRINT '(' exp ')' ';' {
 141                 try {
 142                         ex e = $3;
 143                         if (!e.info(info_flags::integer))
 144                                 throw (std::invalid_argument("argument to iprint() must be an integer"));
 145                         long i = ex_to_numeric(e).to_long();
 146                         cout << i << endl;
 147                         cout << "#o" << oct << i << endl;
 148                         cout << "#x" << hex << i << dec << endl;
 149                 } catch (exception &e) {
 150                         cerr << e.what() << endl;
 151                         YYERROR;
 152                 }
 153         }
 154         | '?' T_SYMBOL          {print_help(ex_to_symbol($2).getname());}
 155         | '?' T_TIME            {print_help("time");}
 156         | '?' '?'               {print_help_topics();}
 157         | T_QUIT                {YYACCEPT;}
 158         | T_WARRANTY {
 159                 cout << "This program is free software; you can redistribute it and/or modify it under\n";
 160                 cout << "the terms of the GNU General Public License as published by the Free Software\n";
 161                 cout << "Foundation; either version 2 of the License, or (at your option) any later\n";
 162                 cout << "version.\n";
 163                 cout << "This program is distributed in the hope that it will be useful, but WITHOUT\n";
 164                 cout << "ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS\n";
 165                 cout << "FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more\n";
 166                 cout << "details.\n";
 167                 cout << "You should have received a copy of the GNU General Public License along with\n";
 168                 cout << "this program. If not, write to the Free Software Foundation, 675 Mass Ave,\n";
 169                 cout << "Cambridge, MA 02139, USA.\n";
 170         }
 171         | T_XYZZY               {cout << "Nothing happens.\n";}
 172         | T_INVENTORY           {cout << "You're not carrying anything.\n";}
 173         | T_LOOK                {cout << "You're in a twisty little maze of passages, all alike.\n";}
 174         | T_SCORE {
 175                 cout << "If you were to quit now, you would score ";
 176                 cout << (syms.size() > 350 ? 350 : syms.size());
 177                 cout << " out of a possible 350.\n";
 178         }
 179         | T_TIME {getrusage(RUSAGE_SELF, &start_time);} '(' exp ')' {
 180                 getrusage(RUSAGE_SELF, &end_time);
 181                 cout << (end_time.ru_utime.tv_sec - start_time.ru_utime.tv_sec) +
 182                         (end_time.ru_stime.tv_sec - start_time.ru_stime.tv_sec) +
 183                          double(end_time.ru_utime.tv_usec - start_time.ru_utime.tv_usec) / 1e6 +
 184                          double(end_time.ru_stime.tv_usec - start_time.ru_stime.tv_usec) / 1e6 << 's' << endl;
 185         }
 186         | error ';'             {yyclearin; yyerrok;}
 187         | error ':'             {yyclearin; yyerrok;}
 188         ;
 189
 190 exp     : T_NUMBER              {$$ = $1;}
 191         | T_SYMBOL              {$$ = $1.eval();}
 192         | '\'' T_SYMBOL '\''    {$$ = $2;}
 193         | T_LITERAL             {$$ = $1;}
 194         | T_DIGITS              {$$ = $1;}
 195         | T_QUOTE               {$$ = exstack[0];}
 196         | T_QUOTE2              {$$ = exstack[1];}
 197         | T_QUOTE3              {$$ = exstack[2];}
 198         | T_SYMBOL '(' exprseq ')' {
 199                 fcn_tab::const_iterator i = find_function($1, $3.nops());
 200                 if (i->second.is_ginac) {
 201                         $$ = ((fcnp2)(i->second.p))(static_cast<const exprseq &>(*($3.bp)), i->second.serial);
 202                 } else {
 203                         $$ = (i->second.p)(static_cast<const exprseq &>(*($3.bp)));
 204                 }
 205         }
 206         | T_DIGITS '=' T_NUMBER {$$ = $3; Digits = ex_to_numeric($3).to_int();}
 207         | T_SYMBOL '=' exp      {$$ = $3; const_cast<symbol *>(&ex_to_symbol($1))->assign($3);}
 208         | exp T_EQUAL exp       {$$ = $1 == $3;}
 209         | exp T_NOTEQ exp       {$$ = $1 != $3;}
 210         | exp '<' exp           {$$ = $1 < $3;}
 211         | exp T_LESSEQ exp      {$$ = $1 <= $3;}
 212         | exp '>' exp           {$$ = $1 > $3;}
 213         | exp T_GREATEREQ exp   {$$ = $1 >= $3;}
 214         | exp '+' exp           {$$ = $1 + $3;}
 215         | exp '-' exp           {$$ = $1 - $3;}
 216         | exp '*' exp           {$$ = $1 * $3;}
 217         | exp '/' exp           {$$ = $1 / $3;}
 218         | exp '%' exp           {$$ = $1 % $3;}
 219         | '-' exp %prec NEG     {$$ = -$2;}
 220         | '+' exp %prec NEG     {$$ = $2;}
 221         | exp '^' exp           {$$ = power($1, $3);}
 222         | exp '!'               {$$ = factorial($1);}
 223         | '(' exp ')'           {$$ = $2;}
 224         | '[' list_or_empty ']' {$$ = $2;}
 225         | T_MATRIX_BEGIN matrix T_MATRIX_END    {$$ = lst_to_matrix($2);}
 226         ;
 227
 228 exprseq : exp                   {$$ = exprseq($1);}
 229         | exprseq ',' exp       {exprseq es(static_cast<exprseq &>(*($1.bp))); $$ = es.append($3);}
 230         ;
 231
 232 list_or_empty: /* empty */      {$$ = *new lst;}
 233         | list                  {$$ = $1;}
 234         ;
 235
 236 list    : exp                   {$$ = lst($1);}
 237         | list ',' exp          {lst l(static_cast<lst &>(*($1.bp))); $$ = l.append($3);}
 238         ;
 239
 240 matrix  : T_MATRIX_BEGIN row T_MATRIX_END               {$$ = lst($2);}
 241         | matrix ',' T_MATRIX_BEGIN row T_MATRIX_END    {lst l(static_cast<lst &>(*($1.bp))); $$ = l.append($4);}
 242         ;
 243
 244 row     : exp                   {$$ = lst($1);}
 245         | row ',' exp           {lst l(static_cast<lst &>(*($1.bp))); $$ = l.append($3);}
 246         ;
 247
 248
 249 /*
 250  *  Routines
 251  */
 252
 253 %%
 254 // Error print routine
 255 int yyerror(char *s)
 256 {
 257         cerr << s << " at " << yytext << endl;
 258         return 0;
 259 }
 260
 261 // Push expression "e" onto the expression stack (for ", "" and """)
 262 static void push(const ex &e)
 263 {
 264         exstack[2] = exstack[1];
 265         exstack[1] = exstack[0];
 266         exstack[0] = e;
 267 }
 268
 269
 270 /*
 271  *  Built-in functions
 272  */
 273
 274 static ex f_denom(const exprseq &e) {return e[0].denom();}
 275 static ex f_eval1(const exprseq &e) {return e[0].eval();}
 276 static ex f_evalf1(const exprseq &e) {return e[0].evalf();}
 277 static ex f_expand(const exprseq &e) {return e[0].expand();}
 278 static ex f_gcd(const exprseq &e) {return gcd(e[0], e[1]);}
 279 static ex f_lcm(const exprseq &e) {return lcm(e[0], e[1]);}
 280 static ex f_lsolve(const exprseq &e) {return lsolve(e[0], e[1]);}
 281 static ex f_nops(const exprseq &e) {return e[0].nops();}
 282 static ex f_normal1(const exprseq &e) {return e[0].normal();}
 283 static ex f_numer(const exprseq &e) {return e[0].numer();}
 284 static ex f_pow(const exprseq &e) {return pow(e[0], e[1]);}
 285 static ex f_sqrt(const exprseq &e) {return sqrt(e[0]);}
 286 static ex f_subs2(const exprseq &e) {return e[0].subs(e[1]);}
 287
 288 #define CHECK_ARG(num, type, fcn) if (!is_ex_of_type(e[num], type)) throw(std::invalid_argument("argument " #num " to " #fcn "() must be a " #type))
 289
 290 static ex f_charpoly(const exprseq &e)
 291 {
 292         CHECK_ARG(0, matrix, charpoly);
 293         CHECK_ARG(1, symbol, charpoly);
 294         return ex_to_matrix(e[0]).charpoly(ex_to_symbol(e[1]));
 295 }
 296
 297 static ex f_coeff(const exprseq &e)
 298 {
 299         CHECK_ARG(1, symbol, coeff);
 300         CHECK_ARG(2, numeric, coeff);
 301         return e[0].coeff(ex_to_symbol(e[1]), ex_to_numeric(e[2]).to_int());
 302 }
 303
 304 static ex f_collect(const exprseq &e)
 305 {
 306         CHECK_ARG(1, symbol, collect);
 307         return e[0].collect(ex_to_symbol(e[1]));
 308 }
 309
 310 static ex f_content(const exprseq &e)
 311 {
 312         CHECK_ARG(1, symbol, content);
 313         return e[0].content(ex_to_symbol(e[1]));
 314 }
 315
 316 static ex f_degree(const exprseq &e)
 317 {
 318         CHECK_ARG(1, symbol, degree);
 319         return e[0].degree(ex_to_symbol(e[1]));
 320 }
 321
 322 static ex f_determinant(const exprseq &e)
 323 {
 324         CHECK_ARG(0, matrix, determinant);
 325         return ex_to_matrix(e[0]).determinant();
 326 }
 327
 328 static ex f_diag(const exprseq &e)
 329 {
 330         unsigned dim = e.nops();
 331         matrix &m = *new matrix(dim, dim);
 332         for (unsigned i=0; i<dim; i++)
 333                 m.set(i, i, e.op(i));
 334         return m;
 335 }
 336
 337 static ex f_diff2(const exprseq &e)
 338 {
 339         CHECK_ARG(1, symbol, diff);
 340         return e[0].diff(ex_to_symbol(e[1]));
 341 }
 342
 343 static ex f_diff3(const exprseq &e)
 344 {
 345         CHECK_ARG(1, symbol, diff);
 346         CHECK_ARG(2, numeric, diff);
 347         return e[0].diff(ex_to_symbol(e[1]), ex_to_numeric(e[2]).to_int());
 348 }
 349
 350 static ex f_divide(const exprseq &e)
 351 {
 352         ex q;
 353         if (divide(e[0], e[1], q))
 354                 return q;
 355         else
 356                 return *new fail();
 357 }
 358
 359 static ex f_eval2(const exprseq &e)
 360 {
 361         CHECK_ARG(1, numeric, eval);
 362         return e[0].eval(ex_to_numeric(e[1]).to_int());
 363 }
 364
 365 static ex f_evalf2(const exprseq &e)
 366 {
 367         CHECK_ARG(1, numeric, evalf);
 368         return e[0].evalf(ex_to_numeric(e[1]).to_int());
 369 }
 370
 371 static ex f_has(const exprseq &e)
 372 {
 373         return e[0].has(e[1]) ? ex(1) : ex(0);
 374 }
 375
 376 static ex f_inverse(const exprseq &e)
 377 {
 378         CHECK_ARG(0, matrix, inverse);
 379         return ex_to_matrix(e[0]).inverse();
 380 }
 381
 382 static ex f_is(const exprseq &e)
 383 {
 384         CHECK_ARG(0, relational, is);
 385         return (bool)ex_to_relational(e[0]) ? ex(1) : ex(0);
 386 }
 387
 388 static ex f_lcoeff(const exprseq &e)
 389 {
 390         CHECK_ARG(1, symbol, lcoeff);
 391         return e[0].lcoeff(ex_to_symbol(e[1]));
 392 }
 393
 394 static ex f_ldegree(const exprseq &e)
 395 {
 396         CHECK_ARG(1, symbol, ldegree);
 397         return e[0].ldegree(ex_to_symbol(e[1]));
 398 }
 399
 400 static ex f_normal2(const exprseq &e)
 401 {
 402         CHECK_ARG(1, numeric, normal);
 403         return e[0].normal(ex_to_numeric(e[1]).to_int());
 404 }
 405
 406 static ex f_op(const exprseq &e)
 407 {
 408         CHECK_ARG(1, numeric, op);
 409         int n = ex_to_numeric(e[1]).to_int();
 410         if (n < 0 || n >= (int)e[0].nops())
 411                 throw(std::out_of_range("second argument to op() is out of range"));
 412         return e[0].op(n);
 413 }
 414
 415 static ex f_prem(const exprseq &e)
 416 {
 417         CHECK_ARG(2, symbol, prem);
 418         return prem(e[0], e[1], ex_to_symbol(e[2]));
 419 }
 420
 421 static ex f_primpart(const exprseq &e)
 422 {
 423         CHECK_ARG(1, symbol, primpart);
 424         return e[0].primpart(ex_to_symbol(e[1]));
 425 }
 426
 427 static ex f_quo(const exprseq &e)
 428 {
 429         CHECK_ARG(2, symbol, quo);
 430         return quo(e[0], e[1], ex_to_symbol(e[2]));
 431 }
 432
 433 static ex f_rem(const exprseq &e)
 434 {
 435         CHECK_ARG(2, symbol, rem);
 436         return rem(e[0], e[1], ex_to_symbol(e[2]));
 437 }
 438
 439 static ex f_series(const exprseq &e)
 440 {
 441         CHECK_ARG(2, numeric, series);
 442         return e[0].series(e[1], ex_to_numeric(e[2]).to_int());
 443 }
 444
 445 static ex f_sqrfree1(const exprseq &e)
 446 {
 447         return sqrfree(e[0]);
 448 }
 449
 450 static ex f_sqrfree2(const exprseq &e)
 451 {
 452         CHECK_ARG(1, lst, sqrfree);
 453         return sqrfree(e[0], ex_to_lst(e[1]));
 454 }
 455
 456 static ex f_subs3(const exprseq &e)
 457 {
 458         CHECK_ARG(1, lst, subs);
 459         CHECK_ARG(2, lst, subs);
 460         return e[0].subs(ex_to_lst(e[1]), ex_to_lst(e[2]));
 461 }
 462
 463 static ex f_tcoeff(const exprseq &e)
 464 {
 465         CHECK_ARG(1, symbol, tcoeff);
 466         return e[0].tcoeff(ex_to_symbol(e[1]));
 467 }
 468
 469 static ex f_trace(const exprseq &e)
 470 {
 471         CHECK_ARG(0, matrix, trace);
 472         return ex_to_matrix(e[0]).trace();
 473 }
 474
 475 static ex f_transpose(const exprseq &e)
 476 {
 477         CHECK_ARG(0, matrix, transpose);
 478         return ex_to_matrix(e[0]).transpose();
 479 }
 480
 481 static ex f_unassign(const exprseq &e)
 482 {
 483         CHECK_ARG(0, symbol, unassign);
 484         (const_cast<symbol *>(&ex_to_symbol(e[0])))->unassign();
 485         return e[0];
 486 }
 487
 488 static ex f_unit(const exprseq &e)
 489 {
 490         CHECK_ARG(1, symbol, unit);
 491         return e[0].unit(ex_to_symbol(e[1]));
 492 }
 493
 494 static ex f_dummy(const exprseq &e)
 495 {
 496         throw(std::logic_error("dummy function called (shouldn't happen)"));
 497 }
 498
 499 // Table for initializing the "fcns" map
 500 struct fcn_init {
 501         const char *name;
 502         const fcn_desc desc;
 503 };
 504
 505 static const fcn_init builtin_fcns[] = {
 506         {"charpoly", fcn_desc(f_charpoly, 2)},
 507         {"coeff", fcn_desc(f_coeff, 3)},
 508         {"collect", fcn_desc(f_collect, 2)},
 509         {"content", fcn_desc(f_content, 2)},
 510         {"degree", fcn_desc(f_degree, 2)},
 511         {"denom", fcn_desc(f_denom, 1)},
 512         {"determinant", fcn_desc(f_determinant, 1)},
 513         {"diag", fcn_desc(f_diag, 0)},
 514         {"diff", fcn_desc(f_diff2, 2)},
 515         {"diff", fcn_desc(f_diff3, 3)},
 516         {"divide", fcn_desc(f_divide, 2)},
 517         {"eval", fcn_desc(f_eval1, 1)},
 518         {"eval", fcn_desc(f_eval2, 2)},
 519         {"evalf", fcn_desc(f_evalf1, 1)},
 520         {"evalf", fcn_desc(f_evalf2, 2)},
 521         {"expand", fcn_desc(f_expand, 1)},
 522         {"gcd", fcn_desc(f_gcd, 2)},
 523         {"has", fcn_desc(f_has, 2)},
 524         {"inverse", fcn_desc(f_inverse, 1)},
 525         {"is", fcn_desc(f_is, 1)},
 526         {"lcm", fcn_desc(f_lcm, 2)},
 527         {"lcoeff", fcn_desc(f_lcoeff, 2)},
 528         {"ldegree", fcn_desc(f_ldegree, 2)},
 529         {"lsolve", fcn_desc(f_lsolve, 2)},
 530         {"nops", fcn_desc(f_nops, 1)},
 531         {"normal", fcn_desc(f_normal1, 1)},
 532         {"normal", fcn_desc(f_normal2, 2)},
 533         {"numer", fcn_desc(f_numer, 1)},
 534         {"op", fcn_desc(f_op, 2)},
 535         {"pow", fcn_desc(f_pow, 2)},
 536         {"prem", fcn_desc(f_prem, 3)},
 537         {"primpart", fcn_desc(f_primpart, 2)},
 538         {"quo", fcn_desc(f_quo, 3)},
 539         {"rem", fcn_desc(f_rem, 3)},
 540         {"series", fcn_desc(f_series, 3)},
 541         {"sqrfree", fcn_desc(f_sqrfree1, 1)},
 542         {"sqrfree", fcn_desc(f_sqrfree2, 2)},
 543         {"sqrt", fcn_desc(f_sqrt, 1)},
 544         {"subs", fcn_desc(f_subs2, 2)},
 545         {"subs", fcn_desc(f_subs3, 3)},
 546         {"tcoeff", fcn_desc(f_tcoeff, 2)},
 547         {"time", fcn_desc(f_dummy, 0)},
 548         {"trace", fcn_desc(f_trace, 1)},
 549         {"transpose", fcn_desc(f_transpose, 1)},
 550         {"unassign", fcn_desc(f_unassign, 1)},
 551         {"unit", fcn_desc(f_unit, 2)},
 552         {NULL, fcn_desc(f_dummy, 0)}    // End marker
 553 };
 554
 555
 556 /*
 557  *  Add functions to ginsh
 558  */
 559
 560 // Functions from fcn_init array
 561 static void insert_fcns(const fcn_init *p)
 562 {
 563         while (p->name) {
 564                 fcns.insert(make_pair(string(p->name), p->desc));
 565                 p++;
 566         }
 567 }
 568
 569 static ex f_ginac_function(const exprseq &es, int serial)
 570 {
 571         return function(serial, es).eval(1);
 572 }
 573
 574 // All registered GiNaC functions
 575 void GiNaC::ginsh_get_ginac_functions(void)
 576 {
 577         vector<function_options>::const_iterator i = function::registered_functions().begin(), end = function::registered_functions().end();
 578         unsigned serial = 0;
 579         while (i != end) {
 580                 fcns.insert(make_pair(i->get_name(), fcn_desc(f_ginac_function, i->get_nparams(), serial)));
 581                 i++;
 582                 serial++;
 583         }
 584 }
 585
 586
 587 /*
 588  *  Find a function given a name and number of parameters. Throw exceptions on error.
 589  */
 590
 591 static fcn_tab::const_iterator find_function(const ex &sym, int req_params)
 592 {
 593         const string &name = ex_to_symbol(sym).getname();
 594         typedef fcn_tab::const_iterator I;
 595         pair<I, I> b = fcns.equal_range(name);
 596         if (b.first == b.second)
 597                 throw(std::logic_error("unknown function '" + name + "'"));
 598         else {
 599                 for (I i=b.first; i!=b.second; i++)
 600                         if ((i->second.num_params == 0) || (i->second.num_params == req_params))
 601                                 return i;
 602         }
 603         throw(std::logic_error("invalid number of arguments to " + name + "()"));
 604 }
 605
 606
 607 /*
 608  *  Insert help strings
 609  */
 610
 611 // Normal help string
 612 static void insert_help(const char *topic, const char *str)
 613 {
 614         help.insert(make_pair(string(topic), string(str)));
 615 }
 616
 617 // Help string for functions, automatically generates synopsis
 618 static void insert_fcn_help(const char *name, const char *str)
 619 {
 620         typedef fcn_tab::const_iterator I;
 621         pair<I, I> b = fcns.equal_range(name);
 622         if (b.first != b.second) {
 623                 string help_str = string(name) + "(";
 624                 for (int i=0; i<b.first->second.num_params; i++) {
 625                         if (i)
 626                                 help_str += ", ";
 627                         help_str += "expression";
 628                 }
 629                 help_str += ") - ";
 630                 help_str += str;
 631                 help.insert(make_pair(string(name), help_str));
 632         }
 633 }
 634
 635
 636 /*
 637  *  Print help to cout
 638  */
 639
 640 // Help for a given topic
 641 static void print_help(const string &topic)
 642 {
 643         typedef help_tab::const_iterator I;
 644         pair<I, I> b = help.equal_range(topic);
 645         if (b.first == b.second)
 646                 cout << "no help for '" << topic << "'\n";
 647         else {
 648                 for (I i=b.first; i!=b.second; i++)
 649                         cout << i->second << endl;
 650         }
 651 }
 652
 653 // List of help topics
 654 static void print_help_topics(void)
 655 {
 656         cout << "Available help topics:\n";
 657         help_tab::const_iterator i;
 658         string last_name = string("*");
 659         int num = 0;
 660         for (i=help.begin(); i!=help.end(); i++) {
 661                 // Don't print duplicates
 662                 if (i->first != last_name) {
 663                         if (num)
 664                                 cout << ", ";
 665                         num++;
 666                         cout << i->first;
 667                         last_name = i->first;
 668                 }
 669         }
 670         cout << "\nTo get help for a certain topic, type ?topic\n";
 671 }
 672
 673
 674 /*
 675  *  Function name completion functions for readline
 676  */
 677
 678 static char *fcn_generator(char *text, int state)
 679 {
 680         static int len;                         // Length of word to complete
 681         static fcn_tab::const_iterator index;   // Iterator to function being currently considered
 682
 683         // If this is a new word to complete, initialize now
 684         if (state == 0) {
 685                 index = fcns.begin();
 686                 len = strlen(text);
 687         }
 688
 689         // Return the next function which partially matches
 690         while (index != fcns.end()) {
 691                 const char *fcn_name = index->first.c_str();
 692                 index++;
 693                 if (strncmp(fcn_name, text, len) == 0)
 694                         return strdup(fcn_name);
 695         }
 696         return NULL;
 697 }
 698
 699 static char **fcn_completion(char *text, int start, int end)
 700 {
 701         if (rl_line_buffer[0] == '!') {
 702                 // For shell commands, revert back to filename completion
 703                 rl_completion_append_character = orig_completion_append_character;
 704                 rl_basic_word_break_characters = orig_basic_word_break_characters;
 705                 rl_completer_word_break_characters = rl_basic_word_break_characters;
 706                 return completion_matches(text, (CPFunction *)filename_completion_function);
 707         } else {
 708                 // Otherwise, complete function names
 709                 rl_completion_append_character = '(';
 710                 rl_basic_word_break_characters = " \t\n\"#$%&'()*+,-./:;<=>?@[\\]^`{|}~";
 711                 rl_completer_word_break_characters = rl_basic_word_break_characters;
 712                 return completion_matches(text, (CPFunction *)fcn_generator);
 713         }
 714 }
 715
 716 void greeting(void)
 717 {
 718     cout << "ginsh - GiNaC Interactive Shell (" << PACKAGE << " V" << VERSION << ")" << endl;
 719     cout << "  __,  _______  Copyright (C) 1999-2001 Johannes Gutenberg University Mainz,\n"
 720          << " (__) *       | Germany.  This is free software with ABSOLUTELY NO WARRANTY.\n"
 721          << "  ._) i N a C | You are welcome to redistribute it under certain conditions.\n"
 722          << "<-------------' For details type `warranty;'.\n" << endl;
 723     cout << "Type ?? for a list of help topics." << endl;
 724 }
 725
 726 /*
 727  *  Main program
 728  */
 729
 730 int main(int argc, char **argv)
 731 {
 732         // Print banner in interactive mode
 733         if (isatty(0))
 734                 greeting();
 735
 736         // Init function table
 737         insert_fcns(builtin_fcns);
 738         ginsh_get_ginac_functions();
 739
 740         // Init help for operators (automatically generated from man page)
 741         insert_help("operators", "Operators in falling order of precedence:");
 742 #include "ginsh_op_help.c"
 743
 744         // Init help for built-in functions (automatically generated from man page)
 745 #include "ginsh_fcn_help.c"
 746
 747         // Help for GiNaC functions is added manually
 748         insert_fcn_help("acos", "inverse cosine function");
 749         insert_fcn_help("acosh", "inverse hyperbolic cosine function");
 750         insert_fcn_help("asin", "inverse sine function");
 751         insert_fcn_help("asinh", "inverse hyperbolic sine function");
 752         insert_fcn_help("atan", "inverse tangent function");
 753         insert_fcn_help("atan2", "inverse tangent function with two arguments");
 754         insert_fcn_help("atanh", "inverse hyperbolic tangent function");
 755         insert_fcn_help("beta", "Beta function");
 756         insert_fcn_help("binomial", "binomial function");
 757         insert_fcn_help("cos", "cosine function");
 758         insert_fcn_help("cosh", "hyperbolic cosine function");
 759         insert_fcn_help("exp", "exponential function");
 760         insert_fcn_help("factorial", "factorial function");
 761         insert_fcn_help("lgamma", "natural logarithm of Gamma function");
 762         insert_fcn_help("tgamma", "Gamma function");
 763         insert_fcn_help("log", "natural logarithm");
 764         insert_fcn_help("psi", "psi function\npsi(x) is the digamma function, psi(n,x) the nth polygamma function");
 765         insert_fcn_help("sin", "sine function");
 766         insert_fcn_help("sinh", "hyperbolic sine function");
 767         insert_fcn_help("tan", "tangent function");
 768         insert_fcn_help("tanh", "hyperbolic tangent function");
 769         insert_fcn_help("zeta", "zeta function\nzeta(x) is Riemann's zeta function, zeta(n,x) its nth derivative");
 770         insert_fcn_help("Li2", "dilogarithm");
 771         insert_fcn_help("Li3", "trilogarithm");
 772         insert_fcn_help("Order", "order term function (for truncated power series)");
 773
 774         // Init readline completer
 775         rl_readline_name = argv[0];
 776         rl_attempted_completion_function = (CPPFunction *)fcn_completion;
 777         orig_completion_append_character = rl_completion_append_character;
 778         orig_basic_word_break_characters = rl_basic_word_break_characters;
 779
 780         // Init input file list, open first file
 781         num_files = argc - 1;
 782         file_list = argv + 1;
 783         if (num_files) {
 784                 yyin = fopen(*file_list, "r");
 785                 if (yyin == NULL) {
 786                         cerr << "Can't open " << *file_list << endl;
 787                         exit(1);
 788                 }
 789                 num_files--;
 790                 file_list++;
 791         }
 792
 793         // Parse input, catch all remaining exceptions
 794         int result;
 795 again:  try {
 796                 result = yyparse();
 797         } catch (exception &e) {
 798                 cerr << e.what() << endl;
 799                 goto again;
 800         }
 801         return result;
 802 }