ginsh/ginsh_parser.yy

   1 /** @file ginsh_parser.yy
   2  *
   3  *  Input grammar definition for ginsh.
   4  *  This file must be processed with yacc/bison. */
   5
   6 /*
   7  *  GiNaC Copyright (C) 1999-2003 Johannes Gutenberg University Mainz, Germany
   8  *
   9  *  This program is free software; you can redistribute it and/or modify
  10  *  it under the terms of the GNU General Public License as published by
  11  *  the Free Software Foundation; either version 2 of the License, or
  12  *  (at your option) any later version.
  13  *
  14  *  This program is distributed in the hope that it will be useful,
  15  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  *  GNU General Public License for more details.
  18  *
  19  *  You should have received a copy of the GNU General Public License
  20  *  along with this program; if not, write to the Free Software
  21  *  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  22  */
  23
  24
  25 /*
  26  *  Definitions
  27  */
  28
  29 %{
  30 #include "config.h"
  31
  32 #include <sys/resource.h>
  33
  34 #if HAVE_UNISTD_H
  35 #include <sys/types.h>
  36 #include <unistd.h>
  37 #endif
  38
  39 #include <stdexcept>
  40
  41 #include "ginsh.h"
  42
  43 #define YYERROR_VERBOSE 1
  44
  45 // Original readline settings
  46 static int orig_completion_append_character;
  47 #if (GINAC_RL_VERSION_MAJOR < 4) || (GINAC_RL_VERSION_MAJOR == 4 && GINAC_RL_VERSION_MINOR < 2)
  48 static char *orig_basic_word_break_characters;
  49 #else
  50 static const char *orig_basic_word_break_characters;
  51 #endif
  52
  53 // Expression stack for ", "" and """
  54 static void push(const ex &e);
  55 static ex exstack[3];
  56
  57 // Start and end time for the time() function
  58 static struct rusage start_time, end_time;
  59
  60 // Table of functions (a multimap, because one function may appear with different
  61 // numbers of parameters)
  62 typedef ex (*fcnp)(const exprseq &e);
  63 typedef ex (*fcnp2)(const exprseq &e, int serial);
  64
  65 struct fcn_desc {
  66         fcn_desc() : p(NULL), num_params(0), is_ginac(false), serial(0) {}
  67         fcn_desc(fcnp func, int num) : p(func), num_params(num), is_ginac(false), serial(0) {}
  68         fcn_desc(fcnp2 func, int num, int ser) : p((fcnp)func), num_params(num), is_ginac(true), serial(ser) {}
  69
  70         fcnp p;         // Pointer to function
  71         int num_params; // Number of parameters (0 = arbitrary)
  72         bool is_ginac;  // Flag: function is GiNaC function
  73         int serial;     // GiNaC function serial number (if is_ginac == true)
  74 };
  75
  76 typedef multimap<string, fcn_desc> fcn_tab;
  77 static fcn_tab fcns;
  78
  79 static fcn_tab::const_iterator find_function(const ex &sym, int req_params);
  80
  81 // Table to map help topics to help strings
  82 typedef multimap<string, string> help_tab;
  83 static help_tab help;
  84
  85 static void insert_fcn_help(const char *name, const char *str);
  86 static void print_help(const string &topic);
  87 static void print_help_topics(void);
  88 %}
  89
  90 /* Tokens (T_LITERAL means a literal value returned by the parser, but not
  91    of class numeric or symbol (e.g. a constant or the FAIL object)) */
  92 %token T_NUMBER T_SYMBOL T_LITERAL T_DIGITS T_QUOTE T_QUOTE2 T_QUOTE3
  93 %token T_EQUAL T_NOTEQ T_LESSEQ T_GREATEREQ
  94
  95 %token T_QUIT T_WARRANTY T_PRINT T_IPRINT T_PRINTLATEX T_PRINTCSRC T_TIME
  96 %token T_XYZZY T_INVENTORY T_LOOK T_SCORE
  97
  98 /* Operator precedence and associativity */
  99 %right '='
 100 %left T_EQUAL T_NOTEQ
 101 %left '<' '>' T_LESSEQ T_GREATEREQ
 102 %left '+' '-'
 103 %left '*' '/'
 104 %nonassoc NEG
 105 %right '^'
 106 %nonassoc '!'
 107
 108 %start input
 109
 110
 111 /*
 112  *  Grammar rules
 113  */
 114
 115 %%
 116 input   : /* empty */
 117         | input line
 118         ;
 119
 120 line    : ';'
 121         | exp ';' {
 122                 try {
 123                         cout << $1 << endl;
 124                         push($1);
 125                 } catch (exception &e) {
 126                         cerr << e.what() << endl;
 127                         YYERROR;
 128                 }
 129         }
 130         | exp ':' {
 131                 try {
 132                         push($1);
 133                 } catch (exception &e) {
 134                         std::cerr << e.what() << endl;
 135                         YYERROR;
 136                 }
 137         }
 138         | T_PRINT '(' exp ')' ';' {
 139                 try {
 140                         $3.print(print_tree(std::cout));
 141                 } catch (exception &e) {
 142                         std::cerr << e.what() << endl;
 143                         YYERROR;
 144                 }
 145         }
 146         | T_IPRINT '(' exp ')' ';' {
 147                 try {
 148                         ex e = $3;
 149                         if (!e.info(info_flags::integer))
 150                                 throw (std::invalid_argument("argument to iprint() must be an integer"));
 151                         long i = ex_to<numeric>(e).to_long();
 152                         cout << i << endl;
 153                         cout << "#o" << oct << i << endl;
 154                         cout << "#x" << hex << i << dec << endl;
 155                 } catch (exception &e) {
 156                         cerr << e.what() << endl;
 157                         YYERROR;
 158                 }
 159         }
 160         | T_PRINTLATEX '(' exp ')' ';' {
 161                 try {
 162                         $3.print(print_latex(std::cout)); cout << endl;
 163                 } catch (exception &e) {
 164                         std::cerr << e.what() << endl;
 165                         YYERROR;
 166                 }
 167         }
 168         | T_PRINTCSRC '(' exp ')' ';' {
 169                 try {
 170                         $3.print(print_csrc_double(std::cout)); cout << endl;
 171                 } catch (exception &e) {
 172                         std::cerr << e.what() << endl;
 173                         YYERROR;
 174                 }
 175         }
 176         | '?' T_SYMBOL          {print_help(ex_to<symbol>($2).get_name());}
 177         | '?' T_TIME            {print_help("time");}
 178         | '?' '?'               {print_help_topics();}
 179         | T_QUIT                {YYACCEPT;}
 180         | T_WARRANTY {
 181                 cout << "This program is free software; you can redistribute it and/or modify it under\n";
 182                 cout << "the terms of the GNU General Public License as published by the Free Software\n";
 183                 cout << "Foundation; either version 2 of the License, or (at your option) any later\n";
 184                 cout << "version.\n";
 185                 cout << "This program is distributed in the hope that it will be useful, but WITHOUT\n";
 186                 cout << "ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS\n";
 187                 cout << "FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more\n";
 188                 cout << "details.\n";
 189                 cout << "You should have received a copy of the GNU General Public License along with\n";
 190                 cout << "this program. If not, write to the Free Software Foundation, 675 Mass Ave,\n";
 191                 cout << "Cambridge, MA 02139, USA.\n";
 192         }
 193         | T_XYZZY               {cout << "Nothing happens.\n";}
 194         | T_INVENTORY           {cout << "You're not carrying anything.\n";}
 195         | T_LOOK                {cout << "You're in a twisty little maze of passages, all alike.\n";}
 196         | T_SCORE {
 197                 cout << "If you were to quit now, you would score ";
 198                 cout << (syms.size() > 350 ? 350 : syms.size());
 199                 cout << " out of a possible 350.\n";
 200         }
 201         | T_TIME {getrusage(RUSAGE_SELF, &start_time);} '(' exp ')' {
 202                 getrusage(RUSAGE_SELF, &end_time);
 203                 cout << (end_time.ru_utime.tv_sec - start_time.ru_utime.tv_sec) +
 204                         (end_time.ru_stime.tv_sec - start_time.ru_stime.tv_sec) +
 205                          double(end_time.ru_utime.tv_usec - start_time.ru_utime.tv_usec) / 1e6 +
 206                          double(end_time.ru_stime.tv_usec - start_time.ru_stime.tv_usec) / 1e6 << 's' << endl;
 207         }
 208         | error ';'             {yyclearin; yyerrok;}
 209         | error ':'             {yyclearin; yyerrok;}
 210         ;
 211
 212 exp     : T_NUMBER              {$$ = $1;}
 213         | T_SYMBOL              {$$ = $1.eval();}
 214         | '\'' T_SYMBOL '\''    {$$ = $2;}
 215         | T_LITERAL             {$$ = $1;}
 216         | T_DIGITS              {$$ = $1;}
 217         | T_QUOTE               {$$ = exstack[0];}
 218         | T_QUOTE2              {$$ = exstack[1];}
 219         | T_QUOTE3              {$$ = exstack[2];}
 220         | T_SYMBOL '(' exprseq ')' {
 221                 fcn_tab::const_iterator i = find_function($1, $3.nops());
 222                 if (i->second.is_ginac) {
 223                         $$ = ((fcnp2)(i->second.p))(ex_to<exprseq>($3), i->second.serial);
 224                 } else {
 225                         $$ = (i->second.p)(ex_to<exprseq>($3));
 226                 }
 227         }
 228         | T_DIGITS '=' T_NUMBER {$$ = $3; Digits = ex_to<numeric>($3).to_int();}
 229         | T_SYMBOL '=' exp      {$$ = $3; const_cast<symbol&>(ex_to<symbol>($1)).assign($3);}
 230         | exp T_EQUAL exp       {$$ = $1 == $3;}
 231         | exp T_NOTEQ exp       {$$ = $1 != $3;}
 232         | exp '<' exp           {$$ = $1 < $3;}
 233         | exp T_LESSEQ exp      {$$ = $1 <= $3;}
 234         | exp '>' exp           {$$ = $1 > $3;}
 235         | exp T_GREATEREQ exp   {$$ = $1 >= $3;}
 236         | exp '+' exp           {$$ = $1 + $3;}
 237         | exp '-' exp           {$$ = $1 - $3;}
 238         | exp '*' exp           {$$ = $1 * $3;}
 239         | exp '/' exp           {$$ = $1 / $3;}
 240         | '-' exp %prec NEG     {$$ = -$2;}
 241         | '+' exp %prec NEG     {$$ = $2;}
 242         | exp '^' exp           {$$ = power($1, $3);}
 243         | exp '!'               {$$ = factorial($1);}
 244         | '(' exp ')'           {$$ = $2;}
 245         | '{' list_or_empty '}' {$$ = $2;}
 246         | '[' matrix ']'        {$$ = lst_to_matrix(ex_to<lst>($2));}
 247         ;
 248
 249 exprseq : exp                   {$$ = exprseq($1);}
 250         | exprseq ',' exp       {exprseq es(ex_to<exprseq>($1)); $$ = es.append($3);}
 251         ;
 252
 253 list_or_empty: /* empty */      {$$ = *new lst;}
 254         | list                  {$$ = $1;}
 255         ;
 256
 257 list    : exp                   {$$ = lst($1);}
 258         | list ',' exp          {lst l(ex_to<lst>($1)); $$ = l.append($3);}
 259         ;
 260
 261 matrix  : '[' row ']'           {$$ = lst($2);}
 262         | matrix ',' '[' row ']' {lst l(ex_to<lst>($1)); $$ = l.append($4);}
 263         ;
 264
 265 row     : exp                   {$$ = lst($1);}
 266         | row ',' exp           {lst l(ex_to<lst>($1)); $$ = l.append($3);}
 267         ;
 268
 269
 270 /*
 271  *  Routines
 272  */
 273
 274 %%
 275 // Error print routine
 276 int yyerror(char *s)
 277 {
 278         cerr << s << " at " << yytext << endl;
 279         return 0;
 280 }
 281
 282 // Push expression "e" onto the expression stack (for ", "" and """)
 283 static void push(const ex &e)
 284 {
 285         exstack[2] = exstack[1];
 286         exstack[1] = exstack[0];
 287         exstack[0] = e;
 288 }
 289
 290
 291 /*
 292  *  Built-in functions
 293  */
 294
 295 static ex f_collect(const exprseq &e) {return e[0].collect(e[1]);}
 296 static ex f_collect_distributed(const exprseq &e) {return e[0].collect(e[1], true);}
 297 static ex f_collect_common_factors(const exprseq &e) {return collect_common_factors(e[0]);}
 298 static ex f_degree(const exprseq &e) {return e[0].degree(e[1]);}
 299 static ex f_denom(const exprseq &e) {return e[0].denom();}
 300 static ex f_eval1(const exprseq &e) {return e[0].eval();}
 301 static ex f_evalf1(const exprseq &e) {return e[0].evalf();}
 302 static ex f_evalm(const exprseq &e) {return e[0].evalm();}
 303 static ex f_expand(const exprseq &e) {return e[0].expand();}
 304 static ex f_gcd(const exprseq &e) {return gcd(e[0], e[1]);}
 305 static ex f_has(const exprseq &e) {return e[0].has(e[1]) ? ex(1) : ex(0);}
 306 static ex f_lcm(const exprseq &e) {return lcm(e[0], e[1]);}
 307 static ex f_lcoeff(const exprseq &e) {return e[0].lcoeff(e[1]);}
 308 static ex f_ldegree(const exprseq &e) {return e[0].ldegree(e[1]);}
 309 static ex f_lsolve(const exprseq &e) {return lsolve(e[0], e[1]);}
 310 static ex f_nops(const exprseq &e) {return e[0].nops();}
 311 static ex f_normal1(const exprseq &e) {return e[0].normal();}
 312 static ex f_numer(const exprseq &e) {return e[0].numer();}
 313 static ex f_numer_denom(const exprseq &e) {return e[0].numer_denom();}
 314 static ex f_pow(const exprseq &e) {return pow(e[0], e[1]);}
 315 static ex f_sqrt(const exprseq &e) {return sqrt(e[0]);}
 316 static ex f_sqrfree1(const exprseq &e) {return sqrfree(e[0]);}
 317 static ex f_subs2(const exprseq &e) {return e[0].subs(e[1]);}
 318 static ex f_tcoeff(const exprseq &e) {return e[0].tcoeff(e[1]);}
 319
 320 #define CHECK_ARG(num, type, fcn) if (!is_a<type>(e[num])) throw(std::invalid_argument("argument " #num " to " #fcn "() must be a " #type))
 321
 322 static ex f_charpoly(const exprseq &e)
 323 {
 324         CHECK_ARG(0, matrix, charpoly);
 325         CHECK_ARG(1, symbol, charpoly);
 326         return ex_to<matrix>(e[0]).charpoly(ex_to<symbol>(e[1]));
 327 }
 328
 329 static ex f_coeff(const exprseq &e)
 330 {
 331         CHECK_ARG(2, numeric, coeff);
 332         return e[0].coeff(e[1], ex_to<numeric>(e[2]).to_int());
 333 }
 334
 335 static ex f_content(const exprseq &e)
 336 {
 337         CHECK_ARG(1, symbol, content);
 338         return e[0].content(ex_to<symbol>(e[1]));
 339 }
 340
 341 static ex f_decomp_rational(const exprseq &e)
 342 {
 343         CHECK_ARG(1, symbol, decomp_rational);
 344         return decomp_rational(e[0], ex_to<symbol>(e[1]));
 345 }
 346
 347 static ex f_determinant(const exprseq &e)
 348 {
 349         CHECK_ARG(0, matrix, determinant);
 350         return ex_to<matrix>(e[0]).determinant();
 351 }
 352
 353 static ex f_diag(const exprseq &e)
 354 {
 355         unsigned dim = e.nops();
 356         matrix &m = *new matrix(dim, dim);
 357         for (unsigned i=0; i<dim; i++)
 358                 m.set(i, i, e.op(i));
 359         return m;
 360 }
 361
 362 static ex f_diff2(const exprseq &e)
 363 {
 364         CHECK_ARG(1, symbol, diff);
 365         return e[0].diff(ex_to<symbol>(e[1]));
 366 }
 367
 368 static ex f_diff3(const exprseq &e)
 369 {
 370         CHECK_ARG(1, symbol, diff);
 371         CHECK_ARG(2, numeric, diff);
 372         return e[0].diff(ex_to<symbol>(e[1]), ex_to<numeric>(e[2]).to_int());
 373 }
 374
 375 static ex f_divide(const exprseq &e)
 376 {
 377         ex q;
 378         if (divide(e[0], e[1], q))
 379                 return q;
 380         else
 381                 return fail();
 382 }
 383
 384 static ex f_eval2(const exprseq &e)
 385 {
 386         CHECK_ARG(1, numeric, eval);
 387         return e[0].eval(ex_to<numeric>(e[1]).to_int());
 388 }
 389
 390 static ex f_evalf2(const exprseq &e)
 391 {
 392         CHECK_ARG(1, numeric, evalf);
 393         return e[0].evalf(ex_to<numeric>(e[1]).to_int());
 394 }
 395
 396 static ex f_find(const exprseq &e)
 397 {
 398         lst found;
 399         e[0].find(e[1], found);
 400         return found;
 401 }
 402
 403 static ex f_inverse(const exprseq &e)
 404 {
 405         CHECK_ARG(0, matrix, inverse);
 406         return ex_to<matrix>(e[0]).inverse();
 407 }
 408
 409 static ex f_is(const exprseq &e)
 410 {
 411         CHECK_ARG(0, relational, is);
 412         return (bool)ex_to<relational>(e[0]) ? ex(1) : ex(0);
 413 }
 414
 415 class apply_map_function : public map_function {
 416         ex apply;
 417 public:
 418         apply_map_function(const ex & a) : apply(a) {}
 419         virtual ~apply_map_function() {}
 420         ex operator()(const ex & e) { return apply.subs(wild() == e, true); }
 421 };
 422
 423 static ex f_map(const exprseq &e)
 424 {
 425         apply_map_function fcn(e[1]);
 426         return e[0].map(fcn);
 427 }
 428
 429 static ex f_match(const exprseq &e)
 430 {
 431         lst repl_lst;
 432         if (e[0].match(e[1], repl_lst))
 433                 return repl_lst;
 434         else
 435                 return fail();
 436 }
 437
 438 static ex f_normal2(const exprseq &e)
 439 {
 440         CHECK_ARG(1, numeric, normal);
 441         return e[0].normal(ex_to<numeric>(e[1]).to_int());
 442 }
 443
 444 static ex f_op(const exprseq &e)
 445 {
 446         CHECK_ARG(1, numeric, op);
 447         int n = ex_to<numeric>(e[1]).to_int();
 448         if (n < 0 || n >= (int)e[0].nops())
 449                 throw(std::out_of_range("second argument to op() is out of range"));
 450         return e[0].op(n);
 451 }
 452
 453 static ex f_prem(const exprseq &e)
 454 {
 455         CHECK_ARG(2, symbol, prem);
 456         return prem(e[0], e[1], ex_to<symbol>(e[2]));
 457 }
 458
 459 static ex f_primpart(const exprseq &e)
 460 {
 461         CHECK_ARG(1, symbol, primpart);
 462         return e[0].primpart(ex_to<symbol>(e[1]));
 463 }
 464
 465 static ex f_quo(const exprseq &e)
 466 {
 467         CHECK_ARG(2, symbol, quo);
 468         return quo(e[0], e[1], ex_to<symbol>(e[2]));
 469 }
 470
 471 static ex f_rem(const exprseq &e)
 472 {
 473         CHECK_ARG(2, symbol, rem);
 474         return rem(e[0], e[1], ex_to<symbol>(e[2]));
 475 }
 476
 477 static ex f_series(const exprseq &e)
 478 {
 479         CHECK_ARG(2, numeric, series);
 480         return e[0].series(e[1], ex_to<numeric>(e[2]).to_int());
 481 }
 482
 483 static ex f_sprem(const exprseq &e)
 484 {
 485         CHECK_ARG(2, symbol, sprem);
 486         return sprem(e[0], e[1], ex_to<symbol>(e[2]));
 487 }
 488
 489 static ex f_sqrfree2(const exprseq &e)
 490 {
 491         CHECK_ARG(1, lst, sqrfree);
 492         return sqrfree(e[0], ex_to<lst>(e[1]));
 493 }
 494
 495 static ex f_subs3(const exprseq &e)
 496 {
 497         CHECK_ARG(1, lst, subs);
 498         CHECK_ARG(2, lst, subs);
 499         return e[0].subs(ex_to<lst>(e[1]), ex_to<lst>(e[2]));
 500 }
 501
 502 static ex f_trace(const exprseq &e)
 503 {
 504         CHECK_ARG(0, matrix, trace);
 505         return ex_to<matrix>(e[0]).trace();
 506 }
 507
 508 static ex f_transpose(const exprseq &e)
 509 {
 510         CHECK_ARG(0, matrix, transpose);
 511         return ex_to<matrix>(e[0]).transpose();
 512 }
 513
 514 static ex f_unassign(const exprseq &e)
 515 {
 516         CHECK_ARG(0, symbol, unassign);
 517         const_cast<symbol&>(ex_to<symbol>(e[0])).unassign();
 518         return e[0];
 519 }
 520
 521 static ex f_unit(const exprseq &e)
 522 {
 523         CHECK_ARG(1, symbol, unit);
 524         return e[0].unit(ex_to<symbol>(e[1]));
 525 }
 526
 527 static ex f_dummy(const exprseq &e)
 528 {
 529         throw(std::logic_error("dummy function called (shouldn't happen)"));
 530 }
 531
 532 // Tables for initializing the "fcns" map and the function help topics
 533 struct fcn_init {
 534         const char *name;
 535         fcnp p;
 536         int num_params;
 537 };
 538
 539 static const fcn_init builtin_fcns[] = {
 540         {"charpoly", f_charpoly, 2},
 541         {"coeff", f_coeff, 3},
 542         {"collect", f_collect, 2},
 543         {"collect_common_factors", f_collect_common_factors, 1},
 544         {"collect_distributed", f_collect_distributed, 2},
 545         {"content", f_content, 2},
 546         {"decomp_rational", f_decomp_rational, 2},
 547         {"degree", f_degree, 2},
 548         {"denom", f_denom, 1},
 549         {"determinant", f_determinant, 1},
 550         {"diag", f_diag, 0},
 551         {"diff", f_diff2, 2},
 552         {"diff", f_diff3, 3},
 553         {"divide", f_divide, 2},
 554         {"eval", f_eval1, 1},
 555         {"eval", f_eval2, 2},
 556         {"evalf", f_evalf1, 1},
 557         {"evalf", f_evalf2, 2},
 558         {"evalm", f_evalm, 1},
 559         {"expand", f_expand, 1},
 560         {"find", f_find, 2},
 561         {"gcd", f_gcd, 2},
 562         {"has", f_has, 2},
 563         {"inverse", f_inverse, 1},
 564         {"is", f_is, 1},
 565         {"lcm", f_lcm, 2},
 566         {"lcoeff", f_lcoeff, 2},
 567         {"ldegree", f_ldegree, 2},
 568         {"lsolve", f_lsolve, 2},
 569         {"map", f_map, 2},
 570         {"match", f_match, 2},
 571         {"nops", f_nops, 1},
 572         {"normal", f_normal1, 1},
 573         {"normal", f_normal2, 2},
 574         {"numer", f_numer, 1},
 575         {"numer_denom", f_numer_denom, 1},
 576         {"op", f_op, 2},
 577         {"pow", f_pow, 2},
 578         {"prem", f_prem, 3},
 579         {"primpart", f_primpart, 2},
 580         {"quo", f_quo, 3},
 581         {"rem", f_rem, 3},
 582         {"series", f_series, 3},
 583         {"sprem", f_sprem, 3},
 584         {"sqrfree", f_sqrfree1, 1},
 585         {"sqrfree", f_sqrfree2, 2},
 586         {"sqrt", f_sqrt, 1},
 587         {"subs", f_subs2, 2},
 588         {"subs", f_subs3, 3},
 589         {"tcoeff", f_tcoeff, 2},
 590         {"time", f_dummy, 0},
 591         {"trace", f_trace, 1},
 592         {"transpose", f_transpose, 1},
 593         {"unassign", f_unassign, 1},
 594         {"unit", f_unit, 2},
 595         {NULL, f_dummy, 0}      // End marker
 596 };
 597
 598 struct fcn_help_init {
 599         const char *name;
 600         const char *help;
 601 };
 602
 603 static const fcn_help_init builtin_help[] = {
 604         {"acos", "inverse cosine function"},
 605         {"acosh", "inverse hyperbolic cosine function"},
 606         {"asin", "inverse sine function"},
 607         {"asinh", "inverse hyperbolic sine function"},
 608         {"atan", "inverse tangent function"},
 609         {"atan2", "inverse tangent function with two arguments"},
 610         {"atanh", "inverse hyperbolic tangent function"},
 611         {"beta", "Beta function"},
 612         {"binomial", "binomial function"},
 613         {"cos", "cosine function"},
 614         {"cosh", "hyperbolic cosine function"},
 615         {"exp", "exponential function"},
 616         {"factorial", "factorial function"},
 617         {"lgamma", "natural logarithm of Gamma function"},
 618         {"tgamma", "Gamma function"},
 619         {"log", "natural logarithm"},
 620         {"psi", "psi function\npsi(x) is the digamma function, psi(n,x) the nth polygamma function"},
 621         {"sin", "sine function"},
 622         {"sinh", "hyperbolic sine function"},
 623         {"tan", "tangent function"},
 624         {"tanh", "hyperbolic tangent function"},
 625         {"zeta", "zeta function\nzeta(x) is Riemann's zeta function, zeta(n,x) its nth derivative"},
 626         {"Li2", "dilogarithm"},
 627         {"Li3", "trilogarithm"},
 628         {"Order", "order term function (for truncated power series)"},
 629         {"Derivative", "inert differential operator"},
 630         {NULL, NULL}    // End marker
 631 };
 632
 633 #include "ginsh_extensions.h"
 634
 635
 636 /*
 637  *  Add functions to ginsh
 638  */
 639
 640 // Functions from fcn_init array
 641 static void insert_fcns(const fcn_init *p)
 642 {
 643         while (p->name) {
 644                 fcns.insert(make_pair(string(p->name), fcn_desc(p->p, p->num_params)));
 645                 p++;
 646         }
 647 }
 648
 649 static ex f_ginac_function(const exprseq &es, int serial)
 650 {
 651         return function(serial, es).eval(1);
 652 }
 653
 654 // All registered GiNaC functions
 655 void GiNaC::ginsh_get_ginac_functions(void)
 656 {
 657         vector<function_options>::const_iterator i = function::registered_functions().begin(), end = function::registered_functions().end();
 658         unsigned serial = 0;
 659         while (i != end) {
 660                 fcns.insert(make_pair(i->get_name(), fcn_desc(f_ginac_function, i->get_nparams(), serial)));
 661                 ++i;
 662                 serial++;
 663         }
 664 }
 665
 666
 667 /*
 668  *  Find a function given a name and number of parameters. Throw exceptions on error.
 669  */
 670
 671 static fcn_tab::const_iterator find_function(const ex &sym, int req_params)
 672 {
 673         const string &name = ex_to<symbol>(sym).get_name();
 674         typedef fcn_tab::const_iterator I;
 675         pair<I, I> b = fcns.equal_range(name);
 676         if (b.first == b.second)
 677                 throw(std::logic_error("unknown function '" + name + "'"));
 678         else {
 679                 for (I i=b.first; i!=b.second; i++)
 680                         if ((i->second.num_params == 0) || (i->second.num_params == req_params))
 681                                 return i;
 682         }
 683         throw(std::logic_error("invalid number of arguments to " + name + "()"));
 684 }
 685
 686
 687 /*
 688  *  Insert help strings
 689  */
 690
 691 // Normal help string
 692 static void insert_help(const char *topic, const char *str)
 693 {
 694         help.insert(make_pair(string(topic), string(str)));
 695 }
 696
 697 // Help string for functions, automatically generates synopsis
 698 static void insert_fcn_help(const char *name, const char *str)
 699 {
 700         typedef fcn_tab::const_iterator I;
 701         pair<I, I> b = fcns.equal_range(name);
 702         if (b.first != b.second) {
 703                 string help_str = string(name) + "(";
 704                 for (int i=0; i<b.first->second.num_params; i++) {
 705                         if (i)
 706                                 help_str += ", ";
 707                         help_str += "expression";
 708                 }
 709                 help_str += ") - ";
 710                 help_str += str;
 711                 help.insert(make_pair(string(name), help_str));
 712         }
 713 }
 714
 715 // Help strings for functions from fcn_help_init array
 716 static void insert_help(const fcn_help_init *p)
 717 {
 718         while (p->name) {
 719                 insert_fcn_help(p->name, p->help);
 720                 p++;
 721         }
 722 }
 723
 724
 725 /*
 726  *  Print help to cout
 727  */
 728
 729 // Help for a given topic
 730 static void print_help(const string &topic)
 731 {
 732         typedef help_tab::const_iterator I;
 733         pair<I, I> b = help.equal_range(topic);
 734         if (b.first == b.second)
 735                 cout << "no help for '" << topic << "'\n";
 736         else {
 737                 for (I i=b.first; i!=b.second; i++)
 738                         cout << i->second << endl;
 739         }
 740 }
 741
 742 // List of help topics
 743 static void print_help_topics(void)
 744 {
 745         cout << "Available help topics:\n";
 746         help_tab::const_iterator i;
 747         string last_name = string("*");
 748         int num = 0;
 749         for (i=help.begin(); i!=help.end(); i++) {
 750                 // Don't print duplicates
 751                 if (i->first != last_name) {
 752                         if (num)
 753                                 cout << ", ";
 754                         num++;
 755                         cout << i->first;
 756                         last_name = i->first;
 757                 }
 758         }
 759         cout << "\nTo get help for a certain topic, type ?topic\n";
 760 }
 761
 762
 763 /*
 764  *  Function name completion functions for readline
 765  */
 766
 767 static char *fcn_generator(const char *text, int state)
 768 {
 769         static int len;                         // Length of word to complete
 770         static fcn_tab::const_iterator index;   // Iterator to function being currently considered
 771
 772         // If this is a new word to complete, initialize now
 773         if (state == 0) {
 774                 index = fcns.begin();
 775                 len = strlen(text);
 776         }
 777
 778         // Return the next function which partially matches
 779         while (index != fcns.end()) {
 780                 const char *fcn_name = index->first.c_str();
 781                 ++index;
 782                 if (strncmp(fcn_name, text, len) == 0)
 783                         return strdup(fcn_name);
 784         }
 785         return NULL;
 786 }
 787
 788 static char **fcn_completion(const char *text, int start, int end)
 789 {
 790         if (rl_line_buffer[0] == '!') {
 791                 // For shell commands, revert back to filename completion
 792                 rl_completion_append_character = orig_completion_append_character;
 793                 rl_basic_word_break_characters = orig_basic_word_break_characters;
 794                 rl_completer_word_break_characters = rl_basic_word_break_characters;
 795 #if (GINAC_RL_VERSION_MAJOR < 4) || (GINAC_RL_VERSION_MAJOR == 4 && GINAC_RL_VERSION_MINOR < 2)
 796                 return completion_matches(const_cast<char *>(text), (CPFunction *)filename_completion_function);
 797 #else
 798                 return rl_completion_matches(text, rl_filename_completion_function);
 799 #endif
 800         } else {
 801                 // Otherwise, complete function names
 802                 rl_completion_append_character = '(';
 803                 rl_basic_word_break_characters = " \t\n\"#$%&'()*+,-./:;<=>?@[\\]^`{|}~";
 804                 rl_completer_word_break_characters = rl_basic_word_break_characters;
 805 #if (GINAC_RL_VERSION_MAJOR < 4) || (GINAC_RL_VERSION_MAJOR == 4 && GINAC_RL_VERSION_MINOR < 2)
 806                 return completion_matches(const_cast<char *>(text), (CPFunction *)fcn_generator);
 807 #else
 808                 return rl_completion_matches(text, fcn_generator);
 809 #endif
 810         }
 811 }
 812
 813 void greeting(void)
 814 {
 815     cout << "ginsh - GiNaC Interactive Shell (" << PACKAGE << " V" << VERSION << ")" << endl;
 816     cout << "  __,  _______  Copyright (C) 1999-2003 Johannes Gutenberg University Mainz,\n"
 817          << " (__) *       | Germany.  This is free software with ABSOLUTELY NO WARRANTY.\n"
 818          << "  ._) i N a C | You are welcome to redistribute it under certain conditions.\n"
 819          << "<-------------' For details type `warranty;'.\n" << endl;
 820     cout << "Type ?? for a list of help topics." << endl;
 821 }
 822
 823 /*
 824  *  Main program
 825  */
 826
 827 int main(int argc, char **argv)
 828 {
 829         // Print banner in interactive mode
 830         if (isatty(0))
 831                 greeting();
 832
 833         // Init function table
 834         insert_fcns(builtin_fcns);
 835         insert_fcns(extended_fcns);
 836         ginsh_get_ginac_functions();
 837
 838         // Init help for operators (automatically generated from man page)
 839         insert_help("operators", "Operators in falling order of precedence:");
 840 #include "ginsh_op_help.h"
 841
 842         // Init help for built-in functions (automatically generated from man page)
 843 #include "ginsh_fcn_help.h"
 844
 845         // Help for GiNaC functions is added manually
 846         insert_help(builtin_help);
 847         insert_help(extended_help);
 848
 849         // Init readline completer
 850         rl_readline_name = argv[0];
 851 #if (GINAC_RL_VERSION_MAJOR < 4) || (GINAC_RL_VERSION_MAJOR == 4 && GINAC_RL_VERSION_MINOR < 2)
 852         rl_attempted_completion_function = (CPPFunction *)fcn_completion;
 853 #else
 854         rl_attempted_completion_function = fcn_completion;
 855 #endif
 856         orig_completion_append_character = rl_completion_append_character;
 857         orig_basic_word_break_characters = rl_basic_word_break_characters;
 858
 859         // Init input file list, open first file
 860         num_files = argc - 1;
 861         file_list = argv + 1;
 862         if (num_files) {
 863                 yyin = fopen(*file_list, "r");
 864                 if (yyin == NULL) {
 865                         cerr << "Can't open " << *file_list << endl;
 866                         exit(1);
 867                 }
 868                 num_files--;
 869                 file_list++;
 870         }
 871
 872         // Parse input, catch all remaining exceptions
 873         int result;
 874 again:  try {
 875                 result = yyparse();
 876         } catch (exception &e) {
 877                 cerr << e.what() << endl;
 878                 goto again;
 879         }
 880         return result;
 881 }