ginsh/ginsh_parser.yy

   1 /** @file ginsh_parser.yy
   2  *
   3  *  Input grammar definition for ginsh.
   4  *  This file must be processed with yacc/bison.
   5  *
   6  *  GiNaC Copyright (C) 1999-2000 Johannes Gutenberg University Mainz, Germany
   7  *
   8  *  This program is free software; you can redistribute it and/or modify
   9  *  it under the terms of the GNU General Public License as published by
  10  *  the Free Software Foundation; either version 2 of the License, or
  11  *  (at your option) any later version.
  12  *
  13  *  This program is distributed in the hope that it will be useful,
  14  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  *  GNU General Public License for more details.
  17  *
  18  *  You should have received a copy of the GNU General Public License
  19  *  along with this program; if not, write to the Free Software
  20  *  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  21  */
  22
  23
  24 /*
  25  *  Definitions
  26  */
  27
  28 %{
  29 #include "config.h"
  30
  31 #include <sys/resource.h>
  32
  33 #if HAVE_UNISTD_H
  34 #include <sys/types.h>
  35 #include <unistd.h>
  36 #endif
  37
  38 #include <stdexcept>
  39
  40 #include "ginsh.h"
  41
  42 // Original readline settings
  43 static int orig_completion_append_character;
  44 static char *orig_basic_word_break_characters;
  45
  46 // Expression stack for ", "" and """
  47 static void push(const ex &e);
  48 static ex exstack[3];
  49
  50 // Start and end time for the time() function
  51 static struct rusage start_time, end_time;
  52
  53 // Table of functions (a multimap, because one function may appear with different
  54 // numbers of parameters)
  55 typedef ex (*fcnp)(const exprseq &e);
  56 typedef ex (*fcnp2)(const exprseq &e, int serial);
  57
  58 struct fcn_desc {
  59         fcn_desc() : p(NULL), num_params(0) {}
  60         fcn_desc(fcnp func, int num) : p(func), num_params(num), is_ginac(false) {}
  61         fcn_desc(fcnp2 func, int num, int ser) : p((fcnp)func), num_params(num), is_ginac(true), serial(ser) {}
  62
  63         fcnp p;         // Pointer to function
  64         int num_params; // Number of parameters (0 = arbitrary)
  65         bool is_ginac;  // Flag: function is GiNaC function
  66         int serial;     // GiNaC function serial number (if is_ginac == true)
  67 };
  68
  69 typedef multimap<string, fcn_desc> fcn_tab;
  70 static fcn_tab fcns;
  71
  72 static fcn_tab::const_iterator find_function(const ex &sym, int req_params);
  73
  74 // Table to map help topics to help strings
  75 typedef multimap<string, string> help_tab;
  76 static help_tab help;
  77
  78 static void print_help(const string &topic);
  79 static void print_help_topics(void);
  80
  81 static ex lst2matrix(const ex &l);
  82 %}
  83
  84 /* Tokens (T_LITERAL means a literal value returned by the parser, but not
  85    of class numeric or symbol (e.g. a constant or the FAIL object)) */
  86 %token T_NUMBER T_SYMBOL T_LITERAL T_DIGITS T_QUOTE T_QUOTE2 T_QUOTE3
  87 %token T_EQUAL T_NOTEQ T_LESSEQ T_GREATEREQ T_MATRIX_BEGIN T_MATRIX_END
  88
  89 %token T_QUIT T_WARRANTY T_PRINT T_READ T_WRITE T_TIME T_XYZZY T_INVENTORY T_LOOK T_SCORE
  90
  91 /* Operator precedence and associativity */
  92 %right '='
  93 %left T_EQUAL T_NOTEQ
  94 %left '<' '>' T_LESSEQ T_GREATEREQ
  95 %left '+' '-'
  96 %left '*' '/' '%'
  97 %nonassoc NEG
  98 %right '^'
  99 %nonassoc '!'
 100
 101 %start input
 102
 103
 104 /*
 105  *  Grammar rules
 106  */
 107
 108 %%
 109 input   : /* empty */
 110         | input line
 111         ;
 112
 113 line    : ';'
 114         | exp ';' {
 115                 try {
 116                         cout << $1 << endl;
 117                         push($1);
 118                 } catch (exception &e) {
 119                         cerr << e.what() << endl;
 120                         YYERROR;
 121                 }
 122         }
 123         | exp ':' {
 124                 try {
 125                         push($1);
 126                 } catch (exception &e) {
 127                         cerr << e.what() << endl;
 128                         YYERROR;
 129                 }
 130         }
 131         | T_PRINT '(' exp ')' ';' {
 132                 try {
 133                         $3.printtree(cout);
 134                 } catch (exception &e) {
 135                         cerr << e.what() << endl;
 136                         YYERROR;
 137                 }
 138         }
 139         | '?' T_SYMBOL          {print_help(ex_to_symbol($2).getname());}
 140         | '?' '?'               {print_help_topics();}
 141         | T_QUIT                {YYACCEPT;}
 142         | T_WARRANTY {
 143                 cout << "This program is free software; you can redistribute it and/or modify it under\n";
 144                 cout << "the terms of the GNU General Public License as published by the Free Software\n";
 145                 cout << "Foundation; either version 2 of the License, or (at your option) any later\n";
 146                 cout << "version.\n";
 147                 cout << "This program is distributed in the hope that it will be useful, but WITHOUT\n";
 148                 cout << "ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS\n";
 149                 cout << "FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more\n";
 150                 cout << "details.\n";
 151                 cout << "You should have received a copy of the GNU General Public License along with\n";
 152                 cout << "this program. If not, write to the Free Software Foundation, 675 Mass Ave,\n";
 153                 cout << "Cambridge, MA 02139, USA.\n";
 154         }
 155         | T_XYZZY               {cout << "Nothing happens.\n";}
 156         | T_INVENTORY           {cout << "You're not carrying anything.\n";}
 157         | T_LOOK                {cout << "You're in a twisty little maze of passages, all alike.\n";}
 158         | T_SCORE {
 159                 cout << "If you were to quit now, you would score ";
 160                 cout << (syms.size() > 350 ? 350 : syms.size());
 161                 cout << " out of a possible 350.\n";
 162         }
 163         | error ';'             {yyclearin; yyerrok;}
 164         | error ':'             {yyclearin; yyerrok;}
 165         ;
 166
 167 exp     : T_NUMBER              {$$ = $1;}
 168         | T_SYMBOL              {$$ = $1.eval();}
 169         | '\'' T_SYMBOL '\''    {$$ = $2;}
 170         | T_LITERAL             {$$ = $1;}
 171         | T_DIGITS              {$$ = $1;}
 172         | T_QUOTE               {$$ = exstack[0];}
 173         | T_QUOTE2              {$$ = exstack[1];}
 174         | T_QUOTE3              {$$ = exstack[2];}
 175         | T_TIME {getrusage(RUSAGE_SELF, &start_time);} '(' exp ')' {
 176                 getrusage(RUSAGE_SELF, &end_time);
 177                 $$ = (end_time.ru_utime.tv_sec - start_time.ru_utime.tv_sec) +
 178                      (end_time.ru_stime.tv_sec - start_time.ru_stime.tv_sec) +
 179                      double(end_time.ru_utime.tv_usec - start_time.ru_utime.tv_usec) / 1e6 +
 180                      double(end_time.ru_stime.tv_usec - start_time.ru_stime.tv_usec) / 1e6;
 181         }
 182         | T_SYMBOL '(' exprseq ')' {
 183                 fcn_tab::const_iterator i = find_function($1, $3.nops());
 184                 if (i->second.is_ginac) {
 185                         $$ = ((fcnp2)(i->second.p))(static_cast<const exprseq &>(*($3.bp)), i->second.serial);
 186                 } else {
 187                         $$ = (i->second.p)(static_cast<const exprseq &>(*($3.bp)));
 188                 }
 189         }
 190         | T_DIGITS '=' T_NUMBER {$$ = $3; Digits = ex_to_numeric($3).to_int();}
 191         | T_SYMBOL '=' exp      {$$ = $3; const_cast<symbol *>(&ex_to_symbol($1))->assign($3);}
 192         | exp T_EQUAL exp       {$$ = $1 == $3;}
 193         | exp T_NOTEQ exp       {$$ = $1 != $3;}
 194         | exp '<' exp           {$$ = $1 < $3;}
 195         | exp T_LESSEQ exp      {$$ = $1 <= $3;}
 196         | exp '>' exp           {$$ = $1 > $3;}
 197         | exp T_GREATEREQ exp   {$$ = $1 >= $3;}
 198         | exp '+' exp           {$$ = $1 + $3;}
 199         | exp '-' exp           {$$ = $1 - $3;}
 200         | exp '*' exp           {$$ = $1 * $3;}
 201         | exp '/' exp           {$$ = $1 / $3;}
 202         | exp '%' exp           {$$ = $1 % $3;}
 203         | '-' exp %prec NEG     {$$ = -$2;}
 204         | '+' exp %prec NEG     {$$ = $2;}
 205         | exp '^' exp           {$$ = power($1, $3);}
 206         | exp '!'               {$$ = factorial($1);}
 207         | '(' exp ')'           {$$ = $2;}
 208         | '[' list_or_empty ']' {$$ = $2;}
 209         | T_MATRIX_BEGIN matrix T_MATRIX_END    {$$ = lst2matrix($2);}
 210         ;
 211
 212 exprseq : exp                   {$$ = exprseq($1);}
 213         | exprseq ',' exp       {exprseq es(static_cast<exprseq &>(*($1.bp))); $$ = es.append($3);}
 214         ;
 215
 216 list_or_empty: /* empty */      {$$ = *new lst;}
 217         | list                  {$$ = $1;}
 218         ;
 219
 220 list    : exp                   {$$ = lst($1);}
 221         | list ',' exp          {lst l(static_cast<lst &>(*($1.bp))); $$ = l.append($3);}
 222         ;
 223
 224 matrix  : T_MATRIX_BEGIN row T_MATRIX_END               {$$ = lst($2);}
 225         | matrix ',' T_MATRIX_BEGIN row T_MATRIX_END    {lst l(static_cast<lst &>(*($1.bp))); $$ = l.append($4);}
 226         ;
 227
 228 row     : exp                   {$$ = lst($1);}
 229         | row ',' exp           {lst l(static_cast<lst &>(*($1.bp))); $$ = l.append($3);}
 230         ;
 231
 232
 233 /*
 234  *  Routines
 235  */
 236
 237 %%
 238 // Error print routine
 239 int yyerror(char *s)
 240 {
 241         cerr << s << " at " << yytext << endl;
 242         return 0;
 243 }
 244
 245 // Push expression "e" onto the expression stack (for ", "" and """)
 246 static void push(const ex &e)
 247 {
 248         exstack[2] = exstack[1];
 249         exstack[1] = exstack[0];
 250         exstack[0] = e;
 251 }
 252
 253
 254 /*
 255  *  Built-in functions
 256  */
 257
 258 static ex f_denom(const exprseq &e) {return e[0].denom();}
 259 static ex f_eval1(const exprseq &e) {return e[0].eval();}
 260 static ex f_evalf1(const exprseq &e) {return e[0].evalf();}
 261 static ex f_expand(const exprseq &e) {return e[0].expand();}
 262 static ex f_gcd(const exprseq &e) {return gcd(e[0], e[1]);}
 263 static ex f_lcm(const exprseq &e) {return lcm(e[0], e[1]);}
 264 static ex f_lsolve(const exprseq &e) {return lsolve(e[0], e[1]);}
 265 static ex f_nops(const exprseq &e) {return e[0].nops();}
 266 static ex f_normal1(const exprseq &e) {return e[0].normal();}
 267 static ex f_numer(const exprseq &e) {return e[0].numer();}
 268 static ex f_pow(const exprseq &e) {return pow(e[0], e[1]);}
 269 static ex f_sqrt(const exprseq &e) {return sqrt(e[0]);}
 270 static ex f_subs2(const exprseq &e) {return e[0].subs(e[1]);}
 271
 272 #define CHECK_ARG(num, type, fcn) if (!is_ex_of_type(e[num], type)) throw(std::invalid_argument("argument " #num " to " #fcn " must be a " #type))
 273
 274 static ex f_charpoly(const exprseq &e)
 275 {
 276         CHECK_ARG(0, matrix, charpoly);
 277         CHECK_ARG(1, symbol, charpoly);
 278         return ex_to_matrix(e[0]).charpoly(ex_to_symbol(e[1]));
 279 }
 280
 281 static ex f_coeff(const exprseq &e)
 282 {
 283         CHECK_ARG(1, symbol, coeff);
 284         CHECK_ARG(2, numeric, coeff);
 285         return e[0].coeff(ex_to_symbol(e[1]), ex_to_numeric(e[2]).to_int());
 286 }
 287
 288 static ex f_collect(const exprseq &e)
 289 {
 290         CHECK_ARG(1, symbol, collect);
 291         return e[0].collect(ex_to_symbol(e[1]));
 292 }
 293
 294 static ex f_content(const exprseq &e)
 295 {
 296         CHECK_ARG(1, symbol, content);
 297         return e[0].content(ex_to_symbol(e[1]));
 298 }
 299
 300 static ex f_degree(const exprseq &e)
 301 {
 302         CHECK_ARG(1, symbol, degree);
 303         return e[0].degree(ex_to_symbol(e[1]));
 304 }
 305
 306 static ex f_determinant(const exprseq &e)
 307 {
 308         CHECK_ARG(0, matrix, determinant);
 309         return ex_to_matrix(e[0]).determinant();
 310 }
 311
 312 static ex f_diag(const exprseq &e)
 313 {
 314         unsigned dim = e.nops();
 315         matrix &m = *new matrix(dim, dim);
 316         for (unsigned i=0; i<dim; i++)
 317                 m.set(i, i, e.op(i));
 318         return m;
 319 }
 320
 321 static ex f_diff2(const exprseq &e)
 322 {
 323         CHECK_ARG(1, symbol, diff);
 324         return e[0].diff(ex_to_symbol(e[1]));
 325 }
 326
 327 static ex f_diff3(const exprseq &e)
 328 {
 329         CHECK_ARG(1, symbol, diff);
 330         CHECK_ARG(2, numeric, diff);
 331         return e[0].diff(ex_to_symbol(e[1]), ex_to_numeric(e[2]).to_int());
 332 }
 333
 334 static ex f_divide(const exprseq &e)
 335 {
 336         ex q;
 337         if (divide(e[0], e[1], q))
 338                 return q;
 339         else
 340                 return *new fail();
 341 }
 342
 343 static ex f_eval2(const exprseq &e)
 344 {
 345         CHECK_ARG(1, numeric, eval);
 346         return e[0].eval(ex_to_numeric(e[1]).to_int());
 347 }
 348
 349 static ex f_evalf2(const exprseq &e)
 350 {
 351         CHECK_ARG(1, numeric, evalf);
 352         return e[0].evalf(ex_to_numeric(e[1]).to_int());
 353 }
 354
 355 static ex f_has(const exprseq &e)
 356 {
 357         return e[0].has(e[1]) ? ex(1) : ex(0);
 358 }
 359
 360 static ex f_inverse(const exprseq &e)
 361 {
 362         CHECK_ARG(0, matrix, inverse);
 363         return ex_to_matrix(e[0]).inverse();
 364 }
 365
 366 static ex f_is(const exprseq &e)
 367 {
 368         CHECK_ARG(0, relational, is);
 369         return (bool)ex_to_relational(e[0]) ? ex(1) : ex(0);
 370 }
 371
 372 static ex f_lcoeff(const exprseq &e)
 373 {
 374         CHECK_ARG(1, symbol, lcoeff);
 375         return e[0].lcoeff(ex_to_symbol(e[1]));
 376 }
 377
 378 static ex f_ldegree(const exprseq &e)
 379 {
 380         CHECK_ARG(1, symbol, ldegree);
 381         return e[0].ldegree(ex_to_symbol(e[1]));
 382 }
 383
 384 static ex f_normal2(const exprseq &e)
 385 {
 386         CHECK_ARG(1, numeric, normal);
 387         return e[0].normal(ex_to_numeric(e[1]).to_int());
 388 }
 389
 390 static ex f_op(const exprseq &e)
 391 {
 392         CHECK_ARG(1, numeric, op);
 393         int n = ex_to_numeric(e[1]).to_int();
 394         if (n < 0 || n >= (int)e[0].nops())
 395                 throw(std::out_of_range("second argument to op() is out of range"));
 396         return e[0].op(n);
 397 }
 398
 399 static ex f_prem(const exprseq &e)
 400 {
 401         CHECK_ARG(2, symbol, prem);
 402         return prem(e[0], e[1], ex_to_symbol(e[2]));
 403 }
 404
 405 static ex f_primpart(const exprseq &e)
 406 {
 407         CHECK_ARG(1, symbol, primpart);
 408         return e[0].primpart(ex_to_symbol(e[1]));
 409 }
 410
 411 static ex f_quo(const exprseq &e)
 412 {
 413         CHECK_ARG(2, symbol, quo);
 414         return quo(e[0], e[1], ex_to_symbol(e[2]));
 415 }
 416
 417 static ex f_rem(const exprseq &e)
 418 {
 419         CHECK_ARG(2, symbol, rem);
 420         return rem(e[0], e[1], ex_to_symbol(e[2]));
 421 }
 422
 423 static ex f_series2(const exprseq &e)
 424 {
 425         CHECK_ARG(1, symbol, series);
 426         return e[0].series(ex_to_symbol(e[1]), ex(0));
 427 }
 428
 429 static ex f_series3(const exprseq &e)
 430 {
 431         CHECK_ARG(1, symbol, series);
 432         return e[0].series(ex_to_symbol(e[1]), e[2]);
 433 }
 434
 435 static ex f_series4(const exprseq &e)
 436 {
 437         CHECK_ARG(1, symbol, series);
 438         CHECK_ARG(3, numeric, series);
 439         return e[0].series(ex_to_symbol(e[1]), e[2], ex_to_numeric(e[3]).to_int());
 440 }
 441
 442 static ex f_sqrfree(const exprseq &e)
 443 {
 444         CHECK_ARG(1, symbol, sqrfree);
 445         return sqrfree(e[0], ex_to_symbol(e[1]));
 446 }
 447
 448 static ex f_subs3(const exprseq &e)
 449 {
 450         CHECK_ARG(1, lst, subs);
 451         CHECK_ARG(2, lst, subs);
 452         return e[0].subs(ex_to_lst(e[1]), ex_to_lst(e[2]));
 453 }
 454
 455 static ex f_tcoeff(const exprseq &e)
 456 {
 457         CHECK_ARG(1, symbol, tcoeff);
 458         return e[0].tcoeff(ex_to_symbol(e[1]));
 459 }
 460
 461 static ex f_trace(const exprseq &e)
 462 {
 463         CHECK_ARG(0, matrix, trace);
 464         return ex_to_matrix(e[0]).trace();
 465 }
 466
 467 static ex f_transpose(const exprseq &e)
 468 {
 469         CHECK_ARG(0, matrix, transpose);
 470         return ex_to_matrix(e[0]).transpose();
 471 }
 472
 473 static ex f_unassign(const exprseq &e)
 474 {
 475         CHECK_ARG(0, symbol, unassign);
 476         (const_cast<symbol *>(&ex_to_symbol(e[0])))->unassign();
 477         return e[0];
 478 }
 479
 480 static ex f_unit(const exprseq &e)
 481 {
 482         CHECK_ARG(1, symbol, unit);
 483         return e[0].unit(ex_to_symbol(e[1]));
 484 }
 485
 486 static ex f_dummy(const exprseq &e)
 487 {
 488         throw(std::logic_error("dummy function called (shouldn't happen)"));
 489 }
 490
 491 // Table for initializing the "fcns" map
 492 struct fcn_init {
 493         const char *name;
 494         const fcn_desc desc;
 495 };
 496
 497 static const fcn_init builtin_fcns[] = {
 498         {"charpoly", fcn_desc(f_charpoly, 2)},
 499         {"coeff", fcn_desc(f_coeff, 3)},
 500         {"collect", fcn_desc(f_collect, 2)},
 501         {"content", fcn_desc(f_content, 2)},
 502         {"degree", fcn_desc(f_degree, 2)},
 503         {"denom", fcn_desc(f_denom, 1)},
 504         {"determinant", fcn_desc(f_determinant, 1)},
 505         {"diag", fcn_desc(f_diag, 0)},
 506         {"diff", fcn_desc(f_diff2, 2)},
 507         {"diff", fcn_desc(f_diff3, 3)},
 508         {"divide", fcn_desc(f_divide, 2)},
 509         {"eval", fcn_desc(f_eval1, 1)},
 510         {"eval", fcn_desc(f_eval2, 2)},
 511         {"evalf", fcn_desc(f_evalf1, 1)},
 512         {"evalf", fcn_desc(f_evalf2, 2)},
 513         {"expand", fcn_desc(f_expand, 1)},
 514         {"gcd", fcn_desc(f_gcd, 2)},
 515         {"has", fcn_desc(f_has, 2)},
 516         {"inverse", fcn_desc(f_inverse, 1)},
 517         {"is", fcn_desc(f_is, 1)},
 518         {"lcm", fcn_desc(f_lcm, 2)},
 519         {"lcoeff", fcn_desc(f_lcoeff, 2)},
 520         {"ldegree", fcn_desc(f_ldegree, 2)},
 521         {"lsolve", fcn_desc(f_lsolve, 2)},
 522         {"nops", fcn_desc(f_nops, 1)},
 523         {"normal", fcn_desc(f_normal1, 1)},
 524         {"normal", fcn_desc(f_normal2, 2)},
 525         {"numer", fcn_desc(f_numer, 1)},
 526         {"op", fcn_desc(f_op, 2)},
 527         {"pow", fcn_desc(f_pow, 2)},
 528         {"prem", fcn_desc(f_prem, 3)},
 529         {"primpart", fcn_desc(f_primpart, 2)},
 530         {"quo", fcn_desc(f_quo, 3)},
 531         {"rem", fcn_desc(f_rem, 3)},
 532         {"series", fcn_desc(f_series2, 2)},
 533         {"series", fcn_desc(f_series3, 3)},
 534         {"series", fcn_desc(f_series4, 4)},
 535         {"sqrfree", fcn_desc(f_sqrfree, 2)},
 536         {"sqrt", fcn_desc(f_sqrt, 1)},
 537         {"subs", fcn_desc(f_subs2, 2)},
 538         {"subs", fcn_desc(f_subs3, 3)},
 539         {"tcoeff", fcn_desc(f_tcoeff, 2)},
 540         {"time", fcn_desc(f_dummy, 0)},
 541         {"trace", fcn_desc(f_trace, 1)},
 542         {"transpose", fcn_desc(f_transpose, 1)},
 543         {"unassign", fcn_desc(f_unassign, 1)},
 544         {"unit", fcn_desc(f_unit, 2)},
 545         {NULL, fcn_desc(f_dummy, 0)}    // End marker
 546 };
 547
 548
 549 /*
 550  *  Add functions to ginsh
 551  */
 552
 553 // Functions from fcn_init array
 554 static void insert_fcns(const fcn_init *p)
 555 {
 556         while (p->name) {
 557                 fcns.insert(make_pair(string(p->name), p->desc));
 558                 p++;
 559         }
 560 }
 561
 562 static ex f_ginac_function(const exprseq &es, int serial)
 563 {
 564         return function(serial, es).eval(1);
 565 }
 566
 567 // All registered GiNaC functions
 568 #ifndef NO_NAMESPACE_GINAC
 569 void GiNaC::ginsh_get_ginac_functions(void)
 570 #else // ndef NO_NAMESPACE_GINAC
 571 void ginsh_get_ginac_functions(void)
 572 #endif // ndef NO_NAMESPACE_GINAC
 573 {
 574         vector<function_options>::const_iterator i = function::registered_functions().begin(), end = function::registered_functions().end();
 575         unsigned serial = 0;
 576         while (i != end) {
 577                 fcns.insert(make_pair(i->get_name(), fcn_desc(f_ginac_function, i->get_nparams(), serial)));
 578                 i++;
 579                 serial++;
 580         }
 581 }
 582
 583
 584 /*
 585  *  Find a function given a name and number of parameters. Throw exceptions on error.
 586  */
 587
 588 static fcn_tab::const_iterator find_function(const ex &sym, int req_params)
 589 {
 590         const string &name = ex_to_symbol(sym).getname();
 591         typedef fcn_tab::const_iterator I;
 592         pair<I, I> b = fcns.equal_range(name);
 593         if (b.first == b.second)
 594                 throw(std::logic_error("unknown function '" + name + "'"));
 595         else {
 596                 for (I i=b.first; i!=b.second; i++)
 597                         if ((i->second.num_params == 0) || (i->second.num_params == req_params))
 598                                 return i;
 599         }
 600         throw(std::logic_error("invalid number of arguments to " + name + "()"));
 601 }
 602
 603
 604 /*
 605  *  Insert help strings
 606  */
 607
 608 // Normal help string
 609 static void insert_help(const char *topic, const char *str)
 610 {
 611         help.insert(make_pair(string(topic), string(str)));
 612 }
 613
 614 // Help string for functions, automatically generates synopsis
 615 static void insert_fcn_help(const char *name, const char *str)
 616 {
 617         typedef fcn_tab::const_iterator I;
 618         pair<I, I> b = fcns.equal_range(name);
 619         if (b.first != b.second) {
 620                 string help_str = string(name) + "(";
 621                 for (int i=0; i<b.first->second.num_params; i++) {
 622                         if (i)
 623                                 help_str += ", ";
 624                         help_str += "expression";
 625                 }
 626                 help_str += ") - ";
 627                 help_str += str;
 628                 help.insert(make_pair(string(name), help_str));
 629         }
 630 }
 631
 632
 633 /*
 634  *  Print help to cout
 635  */
 636
 637 // Help for a given topic
 638 static void print_help(const string &topic)
 639 {
 640         typedef help_tab::const_iterator I;
 641         pair<I, I> b = help.equal_range(topic);
 642         if (b.first == b.second)
 643                 cout << "no help for '" << topic << "'\n";
 644         else {
 645                 for (I i=b.first; i!=b.second; i++)
 646                         cout << i->second << endl;
 647         }
 648 }
 649
 650 // List of help topics
 651 static void print_help_topics(void)
 652 {
 653         cout << "Available help topics:\n";
 654         help_tab::const_iterator i;
 655         string last_name = string("*");
 656         int num = 0;
 657         for (i=help.begin(); i!=help.end(); i++) {
 658                 // Don't print duplicates
 659                 if (i->first != last_name) {
 660                         if (num)
 661                                 cout << ", ";
 662                         num++;
 663                         cout << i->first;
 664                         last_name = i->first;
 665                 }
 666         }
 667         cout << "\nTo get help for a certain topic, type ?topic\n";
 668 }
 669
 670
 671 /*
 672  *  Convert list of lists to matrix
 673  */
 674
 675 static ex lst2matrix(const ex &l)
 676 {
 677         if (!is_ex_of_type(l, lst))
 678                 throw(std::logic_error("internal error: argument to lst2matrix() is not a list"));
 679
 680         // Find number of rows and columns
 681         unsigned rows = l.nops(), cols = 0, i, j;
 682         for (i=0; i<rows; i++)
 683                 if (l.op(i).nops() > cols)
 684                         cols = l.op(i).nops();
 685
 686         // Allocate and fill matrix
 687         matrix &m = *new matrix(rows, cols);
 688         for (i=0; i<rows; i++)
 689                 for (j=0; j<cols; j++)
 690                         if (l.op(i).nops() > j)
 691                                 m.set(i, j, l.op(i).op(j));
 692                         else
 693                                 m.set(i, j, ex(0));
 694         return m;
 695 }
 696
 697
 698 /*
 699  *  Function name completion functions for readline
 700  */
 701
 702 static char *fcn_generator(char *text, int state)
 703 {
 704         static int len;                         // Length of word to complete
 705         static fcn_tab::const_iterator index;   // Iterator to function being currently considered
 706
 707         // If this is a new word to complete, initialize now
 708         if (state == 0) {
 709                 index = fcns.begin();
 710                 len = strlen(text);
 711         }
 712
 713         // Return the next function which partially matches
 714         while (index != fcns.end()) {
 715                 const char *fcn_name = index->first.c_str();
 716                 index++;
 717                 if (strncmp(fcn_name, text, len) == 0)
 718                         return strdup(fcn_name);
 719         }
 720         return NULL;
 721 }
 722
 723 static char **fcn_completion(char *text, int start, int end)
 724 {
 725         if (rl_line_buffer[0] == '!') {
 726                 // For shell commands, revert back to filename completion
 727                 rl_completion_append_character = orig_completion_append_character;
 728                 rl_basic_word_break_characters = orig_basic_word_break_characters;
 729                 return completion_matches(text, (CPFunction *)filename_completion_function);
 730         } else {
 731                 // Otherwise, complete function names
 732                 rl_completion_append_character = '(';
 733                 rl_basic_word_break_characters = " \t\n\"#$%&'()*+,-./:;<=>?@[\\]^`{|}~";
 734                 return completion_matches(text, (CPFunction *)fcn_generator);
 735         }
 736 }
 737
 738 void greeting(void)
 739 {
 740     cout << "ginsh - GiNaC Interactive Shell (" << PACKAGE << " V" << VERSION << ")" << endl;
 741     cout << "  __,  _______  Copyright (C) 1999-2000 Johannes Gutenberg University Mainz,\n"
 742          << " (__) *       | Germany.  This is free software with ABSOLUTELY NO WARRANTY.\n"
 743          << "  ._) i N a C | You are welcome to redistribute it under certain conditions.\n"
 744          << "<-------------' For details type `warranty;'.\n" << endl;
 745     cout << "Type ?? for a list of help topics." << endl;
 746 }
 747
 748 /*
 749  *  Main program
 750  */
 751 int main(int argc, char **argv)
 752 {
 753         // Print banner in interactive mode
 754         if (isatty(0))
 755                 greeting();
 756
 757         // Init function table
 758         insert_fcns(builtin_fcns);
 759         ginsh_get_ginac_functions();
 760
 761         // Init help for operators (automatically generated from man page)
 762         insert_help("operators", "Operators in falling order of precedence:");
 763 #include "ginsh_op_help.c"
 764
 765         // Init help for built-in functions (automatically generated from man page)
 766 #include "ginsh_fcn_help.c"
 767
 768         // Help for GiNaC functions is added manually
 769         insert_fcn_help("acos", "inverse cosine function");
 770         insert_fcn_help("acosh", "inverse hyperbolic cosine function");
 771         insert_fcn_help("asin", "inverse sine function");
 772         insert_fcn_help("asinh", "inverse hyperbolic sine function");
 773         insert_fcn_help("atan", "inverse tangent function");
 774         insert_fcn_help("atan2", "inverse tangent function with two arguments");
 775         insert_fcn_help("atanh", "inverse hyperbolic tangent function");
 776         insert_fcn_help("Beta", "Beta function");
 777         insert_fcn_help("binomial", "binomial function");
 778         insert_fcn_help("cos", "cosine function");
 779         insert_fcn_help("cosh", "hyperbolic cosine function");
 780         insert_fcn_help("exp", "exponential function");
 781         insert_fcn_help("factorial", "factorial function");
 782         insert_fcn_help("Gamma", "Gamma function");
 783         insert_fcn_help("log", "natural logarithm");
 784         insert_fcn_help("psi", "psi function\npsi(x) is the digamma function, psi(n,x) the nth polygamma function");
 785         insert_fcn_help("sin", "sine function");
 786         insert_fcn_help("sinh", "hyperbolic sine function");
 787         insert_fcn_help("tan", "tangent function");
 788         insert_fcn_help("tanh", "hyperbolic tangent function");
 789         insert_fcn_help("zeta", "zeta function\nzeta(x) is Riemann's zeta function, zeta(n,x) its nth derivative");
 790         insert_fcn_help("Li2", "dilogarithm");
 791         insert_fcn_help("Li3", "trilogarithm");
 792         insert_fcn_help("Order", "order term function (for truncated power series)");
 793
 794         // Init readline completer
 795         rl_readline_name = argv[0];
 796         rl_attempted_completion_function = (CPPFunction *)fcn_completion;
 797         orig_completion_append_character = rl_completion_append_character;
 798         orig_basic_word_break_characters = rl_basic_word_break_characters;
 799
 800         // Init input file list, open first file
 801         num_files = argc - 1;
 802         file_list = argv + 1;
 803         if (num_files) {
 804                 yyin = fopen(*file_list, "r");
 805                 if (yyin == NULL) {
 806                         cerr << "Can't open " << *file_list << endl;
 807                         exit(1);
 808                 }
 809                 num_files--;
 810                 file_list++;
 811         }
 812
 813         // Parse input, catch all remaining exceptions
 814         int result;
 815 again:  try {
 816                 result = yyparse();
 817         } catch (exception &e) {
 818                 cerr << e.what() << endl;
 819                 goto again;
 820         }
 821         return result;
 822 }