ginsh/ginsh_parser.yy

   1 /** @file ginsh_parser.yy
   2  *
   3  *  Input grammar definition for ginsh.
   4  *  This file must be processed with yacc/bison. */
   5
   6 /*
   7  *  GiNaC Copyright (C) 1999-2000 Johannes Gutenberg University Mainz, Germany
   8  *
   9  *  This program is free software; you can redistribute it and/or modify
  10  *  it under the terms of the GNU General Public License as published by
  11  *  the Free Software Foundation; either version 2 of the License, or
  12  *  (at your option) any later version.
  13  *
  14  *  This program is distributed in the hope that it will be useful,
  15  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  *  GNU General Public License for more details.
  18  *
  19  *  You should have received a copy of the GNU General Public License
  20  *  along with this program; if not, write to the Free Software
  21  *  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  22  */
  23
  24
  25 /*
  26  *  Definitions
  27  */
  28
  29 %{
  30 #include "config.h"
  31
  32 #include <sys/resource.h>
  33
  34 #if HAVE_UNISTD_H
  35 #include <sys/types.h>
  36 #include <unistd.h>
  37 #endif
  38
  39 #include <stdexcept>
  40
  41 #include "ginsh.h"
  42
  43 #define YYERROR_VERBOSE 1
  44
  45 // Original readline settings
  46 static int orig_completion_append_character;
  47 static char *orig_basic_word_break_characters;
  48
  49 // Expression stack for ", "" and """
  50 static void push(const ex &e);
  51 static ex exstack[3];
  52
  53 // Start and end time for the time() function
  54 static struct rusage start_time, end_time;
  55
  56 // Table of functions (a multimap, because one function may appear with different
  57 // numbers of parameters)
  58 typedef ex (*fcnp)(const exprseq &e);
  59 typedef ex (*fcnp2)(const exprseq &e, int serial);
  60
  61 struct fcn_desc {
  62         fcn_desc() : p(NULL), num_params(0) {}
  63         fcn_desc(fcnp func, int num) : p(func), num_params(num), is_ginac(false) {}
  64         fcn_desc(fcnp2 func, int num, int ser) : p((fcnp)func), num_params(num), is_ginac(true), serial(ser) {}
  65
  66         fcnp p;         // Pointer to function
  67         int num_params; // Number of parameters (0 = arbitrary)
  68         bool is_ginac;  // Flag: function is GiNaC function
  69         int serial;     // GiNaC function serial number (if is_ginac == true)
  70 };
  71
  72 typedef multimap<string, fcn_desc> fcn_tab;
  73 static fcn_tab fcns;
  74
  75 static fcn_tab::const_iterator find_function(const ex &sym, int req_params);
  76
  77 // Table to map help topics to help strings
  78 typedef multimap<string, string> help_tab;
  79 static help_tab help;
  80
  81 static void print_help(const string &topic);
  82 static void print_help_topics(void);
  83 %}
  84
  85 /* Tokens (T_LITERAL means a literal value returned by the parser, but not
  86    of class numeric or symbol (e.g. a constant or the FAIL object)) */
  87 %token T_NUMBER T_SYMBOL T_LITERAL T_DIGITS T_QUOTE T_QUOTE2 T_QUOTE3
  88 %token T_EQUAL T_NOTEQ T_LESSEQ T_GREATEREQ T_MATRIX_BEGIN T_MATRIX_END
  89
  90 %token T_QUIT T_WARRANTY T_PRINT T_READ T_WRITE T_TIME T_XYZZY T_INVENTORY T_LOOK T_SCORE
  91
  92 /* Operator precedence and associativity */
  93 %right '='
  94 %left T_EQUAL T_NOTEQ
  95 %left '<' '>' T_LESSEQ T_GREATEREQ
  96 %left '+' '-'
  97 %left '*' '/' '%'
  98 %nonassoc NEG
  99 %right '^'
 100 %nonassoc '!'
 101
 102 %start input
 103
 104
 105 /*
 106  *  Grammar rules
 107  */
 108
 109 %%
 110 input   : /* empty */
 111         | input line
 112         ;
 113
 114 line    : ';'
 115         | exp ';' {
 116                 try {
 117                         cout << $1 << endl;
 118                         push($1);
 119                 } catch (exception &e) {
 120                         cerr << e.what() << endl;
 121                         YYERROR;
 122                 }
 123         }
 124         | exp ':' {
 125                 try {
 126                         push($1);
 127                 } catch (exception &e) {
 128                         cerr << e.what() << endl;
 129                         YYERROR;
 130                 }
 131         }
 132         | T_PRINT '(' exp ')' ';' {
 133                 try {
 134                         $3.printtree(cout);
 135                 } catch (exception &e) {
 136                         cerr << e.what() << endl;
 137                         YYERROR;
 138                 }
 139         }
 140         | '?' T_SYMBOL          {print_help(ex_to_symbol($2).getname());}
 141         | '?' '?'               {print_help_topics();}
 142         | T_QUIT                {YYACCEPT;}
 143         | T_WARRANTY {
 144                 cout << "This program is free software; you can redistribute it and/or modify it under\n";
 145                 cout << "the terms of the GNU General Public License as published by the Free Software\n";
 146                 cout << "Foundation; either version 2 of the License, or (at your option) any later\n";
 147                 cout << "version.\n";
 148                 cout << "This program is distributed in the hope that it will be useful, but WITHOUT\n";
 149                 cout << "ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS\n";
 150                 cout << "FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more\n";
 151                 cout << "details.\n";
 152                 cout << "You should have received a copy of the GNU General Public License along with\n";
 153                 cout << "this program. If not, write to the Free Software Foundation, 675 Mass Ave,\n";
 154                 cout << "Cambridge, MA 02139, USA.\n";
 155         }
 156         | T_XYZZY               {cout << "Nothing happens.\n";}
 157         | T_INVENTORY           {cout << "You're not carrying anything.\n";}
 158         | T_LOOK                {cout << "You're in a twisty little maze of passages, all alike.\n";}
 159         | T_SCORE {
 160                 cout << "If you were to quit now, you would score ";
 161                 cout << (syms.size() > 350 ? 350 : syms.size());
 162                 cout << " out of a possible 350.\n";
 163         }
 164         | error ';'             {yyclearin; yyerrok;}
 165         | error ':'             {yyclearin; yyerrok;}
 166         ;
 167
 168 exp     : T_NUMBER              {$$ = $1;}
 169         | T_SYMBOL              {$$ = $1.eval();}
 170         | '\'' T_SYMBOL '\''    {$$ = $2;}
 171         | T_LITERAL             {$$ = $1;}
 172         | T_DIGITS              {$$ = $1;}
 173         | T_QUOTE               {$$ = exstack[0];}
 174         | T_QUOTE2              {$$ = exstack[1];}
 175         | T_QUOTE3              {$$ = exstack[2];}
 176         | T_TIME {getrusage(RUSAGE_SELF, &start_time);} '(' exp ')' {
 177                 getrusage(RUSAGE_SELF, &end_time);
 178                 $$ = (end_time.ru_utime.tv_sec - start_time.ru_utime.tv_sec) +
 179                      (end_time.ru_stime.tv_sec - start_time.ru_stime.tv_sec) +
 180                      double(end_time.ru_utime.tv_usec - start_time.ru_utime.tv_usec) / 1e6 +
 181                      double(end_time.ru_stime.tv_usec - start_time.ru_stime.tv_usec) / 1e6;
 182         }
 183         | T_SYMBOL '(' exprseq ')' {
 184                 fcn_tab::const_iterator i = find_function($1, $3.nops());
 185                 if (i->second.is_ginac) {
 186                         $$ = ((fcnp2)(i->second.p))(static_cast<const exprseq &>(*($3.bp)), i->second.serial);
 187                 } else {
 188                         $$ = (i->second.p)(static_cast<const exprseq &>(*($3.bp)));
 189                 }
 190         }
 191         | T_DIGITS '=' T_NUMBER {$$ = $3; Digits = ex_to_numeric($3).to_int();}
 192         | T_SYMBOL '=' exp      {$$ = $3; const_cast<symbol *>(&ex_to_symbol($1))->assign($3);}
 193         | exp T_EQUAL exp       {$$ = $1 == $3;}
 194         | exp T_NOTEQ exp       {$$ = $1 != $3;}
 195         | exp '<' exp           {$$ = $1 < $3;}
 196         | exp T_LESSEQ exp      {$$ = $1 <= $3;}
 197         | exp '>' exp           {$$ = $1 > $3;}
 198         | exp T_GREATEREQ exp   {$$ = $1 >= $3;}
 199         | exp '+' exp           {$$ = $1 + $3;}
 200         | exp '-' exp           {$$ = $1 - $3;}
 201         | exp '*' exp           {$$ = $1 * $3;}
 202         | exp '/' exp           {$$ = $1 / $3;}
 203         | exp '%' exp           {$$ = $1 % $3;}
 204         | '-' exp %prec NEG     {$$ = -$2;}
 205         | '+' exp %prec NEG     {$$ = $2;}
 206         | exp '^' exp           {$$ = power($1, $3);}
 207         | exp '!'               {$$ = factorial($1);}
 208         | '(' exp ')'           {$$ = $2;}
 209         | '[' list_or_empty ']' {$$ = $2;}
 210         | T_MATRIX_BEGIN matrix T_MATRIX_END    {$$ = lst_to_matrix($2);}
 211         ;
 212
 213 exprseq : exp                   {$$ = exprseq($1);}
 214         | exprseq ',' exp       {exprseq es(static_cast<exprseq &>(*($1.bp))); $$ = es.append($3);}
 215         ;
 216
 217 list_or_empty: /* empty */      {$$ = *new lst;}
 218         | list                  {$$ = $1;}
 219         ;
 220
 221 list    : exp                   {$$ = lst($1);}
 222         | list ',' exp          {lst l(static_cast<lst &>(*($1.bp))); $$ = l.append($3);}
 223         ;
 224
 225 matrix  : T_MATRIX_BEGIN row T_MATRIX_END               {$$ = lst($2);}
 226         | matrix ',' T_MATRIX_BEGIN row T_MATRIX_END    {lst l(static_cast<lst &>(*($1.bp))); $$ = l.append($4);}
 227         ;
 228
 229 row     : exp                   {$$ = lst($1);}
 230         | row ',' exp           {lst l(static_cast<lst &>(*($1.bp))); $$ = l.append($3);}
 231         ;
 232
 233
 234 /*
 235  *  Routines
 236  */
 237
 238 %%
 239 // Error print routine
 240 int yyerror(char *s)
 241 {
 242         cerr << s << " at " << yytext << endl;
 243         return 0;
 244 }
 245
 246 // Push expression "e" onto the expression stack (for ", "" and """)
 247 static void push(const ex &e)
 248 {
 249         exstack[2] = exstack[1];
 250         exstack[1] = exstack[0];
 251         exstack[0] = e;
 252 }
 253
 254
 255 /*
 256  *  Built-in functions
 257  */
 258
 259 static ex f_denom(const exprseq &e) {return e[0].denom();}
 260 static ex f_eval1(const exprseq &e) {return e[0].eval();}
 261 static ex f_evalf1(const exprseq &e) {return e[0].evalf();}
 262 static ex f_expand(const exprseq &e) {return e[0].expand();}
 263 static ex f_gcd(const exprseq &e) {return gcd(e[0], e[1]);}
 264 static ex f_lcm(const exprseq &e) {return lcm(e[0], e[1]);}
 265 static ex f_lsolve(const exprseq &e) {return lsolve(e[0], e[1]);}
 266 static ex f_nops(const exprseq &e) {return e[0].nops();}
 267 static ex f_normal1(const exprseq &e) {return e[0].normal();}
 268 static ex f_numer(const exprseq &e) {return e[0].numer();}
 269 static ex f_pow(const exprseq &e) {return pow(e[0], e[1]);}
 270 static ex f_sqrt(const exprseq &e) {return sqrt(e[0]);}
 271 static ex f_subs2(const exprseq &e) {return e[0].subs(e[1]);}
 272
 273 #define CHECK_ARG(num, type, fcn) if (!is_ex_of_type(e[num], type)) throw(std::invalid_argument("argument " #num " to " #fcn " must be a " #type))
 274
 275 static ex f_charpoly(const exprseq &e)
 276 {
 277         CHECK_ARG(0, matrix, charpoly);
 278         CHECK_ARG(1, symbol, charpoly);
 279         return ex_to_matrix(e[0]).charpoly(ex_to_symbol(e[1]));
 280 }
 281
 282 static ex f_coeff(const exprseq &e)
 283 {
 284         CHECK_ARG(1, symbol, coeff);
 285         CHECK_ARG(2, numeric, coeff);
 286         return e[0].coeff(ex_to_symbol(e[1]), ex_to_numeric(e[2]).to_int());
 287 }
 288
 289 static ex f_collect(const exprseq &e)
 290 {
 291         CHECK_ARG(1, symbol, collect);
 292         return e[0].collect(ex_to_symbol(e[1]));
 293 }
 294
 295 static ex f_content(const exprseq &e)
 296 {
 297         CHECK_ARG(1, symbol, content);
 298         return e[0].content(ex_to_symbol(e[1]));
 299 }
 300
 301 static ex f_degree(const exprseq &e)
 302 {
 303         CHECK_ARG(1, symbol, degree);
 304         return e[0].degree(ex_to_symbol(e[1]));
 305 }
 306
 307 static ex f_determinant(const exprseq &e)
 308 {
 309         CHECK_ARG(0, matrix, determinant);
 310         return ex_to_matrix(e[0]).determinant();
 311 }
 312
 313 static ex f_diag(const exprseq &e)
 314 {
 315         unsigned dim = e.nops();
 316         matrix &m = *new matrix(dim, dim);
 317         for (unsigned i=0; i<dim; i++)
 318                 m.set(i, i, e.op(i));
 319         return m;
 320 }
 321
 322 static ex f_diff2(const exprseq &e)
 323 {
 324         CHECK_ARG(1, symbol, diff);
 325         return e[0].diff(ex_to_symbol(e[1]));
 326 }
 327
 328 static ex f_diff3(const exprseq &e)
 329 {
 330         CHECK_ARG(1, symbol, diff);
 331         CHECK_ARG(2, numeric, diff);
 332         return e[0].diff(ex_to_symbol(e[1]), ex_to_numeric(e[2]).to_int());
 333 }
 334
 335 static ex f_divide(const exprseq &e)
 336 {
 337         ex q;
 338         if (divide(e[0], e[1], q))
 339                 return q;
 340         else
 341                 return *new fail();
 342 }
 343
 344 static ex f_eval2(const exprseq &e)
 345 {
 346         CHECK_ARG(1, numeric, eval);
 347         return e[0].eval(ex_to_numeric(e[1]).to_int());
 348 }
 349
 350 static ex f_evalf2(const exprseq &e)
 351 {
 352         CHECK_ARG(1, numeric, evalf);
 353         return e[0].evalf(ex_to_numeric(e[1]).to_int());
 354 }
 355
 356 static ex f_has(const exprseq &e)
 357 {
 358         return e[0].has(e[1]) ? ex(1) : ex(0);
 359 }
 360
 361 static ex f_inverse(const exprseq &e)
 362 {
 363         CHECK_ARG(0, matrix, inverse);
 364         return ex_to_matrix(e[0]).inverse();
 365 }
 366
 367 static ex f_is(const exprseq &e)
 368 {
 369         CHECK_ARG(0, relational, is);
 370         return (bool)ex_to_relational(e[0]) ? ex(1) : ex(0);
 371 }
 372
 373 static ex f_lcoeff(const exprseq &e)
 374 {
 375         CHECK_ARG(1, symbol, lcoeff);
 376         return e[0].lcoeff(ex_to_symbol(e[1]));
 377 }
 378
 379 static ex f_ldegree(const exprseq &e)
 380 {
 381         CHECK_ARG(1, symbol, ldegree);
 382         return e[0].ldegree(ex_to_symbol(e[1]));
 383 }
 384
 385 static ex f_normal2(const exprseq &e)
 386 {
 387         CHECK_ARG(1, numeric, normal);
 388         return e[0].normal(ex_to_numeric(e[1]).to_int());
 389 }
 390
 391 static ex f_op(const exprseq &e)
 392 {
 393         CHECK_ARG(1, numeric, op);
 394         int n = ex_to_numeric(e[1]).to_int();
 395         if (n < 0 || n >= (int)e[0].nops())
 396                 throw(std::out_of_range("second argument to op() is out of range"));
 397         return e[0].op(n);
 398 }
 399
 400 static ex f_prem(const exprseq &e)
 401 {
 402         CHECK_ARG(2, symbol, prem);
 403         return prem(e[0], e[1], ex_to_symbol(e[2]));
 404 }
 405
 406 static ex f_primpart(const exprseq &e)
 407 {
 408         CHECK_ARG(1, symbol, primpart);
 409         return e[0].primpart(ex_to_symbol(e[1]));
 410 }
 411
 412 static ex f_quo(const exprseq &e)
 413 {
 414         CHECK_ARG(2, symbol, quo);
 415         return quo(e[0], e[1], ex_to_symbol(e[2]));
 416 }
 417
 418 static ex f_rem(const exprseq &e)
 419 {
 420         CHECK_ARG(2, symbol, rem);
 421         return rem(e[0], e[1], ex_to_symbol(e[2]));
 422 }
 423
 424 static ex f_series(const exprseq &e)
 425 {
 426         CHECK_ARG(2, numeric, series);
 427         return e[0].series(e[1], ex_to_numeric(e[2]).to_int());
 428 }
 429
 430 static ex f_sqrfree(const exprseq &e)
 431 {
 432         CHECK_ARG(1, symbol, sqrfree);
 433         return sqrfree(e[0], ex_to_symbol(e[1]));
 434 }
 435
 436 static ex f_subs3(const exprseq &e)
 437 {
 438         CHECK_ARG(1, lst, subs);
 439         CHECK_ARG(2, lst, subs);
 440         return e[0].subs(ex_to_lst(e[1]), ex_to_lst(e[2]));
 441 }
 442
 443 static ex f_tcoeff(const exprseq &e)
 444 {
 445         CHECK_ARG(1, symbol, tcoeff);
 446         return e[0].tcoeff(ex_to_symbol(e[1]));
 447 }
 448
 449 static ex f_trace(const exprseq &e)
 450 {
 451         CHECK_ARG(0, matrix, trace);
 452         return ex_to_matrix(e[0]).trace();
 453 }
 454
 455 static ex f_transpose(const exprseq &e)
 456 {
 457         CHECK_ARG(0, matrix, transpose);
 458         return ex_to_matrix(e[0]).transpose();
 459 }
 460
 461 static ex f_unassign(const exprseq &e)
 462 {
 463         CHECK_ARG(0, symbol, unassign);
 464         (const_cast<symbol *>(&ex_to_symbol(e[0])))->unassign();
 465         return e[0];
 466 }
 467
 468 static ex f_unit(const exprseq &e)
 469 {
 470         CHECK_ARG(1, symbol, unit);
 471         return e[0].unit(ex_to_symbol(e[1]));
 472 }
 473
 474 static ex f_dummy(const exprseq &e)
 475 {
 476         throw(std::logic_error("dummy function called (shouldn't happen)"));
 477 }
 478
 479 // Table for initializing the "fcns" map
 480 struct fcn_init {
 481         const char *name;
 482         const fcn_desc desc;
 483 };
 484
 485 static const fcn_init builtin_fcns[] = {
 486         {"charpoly", fcn_desc(f_charpoly, 2)},
 487         {"coeff", fcn_desc(f_coeff, 3)},
 488         {"collect", fcn_desc(f_collect, 2)},
 489         {"content", fcn_desc(f_content, 2)},
 490         {"degree", fcn_desc(f_degree, 2)},
 491         {"denom", fcn_desc(f_denom, 1)},
 492         {"determinant", fcn_desc(f_determinant, 1)},
 493         {"diag", fcn_desc(f_diag, 0)},
 494         {"diff", fcn_desc(f_diff2, 2)},
 495         {"diff", fcn_desc(f_diff3, 3)},
 496         {"divide", fcn_desc(f_divide, 2)},
 497         {"eval", fcn_desc(f_eval1, 1)},
 498         {"eval", fcn_desc(f_eval2, 2)},
 499         {"evalf", fcn_desc(f_evalf1, 1)},
 500         {"evalf", fcn_desc(f_evalf2, 2)},
 501         {"expand", fcn_desc(f_expand, 1)},
 502         {"gcd", fcn_desc(f_gcd, 2)},
 503         {"has", fcn_desc(f_has, 2)},
 504         {"inverse", fcn_desc(f_inverse, 1)},
 505         {"is", fcn_desc(f_is, 1)},
 506         {"lcm", fcn_desc(f_lcm, 2)},
 507         {"lcoeff", fcn_desc(f_lcoeff, 2)},
 508         {"ldegree", fcn_desc(f_ldegree, 2)},
 509         {"lsolve", fcn_desc(f_lsolve, 2)},
 510         {"nops", fcn_desc(f_nops, 1)},
 511         {"normal", fcn_desc(f_normal1, 1)},
 512         {"normal", fcn_desc(f_normal2, 2)},
 513         {"numer", fcn_desc(f_numer, 1)},
 514         {"op", fcn_desc(f_op, 2)},
 515         {"pow", fcn_desc(f_pow, 2)},
 516         {"prem", fcn_desc(f_prem, 3)},
 517         {"primpart", fcn_desc(f_primpart, 2)},
 518         {"quo", fcn_desc(f_quo, 3)},
 519         {"rem", fcn_desc(f_rem, 3)},
 520         {"series", fcn_desc(f_series, 3)},
 521         {"sqrfree", fcn_desc(f_sqrfree, 2)},
 522         {"sqrt", fcn_desc(f_sqrt, 1)},
 523         {"subs", fcn_desc(f_subs2, 2)},
 524         {"subs", fcn_desc(f_subs3, 3)},
 525         {"tcoeff", fcn_desc(f_tcoeff, 2)},
 526         {"time", fcn_desc(f_dummy, 0)},
 527         {"trace", fcn_desc(f_trace, 1)},
 528         {"transpose", fcn_desc(f_transpose, 1)},
 529         {"unassign", fcn_desc(f_unassign, 1)},
 530         {"unit", fcn_desc(f_unit, 2)},
 531         {NULL, fcn_desc(f_dummy, 0)}    // End marker
 532 };
 533
 534
 535 /*
 536  *  Add functions to ginsh
 537  */
 538
 539 // Functions from fcn_init array
 540 static void insert_fcns(const fcn_init *p)
 541 {
 542         while (p->name) {
 543                 fcns.insert(make_pair(string(p->name), p->desc));
 544                 p++;
 545         }
 546 }
 547
 548 static ex f_ginac_function(const exprseq &es, int serial)
 549 {
 550         return function(serial, es).eval(1);
 551 }
 552
 553 // All registered GiNaC functions
 554 #ifndef NO_NAMESPACE_GINAC
 555 void GiNaC::ginsh_get_ginac_functions(void)
 556 #else // ndef NO_NAMESPACE_GINAC
 557 void ginsh_get_ginac_functions(void)
 558 #endif // ndef NO_NAMESPACE_GINAC
 559 {
 560         vector<function_options>::const_iterator i = function::registered_functions().begin(), end = function::registered_functions().end();
 561         unsigned serial = 0;
 562         while (i != end) {
 563                 fcns.insert(make_pair(i->get_name(), fcn_desc(f_ginac_function, i->get_nparams(), serial)));
 564                 i++;
 565                 serial++;
 566         }
 567 }
 568
 569
 570 /*
 571  *  Find a function given a name and number of parameters. Throw exceptions on error.
 572  */
 573
 574 static fcn_tab::const_iterator find_function(const ex &sym, int req_params)
 575 {
 576         const string &name = ex_to_symbol(sym).getname();
 577         typedef fcn_tab::const_iterator I;
 578         pair<I, I> b = fcns.equal_range(name);
 579         if (b.first == b.second)
 580                 throw(std::logic_error("unknown function '" + name + "'"));
 581         else {
 582                 for (I i=b.first; i!=b.second; i++)
 583                         if ((i->second.num_params == 0) || (i->second.num_params == req_params))
 584                                 return i;
 585         }
 586         throw(std::logic_error("invalid number of arguments to " + name + "()"));
 587 }
 588
 589
 590 /*
 591  *  Insert help strings
 592  */
 593
 594 // Normal help string
 595 static void insert_help(const char *topic, const char *str)
 596 {
 597         help.insert(make_pair(string(topic), string(str)));
 598 }
 599
 600 // Help string for functions, automatically generates synopsis
 601 static void insert_fcn_help(const char *name, const char *str)
 602 {
 603         typedef fcn_tab::const_iterator I;
 604         pair<I, I> b = fcns.equal_range(name);
 605         if (b.first != b.second) {
 606                 string help_str = string(name) + "(";
 607                 for (int i=0; i<b.first->second.num_params; i++) {
 608                         if (i)
 609                                 help_str += ", ";
 610                         help_str += "expression";
 611                 }
 612                 help_str += ") - ";
 613                 help_str += str;
 614                 help.insert(make_pair(string(name), help_str));
 615         }
 616 }
 617
 618
 619 /*
 620  *  Print help to cout
 621  */
 622
 623 // Help for a given topic
 624 static void print_help(const string &topic)
 625 {
 626         typedef help_tab::const_iterator I;
 627         pair<I, I> b = help.equal_range(topic);
 628         if (b.first == b.second)
 629                 cout << "no help for '" << topic << "'\n";
 630         else {
 631                 for (I i=b.first; i!=b.second; i++)
 632                         cout << i->second << endl;
 633         }
 634 }
 635
 636 // List of help topics
 637 static void print_help_topics(void)
 638 {
 639         cout << "Available help topics:\n";
 640         help_tab::const_iterator i;
 641         string last_name = string("*");
 642         int num = 0;
 643         for (i=help.begin(); i!=help.end(); i++) {
 644                 // Don't print duplicates
 645                 if (i->first != last_name) {
 646                         if (num)
 647                                 cout << ", ";
 648                         num++;
 649                         cout << i->first;
 650                         last_name = i->first;
 651                 }
 652         }
 653         cout << "\nTo get help for a certain topic, type ?topic\n";
 654 }
 655
 656
 657 /*
 658  *  Function name completion functions for readline
 659  */
 660
 661 static char *fcn_generator(char *text, int state)
 662 {
 663         static int len;                         // Length of word to complete
 664         static fcn_tab::const_iterator index;   // Iterator to function being currently considered
 665
 666         // If this is a new word to complete, initialize now
 667         if (state == 0) {
 668                 index = fcns.begin();
 669                 len = strlen(text);
 670         }
 671
 672         // Return the next function which partially matches
 673         while (index != fcns.end()) {
 674                 const char *fcn_name = index->first.c_str();
 675                 index++;
 676                 if (strncmp(fcn_name, text, len) == 0)
 677                         return strdup(fcn_name);
 678         }
 679         return NULL;
 680 }
 681
 682 static char **fcn_completion(char *text, int start, int end)
 683 {
 684         if (rl_line_buffer[0] == '!') {
 685                 // For shell commands, revert back to filename completion
 686                 rl_completion_append_character = orig_completion_append_character;
 687                 rl_basic_word_break_characters = orig_basic_word_break_characters;
 688                 return completion_matches(text, (CPFunction *)filename_completion_function);
 689         } else {
 690                 // Otherwise, complete function names
 691                 rl_completion_append_character = '(';
 692                 rl_basic_word_break_characters = " \t\n\"#$%&'()*+,-./:;<=>?@[\\]^`{|}~";
 693                 return completion_matches(text, (CPFunction *)fcn_generator);
 694         }
 695 }
 696
 697 void greeting(void)
 698 {
 699     cout << "ginsh - GiNaC Interactive Shell (" << PACKAGE << " V" << VERSION << ")" << endl;
 700     cout << "  __,  _______  Copyright (C) 1999-2000 Johannes Gutenberg University Mainz,\n"
 701          << " (__) *       | Germany.  This is free software with ABSOLUTELY NO WARRANTY.\n"
 702          << "  ._) i N a C | You are welcome to redistribute it under certain conditions.\n"
 703          << "<-------------' For details type `warranty;'.\n" << endl;
 704     cout << "Type ?? for a list of help topics." << endl;
 705 }
 706
 707 /*
 708  *  Main program
 709  */
 710
 711 int main(int argc, char **argv)
 712 {
 713         // Print banner in interactive mode
 714         if (isatty(0))
 715                 greeting();
 716
 717         // Init function table
 718         insert_fcns(builtin_fcns);
 719         ginsh_get_ginac_functions();
 720
 721         // Init help for operators (automatically generated from man page)
 722         insert_help("operators", "Operators in falling order of precedence:");
 723 #include "ginsh_op_help.c"
 724
 725         // Init help for built-in functions (automatically generated from man page)
 726 #include "ginsh_fcn_help.c"
 727
 728         // Help for GiNaC functions is added manually
 729         insert_fcn_help("acos", "inverse cosine function");
 730         insert_fcn_help("acosh", "inverse hyperbolic cosine function");
 731         insert_fcn_help("asin", "inverse sine function");
 732         insert_fcn_help("asinh", "inverse hyperbolic sine function");
 733         insert_fcn_help("atan", "inverse tangent function");
 734         insert_fcn_help("atan2", "inverse tangent function with two arguments");
 735         insert_fcn_help("atanh", "inverse hyperbolic tangent function");
 736         insert_fcn_help("beta", "Beta function");
 737         insert_fcn_help("binomial", "binomial function");
 738         insert_fcn_help("cos", "cosine function");
 739         insert_fcn_help("cosh", "hyperbolic cosine function");
 740         insert_fcn_help("exp", "exponential function");
 741         insert_fcn_help("factorial", "factorial function");
 742         insert_fcn_help("lgamma", "natural logarithm of Gamma function");
 743         insert_fcn_help("tgamma", "Gamma function");
 744         insert_fcn_help("log", "natural logarithm");
 745         insert_fcn_help("psi", "psi function\npsi(x) is the digamma function, psi(n,x) the nth polygamma function");
 746         insert_fcn_help("sin", "sine function");
 747         insert_fcn_help("sinh", "hyperbolic sine function");
 748         insert_fcn_help("tan", "tangent function");
 749         insert_fcn_help("tanh", "hyperbolic tangent function");
 750         insert_fcn_help("zeta", "zeta function\nzeta(x) is Riemann's zeta function, zeta(n,x) its nth derivative");
 751         insert_fcn_help("Li2", "dilogarithm");
 752         insert_fcn_help("Li3", "trilogarithm");
 753         insert_fcn_help("Order", "order term function (for truncated power series)");
 754
 755         // Init readline completer
 756         rl_readline_name = argv[0];
 757         rl_attempted_completion_function = (CPPFunction *)fcn_completion;
 758         orig_completion_append_character = rl_completion_append_character;
 759         orig_basic_word_break_characters = rl_basic_word_break_characters;
 760
 761         // Init input file list, open first file
 762         num_files = argc - 1;
 763         file_list = argv + 1;
 764         if (num_files) {
 765                 yyin = fopen(*file_list, "r");
 766                 if (yyin == NULL) {
 767                         cerr << "Can't open " << *file_list << endl;
 768                         exit(1);
 769                 }
 770                 num_files--;
 771                 file_list++;
 772         }
 773
 774         // Parse input, catch all remaining exceptions
 775         int result;
 776 again:  try {
 777                 result = yyparse();
 778         } catch (exception &e) {
 779                 cerr << e.what() << endl;
 780                 goto again;
 781         }
 782         return result;
 783 }