ginsh/ginsh_parser.yy

   1 /** @file ginsh_parser.yy
   2  *
   3  *  Input grammar definition for ginsh.
   4  *  This file must be processed with yacc/bison. */
   5
   6 /*
   7  *  GiNaC Copyright (C) 1999-2001 Johannes Gutenberg University Mainz, Germany
   8  *
   9  *  This program is free software; you can redistribute it and/or modify
  10  *  it under the terms of the GNU General Public License as published by
  11  *  the Free Software Foundation; either version 2 of the License, or
  12  *  (at your option) any later version.
  13  *
  14  *  This program is distributed in the hope that it will be useful,
  15  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  *  GNU General Public License for more details.
  18  *
  19  *  You should have received a copy of the GNU General Public License
  20  *  along with this program; if not, write to the Free Software
  21  *  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  22  */
  23
  24
  25 /*
  26  *  Definitions
  27  */
  28
  29 %{
  30 #include "config.h"
  31
  32 #include <sys/resource.h>
  33
  34 #if HAVE_UNISTD_H
  35 #include <sys/types.h>
  36 #include <unistd.h>
  37 #endif
  38
  39 #include <stdexcept>
  40
  41 #include "ginsh.h"
  42
  43 #define YYERROR_VERBOSE 1
  44
  45 // Original readline settings
  46 static int orig_completion_append_character;
  47 #if (GINAC_RL_VERSION_MAJOR < 4) || (GINAC_RL_VERSION_MAJOR == 4 && GINAC_RL_VERSION_MINOR < 2)
  48 static char *orig_basic_word_break_characters;
  49 #else
  50 static const char *orig_basic_word_break_characters;
  51 #endif
  52
  53 // Expression stack for ", "" and """
  54 static void push(const ex &e);
  55 static ex exstack[3];
  56
  57 // Start and end time for the time() function
  58 static struct rusage start_time, end_time;
  59
  60 // Table of functions (a multimap, because one function may appear with different
  61 // numbers of parameters)
  62 typedef ex (*fcnp)(const exprseq &e);
  63 typedef ex (*fcnp2)(const exprseq &e, int serial);
  64
  65 struct fcn_desc {
  66         fcn_desc() : p(NULL), num_params(0) {}
  67         fcn_desc(fcnp func, int num) : p(func), num_params(num), is_ginac(false) {}
  68         fcn_desc(fcnp2 func, int num, int ser) : p((fcnp)func), num_params(num), is_ginac(true), serial(ser) {}
  69
  70         fcnp p;         // Pointer to function
  71         int num_params; // Number of parameters (0 = arbitrary)
  72         bool is_ginac;  // Flag: function is GiNaC function
  73         int serial;     // GiNaC function serial number (if is_ginac == true)
  74 };
  75
  76 typedef multimap<string, fcn_desc> fcn_tab;
  77 static fcn_tab fcns;
  78
  79 static fcn_tab::const_iterator find_function(const ex &sym, int req_params);
  80
  81 // Table to map help topics to help strings
  82 typedef multimap<string, string> help_tab;
  83 static help_tab help;
  84
  85 static void print_help(const string &topic);
  86 static void print_help_topics(void);
  87 %}
  88
  89 /* Tokens (T_LITERAL means a literal value returned by the parser, but not
  90    of class numeric or symbol (e.g. a constant or the FAIL object)) */
  91 %token T_NUMBER T_SYMBOL T_LITERAL T_DIGITS T_QUOTE T_QUOTE2 T_QUOTE3
  92 %token T_EQUAL T_NOTEQ T_LESSEQ T_GREATEREQ T_MATRIX_BEGIN T_MATRIX_END
  93
  94 %token T_QUIT T_WARRANTY T_PRINT T_IPRINT T_TIME T_XYZZY T_INVENTORY T_LOOK T_SCORE
  95
  96 /* Operator precedence and associativity */
  97 %right '='
  98 %left T_EQUAL T_NOTEQ
  99 %left '<' '>' T_LESSEQ T_GREATEREQ
 100 %left '+' '-'
 101 %left '*' '/' '%'
 102 %nonassoc NEG
 103 %right '^'
 104 %nonassoc '!'
 105
 106 %start input
 107
 108
 109 /*
 110  *  Grammar rules
 111  */
 112
 113 %%
 114 input   : /* empty */
 115         | input line
 116         ;
 117
 118 line    : ';'
 119         | exp ';' {
 120                 try {
 121                         cout << $1 << endl;
 122                         push($1);
 123                 } catch (exception &e) {
 124                         cerr << e.what() << endl;
 125                         YYERROR;
 126                 }
 127         }
 128         | exp ':' {
 129                 try {
 130                         push($1);
 131                 } catch (exception &e) {
 132                         std::cerr << e.what() << endl;
 133                         YYERROR;
 134                 }
 135         }
 136         | T_PRINT '(' exp ')' ';' {
 137                 try {
 138                         $3.print(print_tree(std::cout));
 139                 } catch (exception &e) {
 140                         std::cerr << e.what() << endl;
 141                         YYERROR;
 142                 }
 143         }
 144         | T_IPRINT '(' exp ')' ';' {
 145                 try {
 146                         ex e = $3;
 147                         if (!e.info(info_flags::integer))
 148                                 throw (std::invalid_argument("argument to iprint() must be an integer"));
 149                         long i = ex_to_numeric(e).to_long();
 150                         cout << i << endl;
 151                         cout << "#o" << oct << i << endl;
 152                         cout << "#x" << hex << i << dec << endl;
 153                 } catch (exception &e) {
 154                         cerr << e.what() << endl;
 155                         YYERROR;
 156                 }
 157         }
 158         | '?' T_SYMBOL          {print_help(ex_to_symbol($2).get_name());}
 159         | '?' T_TIME            {print_help("time");}
 160         | '?' '?'               {print_help_topics();}
 161         | T_QUIT                {YYACCEPT;}
 162         | T_WARRANTY {
 163                 cout << "This program is free software; you can redistribute it and/or modify it under\n";
 164                 cout << "the terms of the GNU General Public License as published by the Free Software\n";
 165                 cout << "Foundation; either version 2 of the License, or (at your option) any later\n";
 166                 cout << "version.\n";
 167                 cout << "This program is distributed in the hope that it will be useful, but WITHOUT\n";
 168                 cout << "ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS\n";
 169                 cout << "FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more\n";
 170                 cout << "details.\n";
 171                 cout << "You should have received a copy of the GNU General Public License along with\n";
 172                 cout << "this program. If not, write to the Free Software Foundation, 675 Mass Ave,\n";
 173                 cout << "Cambridge, MA 02139, USA.\n";
 174         }
 175         | T_XYZZY               {cout << "Nothing happens.\n";}
 176         | T_INVENTORY           {cout << "You're not carrying anything.\n";}
 177         | T_LOOK                {cout << "You're in a twisty little maze of passages, all alike.\n";}
 178         | T_SCORE {
 179                 cout << "If you were to quit now, you would score ";
 180                 cout << (syms.size() > 350 ? 350 : syms.size());
 181                 cout << " out of a possible 350.\n";
 182         }
 183         | T_TIME {getrusage(RUSAGE_SELF, &start_time);} '(' exp ')' {
 184                 getrusage(RUSAGE_SELF, &end_time);
 185                 cout << (end_time.ru_utime.tv_sec - start_time.ru_utime.tv_sec) +
 186                         (end_time.ru_stime.tv_sec - start_time.ru_stime.tv_sec) +
 187                          double(end_time.ru_utime.tv_usec - start_time.ru_utime.tv_usec) / 1e6 +
 188                          double(end_time.ru_stime.tv_usec - start_time.ru_stime.tv_usec) / 1e6 << 's' << endl;
 189         }
 190         | error ';'             {yyclearin; yyerrok;}
 191         | error ':'             {yyclearin; yyerrok;}
 192         ;
 193
 194 exp     : T_NUMBER              {$$ = $1;}
 195         | T_SYMBOL              {$$ = $1.eval();}
 196         | '\'' T_SYMBOL '\''    {$$ = $2;}
 197         | T_LITERAL             {$$ = $1;}
 198         | T_DIGITS              {$$ = $1;}
 199         | T_QUOTE               {$$ = exstack[0];}
 200         | T_QUOTE2              {$$ = exstack[1];}
 201         | T_QUOTE3              {$$ = exstack[2];}
 202         | T_SYMBOL '(' exprseq ')' {
 203                 fcn_tab::const_iterator i = find_function($1, $3.nops());
 204                 if (i->second.is_ginac) {
 205                         $$ = ((fcnp2)(i->second.p))(static_cast<const exprseq &>(*($3.bp)), i->second.serial);
 206                 } else {
 207                         $$ = (i->second.p)(static_cast<const exprseq &>(*($3.bp)));
 208                 }
 209         }
 210         | T_DIGITS '=' T_NUMBER {$$ = $3; Digits = ex_to_numeric($3).to_int();}
 211         | T_SYMBOL '=' exp      {$$ = $3; const_cast<symbol *>(&ex_to_symbol($1))->assign($3);}
 212         | exp T_EQUAL exp       {$$ = $1 == $3;}
 213         | exp T_NOTEQ exp       {$$ = $1 != $3;}
 214         | exp '<' exp           {$$ = $1 < $3;}
 215         | exp T_LESSEQ exp      {$$ = $1 <= $3;}
 216         | exp '>' exp           {$$ = $1 > $3;}
 217         | exp T_GREATEREQ exp   {$$ = $1 >= $3;}
 218         | exp '+' exp           {$$ = $1 + $3;}
 219         | exp '-' exp           {$$ = $1 - $3;}
 220         | exp '*' exp           {$$ = $1 * $3;}
 221         | exp '/' exp           {$$ = $1 / $3;}
 222         | '-' exp %prec NEG     {$$ = -$2;}
 223         | '+' exp %prec NEG     {$$ = $2;}
 224         | exp '^' exp           {$$ = power($1, $3);}
 225         | exp '!'               {$$ = factorial($1);}
 226         | '(' exp ')'           {$$ = $2;}
 227         | '[' list_or_empty ']' {$$ = $2;}
 228         | T_MATRIX_BEGIN matrix T_MATRIX_END    {$$ = lst_to_matrix(ex_to_lst($2));}
 229         ;
 230
 231 exprseq : exp                   {$$ = exprseq($1);}
 232         | exprseq ',' exp       {exprseq es(static_cast<exprseq &>(*($1.bp))); $$ = es.append($3);}
 233         ;
 234
 235 list_or_empty: /* empty */      {$$ = *new lst;}
 236         | list                  {$$ = $1;}
 237         ;
 238
 239 list    : exp                   {$$ = lst($1);}
 240         | list ',' exp          {lst l(static_cast<lst &>(*($1.bp))); $$ = l.append($3);}
 241         ;
 242
 243 matrix  : T_MATRIX_BEGIN row T_MATRIX_END               {$$ = lst($2);}
 244         | matrix ',' T_MATRIX_BEGIN row T_MATRIX_END    {lst l(static_cast<lst &>(*($1.bp))); $$ = l.append($4);}
 245         ;
 246
 247 row     : exp                   {$$ = lst($1);}
 248         | row ',' exp           {lst l(static_cast<lst &>(*($1.bp))); $$ = l.append($3);}
 249         ;
 250
 251
 252 /*
 253  *  Routines
 254  */
 255
 256 %%
 257 // Error print routine
 258 int yyerror(char *s)
 259 {
 260         cerr << s << " at " << yytext << endl;
 261         return 0;
 262 }
 263
 264 // Push expression "e" onto the expression stack (for ", "" and """)
 265 static void push(const ex &e)
 266 {
 267         exstack[2] = exstack[1];
 268         exstack[1] = exstack[0];
 269         exstack[0] = e;
 270 }
 271
 272
 273 /*
 274  *  Built-in functions
 275  */
 276
 277 static ex f_collect(const exprseq &e) {return e[0].collect(e[1]);}
 278 static ex f_collect_distributed(const exprseq &e) {return e[0].collect(e[1], true);}
 279 static ex f_degree(const exprseq &e) {return e[0].degree(e[1]);}
 280 static ex f_denom(const exprseq &e) {return e[0].denom();}
 281 static ex f_eval1(const exprseq &e) {return e[0].eval();}
 282 static ex f_evalf1(const exprseq &e) {return e[0].evalf();}
 283 static ex f_expand(const exprseq &e) {return e[0].expand();}
 284 static ex f_gcd(const exprseq &e) {return gcd(e[0], e[1]);}
 285 static ex f_has(const exprseq &e) {return e[0].has(e[1]) ? ex(1) : ex(0);}
 286 static ex f_lcm(const exprseq &e) {return lcm(e[0], e[1]);}
 287 static ex f_lcoeff(const exprseq &e) {return e[0].lcoeff(e[1]);}
 288 static ex f_ldegree(const exprseq &e) {return e[0].ldegree(e[1]);}
 289 static ex f_lsolve(const exprseq &e) {return lsolve(e[0], e[1]);}
 290 static ex f_nops(const exprseq &e) {return e[0].nops();}
 291 static ex f_normal1(const exprseq &e) {return e[0].normal();}
 292 static ex f_numer(const exprseq &e) {return e[0].numer();}
 293 static ex f_numer_denom(const exprseq &e) {return e[0].numer_denom();}
 294 static ex f_pow(const exprseq &e) {return pow(e[0], e[1]);}
 295 static ex f_sqrt(const exprseq &e) {return sqrt(e[0]);}
 296 static ex f_sqrfree1(const exprseq &e) {return sqrfree(e[0]);}
 297 static ex f_subs2(const exprseq &e) {return e[0].subs(e[1]);}
 298 static ex f_tcoeff(const exprseq &e) {return e[0].tcoeff(e[1]);}
 299
 300 #define CHECK_ARG(num, type, fcn) if (!is_ex_of_type(e[num], type)) throw(std::invalid_argument("argument " #num " to " #fcn "() must be a " #type))
 301
 302 static ex f_charpoly(const exprseq &e)
 303 {
 304         CHECK_ARG(0, matrix, charpoly);
 305         CHECK_ARG(1, symbol, charpoly);
 306         return ex_to_matrix(e[0]).charpoly(ex_to_symbol(e[1]));
 307 }
 308
 309 static ex f_coeff(const exprseq &e)
 310 {
 311         CHECK_ARG(2, numeric, coeff);
 312         return e[0].coeff(e[1], ex_to_numeric(e[2]).to_int());
 313 }
 314
 315 static ex f_content(const exprseq &e)
 316 {
 317         CHECK_ARG(1, symbol, content);
 318         return e[0].content(ex_to_symbol(e[1]));
 319 }
 320
 321 static ex f_determinant(const exprseq &e)
 322 {
 323         CHECK_ARG(0, matrix, determinant);
 324         return ex_to_matrix(e[0]).determinant();
 325 }
 326
 327 static ex f_diag(const exprseq &e)
 328 {
 329         unsigned dim = e.nops();
 330         matrix &m = *new matrix(dim, dim);
 331         for (unsigned i=0; i<dim; i++)
 332                 m.set(i, i, e.op(i));
 333         return m;
 334 }
 335
 336 static ex f_diff2(const exprseq &e)
 337 {
 338         CHECK_ARG(1, symbol, diff);
 339         return e[0].diff(ex_to_symbol(e[1]));
 340 }
 341
 342 static ex f_diff3(const exprseq &e)
 343 {
 344         CHECK_ARG(1, symbol, diff);
 345         CHECK_ARG(2, numeric, diff);
 346         return e[0].diff(ex_to_symbol(e[1]), ex_to_numeric(e[2]).to_int());
 347 }
 348
 349 static ex f_divide(const exprseq &e)
 350 {
 351         ex q;
 352         if (divide(e[0], e[1], q))
 353                 return q;
 354         else
 355                 return fail();
 356 }
 357
 358 static ex f_eval2(const exprseq &e)
 359 {
 360         CHECK_ARG(1, numeric, eval);
 361         return e[0].eval(ex_to_numeric(e[1]).to_int());
 362 }
 363
 364 static ex f_evalf2(const exprseq &e)
 365 {
 366         CHECK_ARG(1, numeric, evalf);
 367         return e[0].evalf(ex_to_numeric(e[1]).to_int());
 368 }
 369
 370 static ex f_inverse(const exprseq &e)
 371 {
 372         CHECK_ARG(0, matrix, inverse);
 373         return ex_to_matrix(e[0]).inverse();
 374 }
 375
 376 static ex f_is(const exprseq &e)
 377 {
 378         CHECK_ARG(0, relational, is);
 379         return (bool)ex_to_relational(e[0]) ? ex(1) : ex(0);
 380 }
 381
 382 static ex f_match(const exprseq &e)
 383 {
 384         lst repl_lst;
 385         if (e[0].match(e[1], repl_lst))
 386                 return repl_lst;
 387         else
 388                 return fail();
 389 }
 390
 391 static ex f_normal2(const exprseq &e)
 392 {
 393         CHECK_ARG(1, numeric, normal);
 394         return e[0].normal(ex_to_numeric(e[1]).to_int());
 395 }
 396
 397 static ex f_op(const exprseq &e)
 398 {
 399         CHECK_ARG(1, numeric, op);
 400         int n = ex_to_numeric(e[1]).to_int();
 401         if (n < 0 || n >= (int)e[0].nops())
 402                 throw(std::out_of_range("second argument to op() is out of range"));
 403         return e[0].op(n);
 404 }
 405
 406 static ex f_prem(const exprseq &e)
 407 {
 408         CHECK_ARG(2, symbol, prem);
 409         return prem(e[0], e[1], ex_to_symbol(e[2]));
 410 }
 411
 412 static ex f_primpart(const exprseq &e)
 413 {
 414         CHECK_ARG(1, symbol, primpart);
 415         return e[0].primpart(ex_to_symbol(e[1]));
 416 }
 417
 418 static ex f_quo(const exprseq &e)
 419 {
 420         CHECK_ARG(2, symbol, quo);
 421         return quo(e[0], e[1], ex_to_symbol(e[2]));
 422 }
 423
 424 static ex f_rem(const exprseq &e)
 425 {
 426         CHECK_ARG(2, symbol, rem);
 427         return rem(e[0], e[1], ex_to_symbol(e[2]));
 428 }
 429
 430 static ex f_series(const exprseq &e)
 431 {
 432         CHECK_ARG(2, numeric, series);
 433         return e[0].series(e[1], ex_to_numeric(e[2]).to_int());
 434 }
 435
 436 static ex f_sqrfree2(const exprseq &e)
 437 {
 438         CHECK_ARG(1, lst, sqrfree);
 439         return sqrfree(e[0], ex_to_lst(e[1]));
 440 }
 441
 442 static ex f_subs3(const exprseq &e)
 443 {
 444         CHECK_ARG(1, lst, subs);
 445         CHECK_ARG(2, lst, subs);
 446         return e[0].subs(ex_to_lst(e[1]), ex_to_lst(e[2]));
 447 }
 448
 449 static ex f_trace(const exprseq &e)
 450 {
 451         CHECK_ARG(0, matrix, trace);
 452         return ex_to_matrix(e[0]).trace();
 453 }
 454
 455 static ex f_transpose(const exprseq &e)
 456 {
 457         CHECK_ARG(0, matrix, transpose);
 458         return ex_to_matrix(e[0]).transpose();
 459 }
 460
 461 static ex f_unassign(const exprseq &e)
 462 {
 463         CHECK_ARG(0, symbol, unassign);
 464         (const_cast<symbol *>(&ex_to_symbol(e[0])))->unassign();
 465         return e[0];
 466 }
 467
 468 static ex f_unit(const exprseq &e)
 469 {
 470         CHECK_ARG(1, symbol, unit);
 471         return e[0].unit(ex_to_symbol(e[1]));
 472 }
 473
 474 static ex f_dummy(const exprseq &e)
 475 {
 476         throw(std::logic_error("dummy function called (shouldn't happen)"));
 477 }
 478
 479 // Table for initializing the "fcns" map
 480 struct fcn_init {
 481         const char *name;
 482         const fcn_desc desc;
 483 };
 484
 485 static const fcn_init builtin_fcns[] = {
 486         {"charpoly", fcn_desc(f_charpoly, 2)},
 487         {"coeff", fcn_desc(f_coeff, 3)},
 488         {"collect", fcn_desc(f_collect, 2)},
 489         {"collect_distributed", fcn_desc(f_collect_distributed, 2)},
 490         {"content", fcn_desc(f_content, 2)},
 491         {"degree", fcn_desc(f_degree, 2)},
 492         {"denom", fcn_desc(f_denom, 1)},
 493         {"determinant", fcn_desc(f_determinant, 1)},
 494         {"diag", fcn_desc(f_diag, 0)},
 495         {"diff", fcn_desc(f_diff2, 2)},
 496         {"diff", fcn_desc(f_diff3, 3)},
 497         {"divide", fcn_desc(f_divide, 2)},
 498         {"eval", fcn_desc(f_eval1, 1)},
 499         {"eval", fcn_desc(f_eval2, 2)},
 500         {"evalf", fcn_desc(f_evalf1, 1)},
 501         {"evalf", fcn_desc(f_evalf2, 2)},
 502         {"expand", fcn_desc(f_expand, 1)},
 503         {"gcd", fcn_desc(f_gcd, 2)},
 504         {"has", fcn_desc(f_has, 2)},
 505         {"inverse", fcn_desc(f_inverse, 1)},
 506         {"is", fcn_desc(f_is, 1)},
 507         {"lcm", fcn_desc(f_lcm, 2)},
 508         {"lcoeff", fcn_desc(f_lcoeff, 2)},
 509         {"ldegree", fcn_desc(f_ldegree, 2)},
 510         {"lsolve", fcn_desc(f_lsolve, 2)},
 511         {"match", fcn_desc(f_match, 2)},
 512         {"nops", fcn_desc(f_nops, 1)},
 513         {"normal", fcn_desc(f_normal1, 1)},
 514         {"normal", fcn_desc(f_normal2, 2)},
 515         {"numer", fcn_desc(f_numer, 1)},
 516         {"numer_denom", fcn_desc(f_numer_denom, 1)},
 517         {"op", fcn_desc(f_op, 2)},
 518         {"pow", fcn_desc(f_pow, 2)},
 519         {"prem", fcn_desc(f_prem, 3)},
 520         {"primpart", fcn_desc(f_primpart, 2)},
 521         {"quo", fcn_desc(f_quo, 3)},
 522         {"rem", fcn_desc(f_rem, 3)},
 523         {"series", fcn_desc(f_series, 3)},
 524         {"sqrfree", fcn_desc(f_sqrfree1, 1)},
 525         {"sqrfree", fcn_desc(f_sqrfree2, 2)},
 526         {"sqrt", fcn_desc(f_sqrt, 1)},
 527         {"subs", fcn_desc(f_subs2, 2)},
 528         {"subs", fcn_desc(f_subs3, 3)},
 529         {"tcoeff", fcn_desc(f_tcoeff, 2)},
 530         {"time", fcn_desc(f_dummy, 0)},
 531         {"trace", fcn_desc(f_trace, 1)},
 532         {"transpose", fcn_desc(f_transpose, 1)},
 533         {"unassign", fcn_desc(f_unassign, 1)},
 534         {"unit", fcn_desc(f_unit, 2)},
 535         {NULL, fcn_desc(f_dummy, 0)}    // End marker
 536 };
 537
 538
 539 /*
 540  *  Add functions to ginsh
 541  */
 542
 543 // Functions from fcn_init array
 544 static void insert_fcns(const fcn_init *p)
 545 {
 546         while (p->name) {
 547                 fcns.insert(make_pair(string(p->name), p->desc));
 548                 p++;
 549         }
 550 }
 551
 552 static ex f_ginac_function(const exprseq &es, int serial)
 553 {
 554         return function(serial, es).eval(1);
 555 }
 556
 557 // All registered GiNaC functions
 558 void GiNaC::ginsh_get_ginac_functions(void)
 559 {
 560         vector<function_options>::const_iterator i = function::registered_functions().begin(), end = function::registered_functions().end();
 561         unsigned serial = 0;
 562         while (i != end) {
 563                 fcns.insert(make_pair(i->get_name(), fcn_desc(f_ginac_function, i->get_nparams(), serial)));
 564                 i++;
 565                 serial++;
 566         }
 567 }
 568
 569
 570 /*
 571  *  Find a function given a name and number of parameters. Throw exceptions on error.
 572  */
 573
 574 static fcn_tab::const_iterator find_function(const ex &sym, int req_params)
 575 {
 576         const string &name = ex_to_symbol(sym).get_name();
 577         typedef fcn_tab::const_iterator I;
 578         pair<I, I> b = fcns.equal_range(name);
 579         if (b.first == b.second)
 580                 throw(std::logic_error("unknown function '" + name + "'"));
 581         else {
 582                 for (I i=b.first; i!=b.second; i++)
 583                         if ((i->second.num_params == 0) || (i->second.num_params == req_params))
 584                                 return i;
 585         }
 586         throw(std::logic_error("invalid number of arguments to " + name + "()"));
 587 }
 588
 589
 590 /*
 591  *  Insert help strings
 592  */
 593
 594 // Normal help string
 595 static void insert_help(const char *topic, const char *str)
 596 {
 597         help.insert(make_pair(string(topic), string(str)));
 598 }
 599
 600 // Help string for functions, automatically generates synopsis
 601 static void insert_fcn_help(const char *name, const char *str)
 602 {
 603         typedef fcn_tab::const_iterator I;
 604         pair<I, I> b = fcns.equal_range(name);
 605         if (b.first != b.second) {
 606                 string help_str = string(name) + "(";
 607                 for (int i=0; i<b.first->second.num_params; i++) {
 608                         if (i)
 609                                 help_str += ", ";
 610                         help_str += "expression";
 611                 }
 612                 help_str += ") - ";
 613                 help_str += str;
 614                 help.insert(make_pair(string(name), help_str));
 615         }
 616 }
 617
 618
 619 /*
 620  *  Print help to cout
 621  */
 622
 623 // Help for a given topic
 624 static void print_help(const string &topic)
 625 {
 626         typedef help_tab::const_iterator I;
 627         pair<I, I> b = help.equal_range(topic);
 628         if (b.first == b.second)
 629                 cout << "no help for '" << topic << "'\n";
 630         else {
 631                 for (I i=b.first; i!=b.second; i++)
 632                         cout << i->second << endl;
 633         }
 634 }
 635
 636 // List of help topics
 637 static void print_help_topics(void)
 638 {
 639         cout << "Available help topics:\n";
 640         help_tab::const_iterator i;
 641         string last_name = string("*");
 642         int num = 0;
 643         for (i=help.begin(); i!=help.end(); i++) {
 644                 // Don't print duplicates
 645                 if (i->first != last_name) {
 646                         if (num)
 647                                 cout << ", ";
 648                         num++;
 649                         cout << i->first;
 650                         last_name = i->first;
 651                 }
 652         }
 653         cout << "\nTo get help for a certain topic, type ?topic\n";
 654 }
 655
 656
 657 /*
 658  *  Function name completion functions for readline
 659  */
 660
 661 static char *fcn_generator(char *text, int state)
 662 {
 663         static int len;                         // Length of word to complete
 664         static fcn_tab::const_iterator index;   // Iterator to function being currently considered
 665
 666         // If this is a new word to complete, initialize now
 667         if (state == 0) {
 668                 index = fcns.begin();
 669                 len = strlen(text);
 670         }
 671
 672         // Return the next function which partially matches
 673         while (index != fcns.end()) {
 674                 const char *fcn_name = index->first.c_str();
 675                 index++;
 676                 if (strncmp(fcn_name, text, len) == 0)
 677                         return strdup(fcn_name);
 678         }
 679         return NULL;
 680 }
 681
 682 static char **fcn_completion(char *text, int start, int end)
 683 {
 684         if (rl_line_buffer[0] == '!') {
 685                 // For shell commands, revert back to filename completion
 686                 rl_completion_append_character = orig_completion_append_character;
 687                 rl_basic_word_break_characters = orig_basic_word_break_characters;
 688                 rl_completer_word_break_characters = rl_basic_word_break_characters;
 689 #if (GINAC_RL_VERSION_MAJOR < 4) || (GINAC_RL_VERSION_MAJOR == 4 && GINAC_RL_VERSION_MINOR < 2)
 690                 return completion_matches(text, (CPFunction *)filename_completion_function);
 691 #else
 692                 return rl_completion_matches(text, (CPFunction *)rl_filename_completion_function);
 693 #endif
 694         } else {
 695                 // Otherwise, complete function names
 696                 rl_completion_append_character = '(';
 697                 rl_basic_word_break_characters = " \t\n\"#$%&'()*+,-./:;<=>?@[\\]^`{|}~";
 698                 rl_completer_word_break_characters = rl_basic_word_break_characters;
 699 #if (GINAC_RL_VERSION_MAJOR < 4) || (GINAC_RL_VERSION_MAJOR == 4 && GINAC_RL_VERSION_MINOR < 2)
 700                 return completion_matches(text, (CPFunction *)fcn_generator);
 701 #else
 702                 return rl_completion_matches(text, (CPFunction *)fcn_generator);
 703 #endif
 704         }
 705 }
 706
 707 void greeting(void)
 708 {
 709     cout << "ginsh - GiNaC Interactive Shell (" << PACKAGE << " V" << VERSION << ")" << endl;
 710     cout << "  __,  _______  Copyright (C) 1999-2001 Johannes Gutenberg University Mainz,\n"
 711          << " (__) *       | Germany.  This is free software with ABSOLUTELY NO WARRANTY.\n"
 712          << "  ._) i N a C | You are welcome to redistribute it under certain conditions.\n"
 713          << "<-------------' For details type `warranty;'.\n" << endl;
 714     cout << "Type ?? for a list of help topics." << endl;
 715 }
 716
 717 /*
 718  *  Main program
 719  */
 720
 721 int main(int argc, char **argv)
 722 {
 723         // Print banner in interactive mode
 724         if (isatty(0))
 725                 greeting();
 726
 727         // Init function table
 728         insert_fcns(builtin_fcns);
 729         ginsh_get_ginac_functions();
 730
 731         // Init help for operators (automatically generated from man page)
 732         insert_help("operators", "Operators in falling order of precedence:");
 733 #include "ginsh_op_help.c"
 734
 735         // Init help for built-in functions (automatically generated from man page)
 736 #include "ginsh_fcn_help.c"
 737
 738         // Help for GiNaC functions is added manually
 739         insert_fcn_help("acos", "inverse cosine function");
 740         insert_fcn_help("acosh", "inverse hyperbolic cosine function");
 741         insert_fcn_help("asin", "inverse sine function");
 742         insert_fcn_help("asinh", "inverse hyperbolic sine function");
 743         insert_fcn_help("atan", "inverse tangent function");
 744         insert_fcn_help("atan2", "inverse tangent function with two arguments");
 745         insert_fcn_help("atanh", "inverse hyperbolic tangent function");
 746         insert_fcn_help("beta", "Beta function");
 747         insert_fcn_help("binomial", "binomial function");
 748         insert_fcn_help("cos", "cosine function");
 749         insert_fcn_help("cosh", "hyperbolic cosine function");
 750         insert_fcn_help("exp", "exponential function");
 751         insert_fcn_help("factorial", "factorial function");
 752         insert_fcn_help("lgamma", "natural logarithm of Gamma function");
 753         insert_fcn_help("tgamma", "Gamma function");
 754         insert_fcn_help("log", "natural logarithm");
 755         insert_fcn_help("psi", "psi function\npsi(x) is the digamma function, psi(n,x) the nth polygamma function");
 756         insert_fcn_help("sin", "sine function");
 757         insert_fcn_help("sinh", "hyperbolic sine function");
 758         insert_fcn_help("tan", "tangent function");
 759         insert_fcn_help("tanh", "hyperbolic tangent function");
 760         insert_fcn_help("zeta", "zeta function\nzeta(x) is Riemann's zeta function, zeta(n,x) its nth derivative");
 761         insert_fcn_help("Li2", "dilogarithm");
 762         insert_fcn_help("Li3", "trilogarithm");
 763         insert_fcn_help("Order", "order term function (for truncated power series)");
 764
 765         // Init readline completer
 766         rl_readline_name = argv[0];
 767         rl_attempted_completion_function = (CPPFunction *)fcn_completion;
 768         orig_completion_append_character = rl_completion_append_character;
 769         orig_basic_word_break_characters = rl_basic_word_break_characters;
 770
 771         // Init input file list, open first file
 772         num_files = argc - 1;
 773         file_list = argv + 1;
 774         if (num_files) {
 775                 yyin = fopen(*file_list, "r");
 776                 if (yyin == NULL) {
 777                         cerr << "Can't open " << *file_list << endl;
 778                         exit(1);
 779                 }
 780                 num_files--;
 781                 file_list++;
 782         }
 783
 784         // Parse input, catch all remaining exceptions
 785         int result;
 786 again:  try {
 787                 result = yyparse();
 788         } catch (exception &e) {
 789                 cerr << e.what() << endl;
 790                 goto again;
 791         }
 792         return result;
 793 }