ginsh/ginsh_parser.yy

   1 /** @file ginsh_parser.yy
   2  *
   3  *  Input grammar definition for ginsh.
   4  *  This file must be processed with yacc/bison. */
   5
   6 /*
   7  *  GiNaC Copyright (C) 1999-2001 Johannes Gutenberg University Mainz, Germany
   8  *
   9  *  This program is free software; you can redistribute it and/or modify
  10  *  it under the terms of the GNU General Public License as published by
  11  *  the Free Software Foundation; either version 2 of the License, or
  12  *  (at your option) any later version.
  13  *
  14  *  This program is distributed in the hope that it will be useful,
  15  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  *  GNU General Public License for more details.
  18  *
  19  *  You should have received a copy of the GNU General Public License
  20  *  along with this program; if not, write to the Free Software
  21  *  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  22  */
  23
  24
  25 /*
  26  *  Definitions
  27  */
  28
  29 %{
  30 #include "config.h"
  31
  32 #include <sys/resource.h>
  33
  34 #if HAVE_UNISTD_H
  35 #include <sys/types.h>
  36 #include <unistd.h>
  37 #endif
  38
  39 #include <stdexcept>
  40
  41 #include "ginsh.h"
  42
  43 #define YYERROR_VERBOSE 1
  44
  45 // Original readline settings
  46 static int orig_completion_append_character;
  47 #if (GINAC_RL_VERSION_MAJOR < 4) || (GINAC_RL_VERSION_MAJOR == 4 && GINAC_RL_VERSION_MINOR < 2)
  48 static char *orig_basic_word_break_characters;
  49 #else
  50 static const char *orig_basic_word_break_characters;
  51 #endif
  52
  53 // Expression stack for ", "" and """
  54 static void push(const ex &e);
  55 static ex exstack[3];
  56
  57 // Start and end time for the time() function
  58 static struct rusage start_time, end_time;
  59
  60 // Table of functions (a multimap, because one function may appear with different
  61 // numbers of parameters)
  62 typedef ex (*fcnp)(const exprseq &e);
  63 typedef ex (*fcnp2)(const exprseq &e, int serial);
  64
  65 struct fcn_desc {
  66         fcn_desc() : p(NULL), num_params(0) {}
  67         fcn_desc(fcnp func, int num) : p(func), num_params(num), is_ginac(false) {}
  68         fcn_desc(fcnp2 func, int num, int ser) : p((fcnp)func), num_params(num), is_ginac(true), serial(ser) {}
  69
  70         fcnp p;         // Pointer to function
  71         int num_params; // Number of parameters (0 = arbitrary)
  72         bool is_ginac;  // Flag: function is GiNaC function
  73         int serial;     // GiNaC function serial number (if is_ginac == true)
  74 };
  75
  76 typedef multimap<string, fcn_desc> fcn_tab;
  77 static fcn_tab fcns;
  78
  79 static fcn_tab::const_iterator find_function(const ex &sym, int req_params);
  80
  81 // Table to map help topics to help strings
  82 typedef multimap<string, string> help_tab;
  83 static help_tab help;
  84
  85 static void print_help(const string &topic);
  86 static void print_help_topics(void);
  87 %}
  88
  89 /* Tokens (T_LITERAL means a literal value returned by the parser, but not
  90    of class numeric or symbol (e.g. a constant or the FAIL object)) */
  91 %token T_NUMBER T_SYMBOL T_LITERAL T_DIGITS T_QUOTE T_QUOTE2 T_QUOTE3
  92 %token T_EQUAL T_NOTEQ T_LESSEQ T_GREATEREQ
  93
  94 %token T_QUIT T_WARRANTY T_PRINT T_IPRINT T_TIME T_XYZZY T_INVENTORY T_LOOK T_SCORE
  95
  96 /* Operator precedence and associativity */
  97 %right '='
  98 %left T_EQUAL T_NOTEQ
  99 %left '<' '>' T_LESSEQ T_GREATEREQ
 100 %left '+' '-'
 101 %left '*' '/' '%'
 102 %nonassoc NEG
 103 %right '^'
 104 %nonassoc '!'
 105
 106 %start input
 107
 108
 109 /*
 110  *  Grammar rules
 111  */
 112
 113 %%
 114 input   : /* empty */
 115         | input line
 116         ;
 117
 118 line    : ';'
 119         | exp ';' {
 120                 try {
 121                         cout << $1 << endl;
 122                         push($1);
 123                 } catch (exception &e) {
 124                         cerr << e.what() << endl;
 125                         YYERROR;
 126                 }
 127         }
 128         | exp ':' {
 129                 try {
 130                         push($1);
 131                 } catch (exception &e) {
 132                         std::cerr << e.what() << endl;
 133                         YYERROR;
 134                 }
 135         }
 136         | T_PRINT '(' exp ')' ';' {
 137                 try {
 138                         $3.print(print_tree(std::cout));
 139                 } catch (exception &e) {
 140                         std::cerr << e.what() << endl;
 141                         YYERROR;
 142                 }
 143         }
 144         | T_IPRINT '(' exp ')' ';' {
 145                 try {
 146                         ex e = $3;
 147                         if (!e.info(info_flags::integer))
 148                                 throw (std::invalid_argument("argument to iprint() must be an integer"));
 149                         long i = ex_to<numeric>(e).to_long();
 150                         cout << i << endl;
 151                         cout << "#o" << oct << i << endl;
 152                         cout << "#x" << hex << i << dec << endl;
 153                 } catch (exception &e) {
 154                         cerr << e.what() << endl;
 155                         YYERROR;
 156                 }
 157         }
 158         | '?' T_SYMBOL          {print_help(ex_to<symbol>($2).get_name());}
 159         | '?' T_TIME            {print_help("time");}
 160         | '?' '?'               {print_help_topics();}
 161         | T_QUIT                {YYACCEPT;}
 162         | T_WARRANTY {
 163                 cout << "This program is free software; you can redistribute it and/or modify it under\n";
 164                 cout << "the terms of the GNU General Public License as published by the Free Software\n";
 165                 cout << "Foundation; either version 2 of the License, or (at your option) any later\n";
 166                 cout << "version.\n";
 167                 cout << "This program is distributed in the hope that it will be useful, but WITHOUT\n";
 168                 cout << "ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS\n";
 169                 cout << "FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more\n";
 170                 cout << "details.\n";
 171                 cout << "You should have received a copy of the GNU General Public License along with\n";
 172                 cout << "this program. If not, write to the Free Software Foundation, 675 Mass Ave,\n";
 173                 cout << "Cambridge, MA 02139, USA.\n";
 174         }
 175         | T_XYZZY               {cout << "Nothing happens.\n";}
 176         | T_INVENTORY           {cout << "You're not carrying anything.\n";}
 177         | T_LOOK                {cout << "You're in a twisty little maze of passages, all alike.\n";}
 178         | T_SCORE {
 179                 cout << "If you were to quit now, you would score ";
 180                 cout << (syms.size() > 350 ? 350 : syms.size());
 181                 cout << " out of a possible 350.\n";
 182         }
 183         | T_TIME {getrusage(RUSAGE_SELF, &start_time);} '(' exp ')' {
 184                 getrusage(RUSAGE_SELF, &end_time);
 185                 cout << (end_time.ru_utime.tv_sec - start_time.ru_utime.tv_sec) +
 186                         (end_time.ru_stime.tv_sec - start_time.ru_stime.tv_sec) +
 187                          double(end_time.ru_utime.tv_usec - start_time.ru_utime.tv_usec) / 1e6 +
 188                          double(end_time.ru_stime.tv_usec - start_time.ru_stime.tv_usec) / 1e6 << 's' << endl;
 189         }
 190         | error ';'             {yyclearin; yyerrok;}
 191         | error ':'             {yyclearin; yyerrok;}
 192         ;
 193
 194 exp     : T_NUMBER              {$$ = $1;}
 195         | T_SYMBOL              {$$ = $1.eval();}
 196         | '\'' T_SYMBOL '\''    {$$ = $2;}
 197         | T_LITERAL             {$$ = $1;}
 198         | T_DIGITS              {$$ = $1;}
 199         | T_QUOTE               {$$ = exstack[0];}
 200         | T_QUOTE2              {$$ = exstack[1];}
 201         | T_QUOTE3              {$$ = exstack[2];}
 202         | T_SYMBOL '(' exprseq ')' {
 203                 fcn_tab::const_iterator i = find_function($1, $3.nops());
 204                 if (i->second.is_ginac) {
 205                         $$ = ((fcnp2)(i->second.p))(static_cast<const exprseq &>(*($3.bp)), i->second.serial);
 206                 } else {
 207                         $$ = (i->second.p)(static_cast<const exprseq &>(*($3.bp)));
 208                 }
 209         }
 210         | T_DIGITS '=' T_NUMBER {$$ = $3; Digits = ex_to<numeric>($3).to_int();}
 211         | T_SYMBOL '=' exp      {$$ = $3; const_cast<symbol *>(&ex_to<symbol>($1))->assign($3);}
 212         | exp T_EQUAL exp       {$$ = $1 == $3;}
 213         | exp T_NOTEQ exp       {$$ = $1 != $3;}
 214         | exp '<' exp           {$$ = $1 < $3;}
 215         | exp T_LESSEQ exp      {$$ = $1 <= $3;}
 216         | exp '>' exp           {$$ = $1 > $3;}
 217         | exp T_GREATEREQ exp   {$$ = $1 >= $3;}
 218         | exp '+' exp           {$$ = $1 + $3;}
 219         | exp '-' exp           {$$ = $1 - $3;}
 220         | exp '*' exp           {$$ = $1 * $3;}
 221         | exp '/' exp           {$$ = $1 / $3;}
 222         | '-' exp %prec NEG     {$$ = -$2;}
 223         | '+' exp %prec NEG     {$$ = $2;}
 224         | exp '^' exp           {$$ = power($1, $3);}
 225         | exp '!'               {$$ = factorial($1);}
 226         | '(' exp ')'           {$$ = $2;}
 227         | '{' list_or_empty '}' {$$ = $2;}
 228         | '[' matrix ']'        {$$ = lst_to_matrix(ex_to<lst>($2));}
 229         ;
 230
 231 exprseq : exp                   {$$ = exprseq($1);}
 232         | exprseq ',' exp       {exprseq es(static_cast<exprseq &>(*($1.bp))); $$ = es.append($3);}
 233         ;
 234
 235 list_or_empty: /* empty */      {$$ = *new lst;}
 236         | list                  {$$ = $1;}
 237         ;
 238
 239 list    : exp                   {$$ = lst($1);}
 240         | list ',' exp          {lst l(static_cast<lst &>(*($1.bp))); $$ = l.append($3);}
 241         ;
 242
 243 matrix  : '[' row ']'           {$$ = lst($2);}
 244         | matrix ',' '[' row ']' {lst l(static_cast<lst &>(*($1.bp))); $$ = l.append($4);}
 245         ;
 246
 247 row     : exp                   {$$ = lst($1);}
 248         | row ',' exp           {lst l(static_cast<lst &>(*($1.bp))); $$ = l.append($3);}
 249         ;
 250
 251
 252 /*
 253  *  Routines
 254  */
 255
 256 %%
 257 // Error print routine
 258 int yyerror(char *s)
 259 {
 260         cerr << s << " at " << yytext << endl;
 261         return 0;
 262 }
 263
 264 // Push expression "e" onto the expression stack (for ", "" and """)
 265 static void push(const ex &e)
 266 {
 267         exstack[2] = exstack[1];
 268         exstack[1] = exstack[0];
 269         exstack[0] = e;
 270 }
 271
 272
 273 /*
 274  *  Built-in functions
 275  */
 276
 277 static ex f_collect(const exprseq &e) {return e[0].collect(e[1]);}
 278 static ex f_collect_distributed(const exprseq &e) {return e[0].collect(e[1], true);}
 279 static ex f_degree(const exprseq &e) {return e[0].degree(e[1]);}
 280 static ex f_denom(const exprseq &e) {return e[0].denom();}
 281 static ex f_eval1(const exprseq &e) {return e[0].eval();}
 282 static ex f_evalf1(const exprseq &e) {return e[0].evalf();}
 283 static ex f_evalm(const exprseq &e) {return e[0].evalm();}
 284 static ex f_expand(const exprseq &e) {return e[0].expand();}
 285 static ex f_gcd(const exprseq &e) {return gcd(e[0], e[1]);}
 286 static ex f_has(const exprseq &e) {return e[0].has(e[1]) ? ex(1) : ex(0);}
 287 static ex f_lcm(const exprseq &e) {return lcm(e[0], e[1]);}
 288 static ex f_lcoeff(const exprseq &e) {return e[0].lcoeff(e[1]);}
 289 static ex f_ldegree(const exprseq &e) {return e[0].ldegree(e[1]);}
 290 static ex f_lsolve(const exprseq &e) {return lsolve(e[0], e[1]);}
 291 static ex f_nops(const exprseq &e) {return e[0].nops();}
 292 static ex f_normal1(const exprseq &e) {return e[0].normal();}
 293 static ex f_numer(const exprseq &e) {return e[0].numer();}
 294 static ex f_numer_denom(const exprseq &e) {return e[0].numer_denom();}
 295 static ex f_pow(const exprseq &e) {return pow(e[0], e[1]);}
 296 static ex f_sqrt(const exprseq &e) {return sqrt(e[0]);}
 297 static ex f_sqrfree1(const exprseq &e) {return sqrfree(e[0]);}
 298 static ex f_subs2(const exprseq &e) {return e[0].subs(e[1]);}
 299 static ex f_tcoeff(const exprseq &e) {return e[0].tcoeff(e[1]);}
 300
 301 #define CHECK_ARG(num, type, fcn) if (!is_a<type>(e[num])) throw(std::invalid_argument("argument " #num " to " #fcn "() must be a " #type))
 302
 303 static ex f_charpoly(const exprseq &e)
 304 {
 305         CHECK_ARG(0, matrix, charpoly);
 306         CHECK_ARG(1, symbol, charpoly);
 307         return ex_to<matrix>(e[0]).charpoly(ex_to<symbol>(e[1]));
 308 }
 309
 310 static ex f_coeff(const exprseq &e)
 311 {
 312         CHECK_ARG(2, numeric, coeff);
 313         return e[0].coeff(e[1], ex_to<numeric>(e[2]).to_int());
 314 }
 315
 316 static ex f_content(const exprseq &e)
 317 {
 318         CHECK_ARG(1, symbol, content);
 319         return e[0].content(ex_to<symbol>(e[1]));
 320 }
 321
 322 static ex f_determinant(const exprseq &e)
 323 {
 324         CHECK_ARG(0, matrix, determinant);
 325         return ex_to<matrix>(e[0]).determinant();
 326 }
 327
 328 static ex f_diag(const exprseq &e)
 329 {
 330         unsigned dim = e.nops();
 331         matrix &m = *new matrix(dim, dim);
 332         for (unsigned i=0; i<dim; i++)
 333                 m.set(i, i, e.op(i));
 334         return m;
 335 }
 336
 337 static ex f_diff2(const exprseq &e)
 338 {
 339         CHECK_ARG(1, symbol, diff);
 340         return e[0].diff(ex_to<symbol>(e[1]));
 341 }
 342
 343 static ex f_diff3(const exprseq &e)
 344 {
 345         CHECK_ARG(1, symbol, diff);
 346         CHECK_ARG(2, numeric, diff);
 347         return e[0].diff(ex_to<symbol>(e[1]), ex_to<numeric>(e[2]).to_int());
 348 }
 349
 350 static ex f_divide(const exprseq &e)
 351 {
 352         ex q;
 353         if (divide(e[0], e[1], q))
 354                 return q;
 355         else
 356                 return fail();
 357 }
 358
 359 static ex f_eval2(const exprseq &e)
 360 {
 361         CHECK_ARG(1, numeric, eval);
 362         return e[0].eval(ex_to<numeric>(e[1]).to_int());
 363 }
 364
 365 static ex f_evalf2(const exprseq &e)
 366 {
 367         CHECK_ARG(1, numeric, evalf);
 368         return e[0].evalf(ex_to<numeric>(e[1]).to_int());
 369 }
 370
 371 static ex f_inverse(const exprseq &e)
 372 {
 373         CHECK_ARG(0, matrix, inverse);
 374         return ex_to<matrix>(e[0]).inverse();
 375 }
 376
 377 static ex f_is(const exprseq &e)
 378 {
 379         CHECK_ARG(0, relational, is);
 380         return (bool)ex_to<relational>(e[0]) ? ex(1) : ex(0);
 381 }
 382
 383 static ex f_match(const exprseq &e)
 384 {
 385         lst repl_lst;
 386         if (e[0].match(e[1], repl_lst))
 387                 return repl_lst;
 388         else
 389                 return fail();
 390 }
 391
 392 static ex f_normal2(const exprseq &e)
 393 {
 394         CHECK_ARG(1, numeric, normal);
 395         return e[0].normal(ex_to<numeric>(e[1]).to_int());
 396 }
 397
 398 static ex f_op(const exprseq &e)
 399 {
 400         CHECK_ARG(1, numeric, op);
 401         int n = ex_to<numeric>(e[1]).to_int();
 402         if (n < 0 || n >= (int)e[0].nops())
 403                 throw(std::out_of_range("second argument to op() is out of range"));
 404         return e[0].op(n);
 405 }
 406
 407 static ex f_prem(const exprseq &e)
 408 {
 409         CHECK_ARG(2, symbol, prem);
 410         return prem(e[0], e[1], ex_to<symbol>(e[2]));
 411 }
 412
 413 static ex f_primpart(const exprseq &e)
 414 {
 415         CHECK_ARG(1, symbol, primpart);
 416         return e[0].primpart(ex_to<symbol>(e[1]));
 417 }
 418
 419 static ex f_quo(const exprseq &e)
 420 {
 421         CHECK_ARG(2, symbol, quo);
 422         return quo(e[0], e[1], ex_to<symbol>(e[2]));
 423 }
 424
 425 static ex f_rem(const exprseq &e)
 426 {
 427         CHECK_ARG(2, symbol, rem);
 428         return rem(e[0], e[1], ex_to<symbol>(e[2]));
 429 }
 430
 431 static ex f_series(const exprseq &e)
 432 {
 433         CHECK_ARG(2, numeric, series);
 434         return e[0].series(e[1], ex_to<numeric>(e[2]).to_int());
 435 }
 436
 437 static ex f_sqrfree2(const exprseq &e)
 438 {
 439         CHECK_ARG(1, lst, sqrfree);
 440         return sqrfree(e[0], ex_to<lst>(e[1]));
 441 }
 442
 443 static ex f_subs3(const exprseq &e)
 444 {
 445         CHECK_ARG(1, lst, subs);
 446         CHECK_ARG(2, lst, subs);
 447         return e[0].subs(ex_to<lst>(e[1]), ex_to<lst>(e[2]));
 448 }
 449
 450 static ex f_trace(const exprseq &e)
 451 {
 452         CHECK_ARG(0, matrix, trace);
 453         return ex_to<matrix>(e[0]).trace();
 454 }
 455
 456 static ex f_transpose(const exprseq &e)
 457 {
 458         CHECK_ARG(0, matrix, transpose);
 459         return ex_to<matrix>(e[0]).transpose();
 460 }
 461
 462 static ex f_unassign(const exprseq &e)
 463 {
 464         CHECK_ARG(0, symbol, unassign);
 465         (const_cast<symbol *>(&ex_to<symbol>(e[0])))->unassign();
 466         return e[0];
 467 }
 468
 469 static ex f_unit(const exprseq &e)
 470 {
 471         CHECK_ARG(1, symbol, unit);
 472         return e[0].unit(ex_to<symbol>(e[1]));
 473 }
 474
 475 static ex f_dummy(const exprseq &e)
 476 {
 477         throw(std::logic_error("dummy function called (shouldn't happen)"));
 478 }
 479
 480 // Table for initializing the "fcns" map
 481 struct fcn_init {
 482         const char *name;
 483         const fcn_desc desc;
 484 };
 485
 486 static const fcn_init builtin_fcns[] = {
 487         {"charpoly", fcn_desc(f_charpoly, 2)},
 488         {"coeff", fcn_desc(f_coeff, 3)},
 489         {"collect", fcn_desc(f_collect, 2)},
 490         {"collect_distributed", fcn_desc(f_collect_distributed, 2)},
 491         {"content", fcn_desc(f_content, 2)},
 492         {"degree", fcn_desc(f_degree, 2)},
 493         {"denom", fcn_desc(f_denom, 1)},
 494         {"determinant", fcn_desc(f_determinant, 1)},
 495         {"diag", fcn_desc(f_diag, 0)},
 496         {"diff", fcn_desc(f_diff2, 2)},
 497         {"diff", fcn_desc(f_diff3, 3)},
 498         {"divide", fcn_desc(f_divide, 2)},
 499         {"eval", fcn_desc(f_eval1, 1)},
 500         {"eval", fcn_desc(f_eval2, 2)},
 501         {"evalf", fcn_desc(f_evalf1, 1)},
 502         {"evalf", fcn_desc(f_evalf2, 2)},
 503         {"evalm", fcn_desc(f_evalm, 1)},
 504         {"expand", fcn_desc(f_expand, 1)},
 505         {"gcd", fcn_desc(f_gcd, 2)},
 506         {"has", fcn_desc(f_has, 2)},
 507         {"inverse", fcn_desc(f_inverse, 1)},
 508         {"is", fcn_desc(f_is, 1)},
 509         {"lcm", fcn_desc(f_lcm, 2)},
 510         {"lcoeff", fcn_desc(f_lcoeff, 2)},
 511         {"ldegree", fcn_desc(f_ldegree, 2)},
 512         {"lsolve", fcn_desc(f_lsolve, 2)},
 513         {"match", fcn_desc(f_match, 2)},
 514         {"nops", fcn_desc(f_nops, 1)},
 515         {"normal", fcn_desc(f_normal1, 1)},
 516         {"normal", fcn_desc(f_normal2, 2)},
 517         {"numer", fcn_desc(f_numer, 1)},
 518         {"numer_denom", fcn_desc(f_numer_denom, 1)},
 519         {"op", fcn_desc(f_op, 2)},
 520         {"pow", fcn_desc(f_pow, 2)},
 521         {"prem", fcn_desc(f_prem, 3)},
 522         {"primpart", fcn_desc(f_primpart, 2)},
 523         {"quo", fcn_desc(f_quo, 3)},
 524         {"rem", fcn_desc(f_rem, 3)},
 525         {"series", fcn_desc(f_series, 3)},
 526         {"sqrfree", fcn_desc(f_sqrfree1, 1)},
 527         {"sqrfree", fcn_desc(f_sqrfree2, 2)},
 528         {"sqrt", fcn_desc(f_sqrt, 1)},
 529         {"subs", fcn_desc(f_subs2, 2)},
 530         {"subs", fcn_desc(f_subs3, 3)},
 531         {"tcoeff", fcn_desc(f_tcoeff, 2)},
 532         {"time", fcn_desc(f_dummy, 0)},
 533         {"trace", fcn_desc(f_trace, 1)},
 534         {"transpose", fcn_desc(f_transpose, 1)},
 535         {"unassign", fcn_desc(f_unassign, 1)},
 536         {"unit", fcn_desc(f_unit, 2)},
 537         {NULL, fcn_desc(f_dummy, 0)}    // End marker
 538 };
 539
 540
 541 /*
 542  *  Add functions to ginsh
 543  */
 544
 545 // Functions from fcn_init array
 546 static void insert_fcns(const fcn_init *p)
 547 {
 548         while (p->name) {
 549                 fcns.insert(make_pair(string(p->name), p->desc));
 550                 p++;
 551         }
 552 }
 553
 554 static ex f_ginac_function(const exprseq &es, int serial)
 555 {
 556         return function(serial, es).eval(1);
 557 }
 558
 559 // All registered GiNaC functions
 560 void GiNaC::ginsh_get_ginac_functions(void)
 561 {
 562         vector<function_options>::const_iterator i = function::registered_functions().begin(), end = function::registered_functions().end();
 563         unsigned serial = 0;
 564         while (i != end) {
 565                 fcns.insert(make_pair(i->get_name(), fcn_desc(f_ginac_function, i->get_nparams(), serial)));
 566                 i++;
 567                 serial++;
 568         }
 569 }
 570
 571
 572 /*
 573  *  Find a function given a name and number of parameters. Throw exceptions on error.
 574  */
 575
 576 static fcn_tab::const_iterator find_function(const ex &sym, int req_params)
 577 {
 578         const string &name = ex_to<symbol>(sym).get_name();
 579         typedef fcn_tab::const_iterator I;
 580         pair<I, I> b = fcns.equal_range(name);
 581         if (b.first == b.second)
 582                 throw(std::logic_error("unknown function '" + name + "'"));
 583         else {
 584                 for (I i=b.first; i!=b.second; i++)
 585                         if ((i->second.num_params == 0) || (i->second.num_params == req_params))
 586                                 return i;
 587         }
 588         throw(std::logic_error("invalid number of arguments to " + name + "()"));
 589 }
 590
 591
 592 /*
 593  *  Insert help strings
 594  */
 595
 596 // Normal help string
 597 static void insert_help(const char *topic, const char *str)
 598 {
 599         help.insert(make_pair(string(topic), string(str)));
 600 }
 601
 602 // Help string for functions, automatically generates synopsis
 603 static void insert_fcn_help(const char *name, const char *str)
 604 {
 605         typedef fcn_tab::const_iterator I;
 606         pair<I, I> b = fcns.equal_range(name);
 607         if (b.first != b.second) {
 608                 string help_str = string(name) + "(";
 609                 for (int i=0; i<b.first->second.num_params; i++) {
 610                         if (i)
 611                                 help_str += ", ";
 612                         help_str += "expression";
 613                 }
 614                 help_str += ") - ";
 615                 help_str += str;
 616                 help.insert(make_pair(string(name), help_str));
 617         }
 618 }
 619
 620
 621 /*
 622  *  Print help to cout
 623  */
 624
 625 // Help for a given topic
 626 static void print_help(const string &topic)
 627 {
 628         typedef help_tab::const_iterator I;
 629         pair<I, I> b = help.equal_range(topic);
 630         if (b.first == b.second)
 631                 cout << "no help for '" << topic << "'\n";
 632         else {
 633                 for (I i=b.first; i!=b.second; i++)
 634                         cout << i->second << endl;
 635         }
 636 }
 637
 638 // List of help topics
 639 static void print_help_topics(void)
 640 {
 641         cout << "Available help topics:\n";
 642         help_tab::const_iterator i;
 643         string last_name = string("*");
 644         int num = 0;
 645         for (i=help.begin(); i!=help.end(); i++) {
 646                 // Don't print duplicates
 647                 if (i->first != last_name) {
 648                         if (num)
 649                                 cout << ", ";
 650                         num++;
 651                         cout << i->first;
 652                         last_name = i->first;
 653                 }
 654         }
 655         cout << "\nTo get help for a certain topic, type ?topic\n";
 656 }
 657
 658
 659 /*
 660  *  Function name completion functions for readline
 661  */
 662
 663 static char *fcn_generator(char *text, int state)
 664 {
 665         static int len;                         // Length of word to complete
 666         static fcn_tab::const_iterator index;   // Iterator to function being currently considered
 667
 668         // If this is a new word to complete, initialize now
 669         if (state == 0) {
 670                 index = fcns.begin();
 671                 len = strlen(text);
 672         }
 673
 674         // Return the next function which partially matches
 675         while (index != fcns.end()) {
 676                 const char *fcn_name = index->first.c_str();
 677                 index++;
 678                 if (strncmp(fcn_name, text, len) == 0)
 679                         return strdup(fcn_name);
 680         }
 681         return NULL;
 682 }
 683
 684 static char **fcn_completion(char *text, int start, int end)
 685 {
 686         if (rl_line_buffer[0] == '!') {
 687                 // For shell commands, revert back to filename completion
 688                 rl_completion_append_character = orig_completion_append_character;
 689                 rl_basic_word_break_characters = orig_basic_word_break_characters;
 690                 rl_completer_word_break_characters = rl_basic_word_break_characters;
 691 #if (GINAC_RL_VERSION_MAJOR < 4) || (GINAC_RL_VERSION_MAJOR == 4 && GINAC_RL_VERSION_MINOR < 2)
 692                 return completion_matches(text, (CPFunction *)filename_completion_function);
 693 #else
 694                 return rl_completion_matches(text, (CPFunction *)rl_filename_completion_function);
 695 #endif
 696         } else {
 697                 // Otherwise, complete function names
 698                 rl_completion_append_character = '(';
 699                 rl_basic_word_break_characters = " \t\n\"#$%&'()*+,-./:;<=>?@[\\]^`{|}~";
 700                 rl_completer_word_break_characters = rl_basic_word_break_characters;
 701 #if (GINAC_RL_VERSION_MAJOR < 4) || (GINAC_RL_VERSION_MAJOR == 4 && GINAC_RL_VERSION_MINOR < 2)
 702                 return completion_matches(text, (CPFunction *)fcn_generator);
 703 #else
 704                 return rl_completion_matches(text, (CPFunction *)fcn_generator);
 705 #endif
 706         }
 707 }
 708
 709 void greeting(void)
 710 {
 711     cout << "ginsh - GiNaC Interactive Shell (" << PACKAGE << " V" << VERSION << ")" << endl;
 712     cout << "  __,  _______  Copyright (C) 1999-2001 Johannes Gutenberg University Mainz,\n"
 713          << " (__) *       | Germany.  This is free software with ABSOLUTELY NO WARRANTY.\n"
 714          << "  ._) i N a C | You are welcome to redistribute it under certain conditions.\n"
 715          << "<-------------' For details type `warranty;'.\n" << endl;
 716     cout << "Type ?? for a list of help topics." << endl;
 717 }
 718
 719 /*
 720  *  Main program
 721  */
 722
 723 int main(int argc, char **argv)
 724 {
 725         // Print banner in interactive mode
 726         if (isatty(0))
 727                 greeting();
 728
 729         // Init function table
 730         insert_fcns(builtin_fcns);
 731         ginsh_get_ginac_functions();
 732
 733         // Init help for operators (automatically generated from man page)
 734         insert_help("operators", "Operators in falling order of precedence:");
 735 #include "ginsh_op_help.c"
 736
 737         // Init help for built-in functions (automatically generated from man page)
 738 #include "ginsh_fcn_help.c"
 739
 740         // Help for GiNaC functions is added manually
 741         insert_fcn_help("acos", "inverse cosine function");
 742         insert_fcn_help("acosh", "inverse hyperbolic cosine function");
 743         insert_fcn_help("asin", "inverse sine function");
 744         insert_fcn_help("asinh", "inverse hyperbolic sine function");
 745         insert_fcn_help("atan", "inverse tangent function");
 746         insert_fcn_help("atan2", "inverse tangent function with two arguments");
 747         insert_fcn_help("atanh", "inverse hyperbolic tangent function");
 748         insert_fcn_help("beta", "Beta function");
 749         insert_fcn_help("binomial", "binomial function");
 750         insert_fcn_help("cos", "cosine function");
 751         insert_fcn_help("cosh", "hyperbolic cosine function");
 752         insert_fcn_help("exp", "exponential function");
 753         insert_fcn_help("factorial", "factorial function");
 754         insert_fcn_help("lgamma", "natural logarithm of Gamma function");
 755         insert_fcn_help("tgamma", "Gamma function");
 756         insert_fcn_help("log", "natural logarithm");
 757         insert_fcn_help("psi", "psi function\npsi(x) is the digamma function, psi(n,x) the nth polygamma function");
 758         insert_fcn_help("sin", "sine function");
 759         insert_fcn_help("sinh", "hyperbolic sine function");
 760         insert_fcn_help("tan", "tangent function");
 761         insert_fcn_help("tanh", "hyperbolic tangent function");
 762         insert_fcn_help("zeta", "zeta function\nzeta(x) is Riemann's zeta function, zeta(n,x) its nth derivative");
 763         insert_fcn_help("Li2", "dilogarithm");
 764         insert_fcn_help("Li3", "trilogarithm");
 765         insert_fcn_help("Order", "order term function (for truncated power series)");
 766
 767         // Init readline completer
 768         rl_readline_name = argv[0];
 769         rl_attempted_completion_function = (CPPFunction *)fcn_completion;
 770         orig_completion_append_character = rl_completion_append_character;
 771         orig_basic_word_break_characters = rl_basic_word_break_characters;
 772
 773         // Init input file list, open first file
 774         num_files = argc - 1;
 775         file_list = argv + 1;
 776         if (num_files) {
 777                 yyin = fopen(*file_list, "r");
 778                 if (yyin == NULL) {
 779                         cerr << "Can't open " << *file_list << endl;
 780                         exit(1);
 781                 }
 782                 num_files--;
 783                 file_list++;
 784         }
 785
 786         // Parse input, catch all remaining exceptions
 787         int result;
 788 again:  try {
 789                 result = yyparse();
 790         } catch (exception &e) {
 791                 cerr << e.what() << endl;
 792                 goto again;
 793         }
 794         return result;
 795 }