ginsh/ginsh_parser.yy

   1 /** @file ginsh_parser.yy
   2  *
   3  *  Input grammar definition for ginsh.
   4  *  This file must be processed with yacc/bison. */
   5
   6 /*
   7  *  GiNaC Copyright (C) 1999-2008 Johannes Gutenberg University Mainz, Germany
   8  *
   9  *  This program is free software; you can redistribute it and/or modify
  10  *  it under the terms of the GNU General Public License as published by
  11  *  the Free Software Foundation; either version 2 of the License, or
  12  *  (at your option) any later version.
  13  *
  14  *  This program is distributed in the hope that it will be useful,
  15  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  *  GNU General Public License for more details.
  18  *
  19  *  You should have received a copy of the GNU General Public License
  20  *  along with this program; if not, write to the Free Software
  21  *  Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA
  22  */
  23
  24
  25 /*
  26  *  Definitions
  27  */
  28
  29 %{
  30 #include "config.h"
  31 #ifdef HAVE_RUSAGE
  32 #include <sys/resource.h>
  33 #else
  34 #include <ctime>
  35 #endif
  36
  37 #if HAVE_UNISTD_H
  38 #include <sys/types.h>
  39 #include <unistd.h>
  40 #endif
  41
  42 #include <stdexcept>
  43
  44 #include "ginsh.h"
  45
  46 #define YYERROR_VERBOSE 1
  47
  48 #ifdef HAVE_LIBREADLINE
  49 // Original readline settings
  50 static int orig_completion_append_character;
  51 static const char *orig_basic_word_break_characters;
  52
  53 #if (RL_VERSION_MAJOR >= 5)
  54 #define GINAC_RL_COMPLETER_CAST(a) const_cast<char *>((a))
  55 #else
  56 #define GINAC_RL_COMPLETER_CAST(a) (a)
  57 #endif
  58 #endif // HAVE_LIBREADLINE
  59
  60 // Expression stack for %, %% and %%%
  61 static void push(const ex &e);
  62 static ex exstack[3];
  63 // Assigned symbols
  64 static exmap assigned_symbol_table;
  65
  66 // Start and end time for the time() function
  67 #ifdef HAVE_RUSAGE
  68 static struct rusage start_time, end_time;
  69 #define START_TIMER getrusage(RUSAGE_SELF, &start_time);
  70 #define STOP_TIMER getrusage(RUSAGE_SELF, &end_time);
  71 #define PRINT_TIME_USED cout << \
  72    (end_time.ru_utime.tv_sec - start_time.ru_utime.tv_sec) + \
  73        (end_time.ru_stime.tv_sec - start_time.ru_stime.tv_sec) + \
  74        double(end_time.ru_utime.tv_usec - start_time.ru_utime.tv_usec) / 1e6 + \
  75        double(end_time.ru_stime.tv_usec - start_time.ru_stime.tv_usec) / 1e6 \
  76                        << 's' << endl;
  77 #else
  78 static std::clock_t start_time, end_time;
  79 #define START_TIMER start_time = std::clock();
  80 #define STOP_TIMER end_time = std::clock();
  81 #define PRINT_TIME_USED \
  82   cout << double(end_time - start_time)/CLOCKS_PER_SEC << 's' << endl;
  83 #endif
  84
  85 // Table of functions (a multimap, because one function may appear with different
  86 // numbers of parameters)
  87 typedef ex (*fcnp)(const exprseq &e);
  88 typedef ex (*fcnp2)(const exprseq &e, int serial);
  89
  90 struct fcn_desc {
  91         fcn_desc() : p(NULL), num_params(0), is_ginac(false), serial(0) {}
  92         fcn_desc(fcnp func, int num) : p(func), num_params(num), is_ginac(false), serial(0) {}
  93         fcn_desc(fcnp2 func, int num, int ser) : p((fcnp)func), num_params(num), is_ginac(true), serial(ser) {}
  94
  95         fcnp p;         // Pointer to function
  96         int num_params; // Number of parameters (0 = arbitrary)
  97         bool is_ginac;  // Flag: function is GiNaC function
  98         int serial;     // GiNaC function serial number (if is_ginac == true)
  99 };
 100
 101 typedef multimap<string, fcn_desc> fcn_tab;
 102 static fcn_tab fcns;
 103
 104 static fcn_tab::const_iterator find_function(const ex &sym, int req_params);
 105
 106 // Table to map help topics to help strings
 107 typedef multimap<string, string> help_tab;
 108 static help_tab help;
 109
 110 static void insert_fcn_help(const char *name, const char *str);
 111 static void print_help(const string &topic);
 112 static void print_help_topics(void);
 113 %}
 114
 115 /* Tokens (T_LITERAL means a literal value returned by the parser, but not
 116    of class numeric or symbol (e.g. a constant or the FAIL object)) */
 117 %token T_NUMBER T_SYMBOL T_LITERAL T_DIGITS T_QUOTE T_QUOTE2 T_QUOTE3
 118 %token T_EQUAL T_NOTEQ T_LESSEQ T_GREATEREQ
 119
 120 %token T_QUIT T_WARRANTY T_PRINT T_IPRINT T_PRINTLATEX T_PRINTCSRC T_TIME
 121 %token T_XYZZY T_INVENTORY T_LOOK T_SCORE T_COMPLEX_SYMBOLS T_REAL_SYMBOLS
 122
 123 /* Operator precedence and associativity */
 124 %right '='
 125 %left T_EQUAL T_NOTEQ
 126 %left '<' '>' T_LESSEQ T_GREATEREQ
 127 %left '+' '-'
 128 %left '*' '/'
 129 %nonassoc NEG
 130 %right '^'
 131 %nonassoc '!'
 132
 133 %start input
 134
 135
 136 /*
 137  *  Grammar rules
 138  */
 139
 140 %%
 141 input   : /* empty */
 142         | input line
 143         ;
 144
 145 line    : ';'
 146         | exp ';' {
 147                 try {
 148                         cout << $1 << endl;
 149                         push($1);
 150                 } catch (exception &e) {
 151                         cerr << e.what() << endl;
 152                         YYERROR;
 153                 }
 154         }
 155         | exp ':' {
 156                 try {
 157                         push($1);
 158                 } catch (exception &e) {
 159                         std::cerr << e.what() << endl;
 160                         YYERROR;
 161                 }
 162         }
 163         | T_PRINT '(' exp ')' ';' {
 164                 try {
 165                         $3.print(print_tree(std::cout));
 166                 } catch (exception &e) {
 167                         std::cerr << e.what() << endl;
 168                         YYERROR;
 169                 }
 170         }
 171         | T_IPRINT '(' exp ')' ';' {
 172                 try {
 173                         ex e = $3;
 174                         if (!e.info(info_flags::integer))
 175                                 throw (std::invalid_argument("argument to iprint() must be an integer"));
 176                         long i = ex_to<numeric>(e).to_long();
 177                         cout << i << endl;
 178                         cout << "#o" << oct << i << endl;
 179                         cout << "#x" << hex << i << dec << endl;
 180                 } catch (exception &e) {
 181                         cerr << e.what() << endl;
 182                         YYERROR;
 183                 }
 184         }
 185         | T_PRINTLATEX '(' exp ')' ';' {
 186                 try {
 187                         $3.print(print_latex(std::cout)); cout << endl;
 188                 } catch (exception &e) {
 189                         std::cerr << e.what() << endl;
 190                         YYERROR;
 191                 }
 192         }
 193         | T_PRINTCSRC '(' exp ')' ';' {
 194                 try {
 195                         $3.print(print_csrc_double(std::cout)); cout << endl;
 196                 } catch (exception &e) {
 197                         std::cerr << e.what() << endl;
 198                         YYERROR;
 199                 }
 200         }
 201         | '?' T_SYMBOL          {print_help(ex_to<symbol>($2).get_name());}
 202         | '?' T_TIME            {print_help("time");}
 203         | '?' T_PRINT           {print_help("print");}
 204         | '?' T_IPRINT          {print_help("iprint");}
 205         | '?' T_PRINTLATEX      {print_help("print_latex");}
 206         | '?' T_PRINTCSRC       {print_help("print_csrc");}
 207         | '?' '?'               {print_help_topics();}
 208         | T_QUIT                {YYACCEPT;}
 209         | T_WARRANTY {
 210                 cout << "This program is free software; you can redistribute it and/or modify it under\n";
 211                 cout << "the terms of the GNU General Public License as published by the Free Software\n";
 212                 cout << "Foundation; either version 2 of the License, or (at your option) any later\n";
 213                 cout << "version.\n";
 214                 cout << "This program is distributed in the hope that it will be useful, but WITHOUT\n";
 215                 cout << "ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS\n";
 216                 cout << "FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more\n";
 217                 cout << "details.\n";
 218                 cout << "You should have received a copy of the GNU General Public License along with\n";
 219                 cout << "this program. If not, write to the Free Software Foundation, 675 Mass Ave,\n";
 220                 cout << "Cambridge, MA 02139, USA.\n";
 221         }
 222         | T_XYZZY               {cout << "Nothing happens.\n";}
 223         | T_INVENTORY           {cout << "You're not carrying anything.\n";}
 224         | T_LOOK                {cout << "You're in a twisty little maze of passages, all alike.\n";}
 225         | T_SCORE {
 226                 cout << "If you were to quit now, you would score ";
 227                 cout << (syms.size() > 350 ? 350 : syms.size());
 228                 cout << " out of a possible 350.\n";
 229         }
 230         | T_REAL_SYMBOLS { symboltype = domain::real; }
 231         | T_COMPLEX_SYMBOLS { symboltype = domain::complex; }
 232         | T_TIME { START_TIMER } '(' exp ')' { STOP_TIMER PRINT_TIME_USED }
 233         | error ';'             {yyclearin; yyerrok;}
 234         | error ':'             {yyclearin; yyerrok;}
 235         ;
 236
 237 exp     : T_NUMBER              {$$ = $1;}
 238         | T_SYMBOL              {
 239                 exmap::const_iterator i = assigned_symbol_table.find($1);
 240                 if (i == assigned_symbol_table.end())
 241                         $$ = $1;
 242                 else
 243                         $$ = i->second.eval();
 244         }
 245         | '\'' T_SYMBOL '\''    {$$ = $2;}
 246         | T_LITERAL             {$$ = $1;}
 247         | T_DIGITS              {$$ = $1;}
 248         | T_QUOTE               {$$ = exstack[0];}
 249         | T_QUOTE2              {$$ = exstack[1];}
 250         | T_QUOTE3              {$$ = exstack[2];}
 251         | T_SYMBOL '(' exprseq ')' {
 252                 fcn_tab::const_iterator i = find_function($1, $3.nops());
 253                 if (i->second.is_ginac) {
 254                         $$ = ((fcnp2)(i->second.p))(ex_to<exprseq>($3), i->second.serial);
 255                 } else {
 256                         $$ = (i->second.p)(ex_to<exprseq>($3));
 257                 }
 258         }
 259         | T_DIGITS '=' T_NUMBER {$$ = $3; Digits = ex_to<numeric>($3).to_int();}
 260         | T_SYMBOL '=' exp      {$$ = $3; assigned_symbol_table[$1] = $3; }
 261         | exp T_EQUAL exp       {$$ = $1 == $3;}
 262         | exp T_NOTEQ exp       {$$ = $1 != $3;}
 263         | exp '<' exp           {$$ = $1 < $3;}
 264         | exp T_LESSEQ exp      {$$ = $1 <= $3;}
 265         | exp '>' exp           {$$ = $1 > $3;}
 266         | exp T_GREATEREQ exp   {$$ = $1 >= $3;}
 267         | exp '+' exp           {$$ = $1 + $3;}
 268         | exp '-' exp           {$$ = $1 - $3;}
 269         | exp '*' exp           {$$ = $1 * $3;}
 270         | exp '/' exp           {$$ = $1 / $3;}
 271         | '-' exp %prec NEG     {$$ = -$2;}
 272         | '+' exp %prec NEG     {$$ = $2;}
 273         | exp '^' exp           {$$ = power($1, $3);}
 274         | exp '!'               {$$ = factorial($1);}
 275         | '(' exp ')'           {$$ = $2;}
 276         | '{' list_or_empty '}' {$$ = $2;}
 277         | '[' matrix ']'        {$$ = lst_to_matrix(ex_to<lst>($2));}
 278         ;
 279
 280 exprseq : exp                   {$$ = exprseq($1);}
 281         | exprseq ',' exp       {exprseq es(ex_to<exprseq>($1)); $$ = es.append($3);}
 282         ;
 283
 284 list_or_empty: /* empty */      {$$ = *new lst;}
 285         | list                  {$$ = $1;}
 286         ;
 287
 288 list    : exp                   {$$ = lst($1);}
 289         | list ',' exp          {lst l(ex_to<lst>($1)); $$ = l.append($3);}
 290         ;
 291
 292 matrix  : '[' row ']'           {$$ = lst($2);}
 293         | matrix ',' '[' row ']' {lst l(ex_to<lst>($1)); $$ = l.append($4);}
 294         ;
 295
 296 row     : exp                   {$$ = lst($1);}
 297         | row ',' exp           {lst l(ex_to<lst>($1)); $$ = l.append($3);}
 298         ;
 299
 300
 301 /*
 302  *  Routines
 303  */
 304
 305 %%
 306 // Error print routine
 307 int yyerror(char *s)
 308 {
 309         cerr << s << " at " << yytext << endl;
 310         return 0;
 311 }
 312
 313 // Push expression "e" onto the expression stack (for ", "" and """)
 314 static void push(const ex &e)
 315 {
 316         exstack[2] = exstack[1];
 317         exstack[1] = exstack[0];
 318         exstack[0] = e;
 319 }
 320
 321
 322 /*
 323  *  Built-in functions
 324  */
 325
 326 static ex f_collect(const exprseq &e) {return e[0].collect(e[1]);}
 327 static ex f_collect_distributed(const exprseq &e) {return e[0].collect(e[1], true);}
 328 static ex f_collect_common_factors(const exprseq &e) {return collect_common_factors(e[0]);}
 329 static ex f_convert_H_to_Li(const exprseq &e) {return convert_H_to_Li(e[0], e[1]);}
 330 static ex f_degree(const exprseq &e) {return e[0].degree(e[1]);}
 331 static ex f_denom(const exprseq &e) {return e[0].denom();}
 332 static ex f_eval1(const exprseq &e) {return e[0].eval();}
 333 static ex f_evalf1(const exprseq &e) {return e[0].evalf();}
 334 static ex f_evalm(const exprseq &e) {return e[0].evalm();}
 335 static ex f_eval_integ(const exprseq &e) {return e[0].eval_integ();}
 336 static ex f_expand(const exprseq &e) {return e[0].expand();}
 337 static ex f_factor(const exprseq &e) {return factor(e[0]);}
 338 static ex f_gcd(const exprseq &e) {return gcd(e[0], e[1]);}
 339 static ex f_has(const exprseq &e) {return e[0].has(e[1]) ? ex(1) : ex(0);}
 340 static ex f_lcm(const exprseq &e) {return lcm(e[0], e[1]);}
 341 static ex f_lcoeff(const exprseq &e) {return e[0].lcoeff(e[1]);}
 342 static ex f_ldegree(const exprseq &e) {return e[0].ldegree(e[1]);}
 343 static ex f_lsolve(const exprseq &e) {return lsolve(e[0], e[1]);}
 344 static ex f_nops(const exprseq &e) {return e[0].nops();}
 345 static ex f_normal1(const exprseq &e) {return e[0].normal();}
 346 static ex f_numer(const exprseq &e) {return e[0].numer();}
 347 static ex f_numer_denom(const exprseq &e) {return e[0].numer_denom();}
 348 static ex f_pow(const exprseq &e) {return pow(e[0], e[1]);}
 349 static ex f_sqrt(const exprseq &e) {return sqrt(e[0]);}
 350 static ex f_sqrfree1(const exprseq &e) {return sqrfree(e[0]);}
 351 static ex f_subs2(const exprseq &e) {return e[0].subs(e[1]);}
 352 static ex f_tcoeff(const exprseq &e) {return e[0].tcoeff(e[1]);}
 353
 354 #define CHECK_ARG(num, type, fcn) if (!is_a<type>(e[num])) throw(std::invalid_argument("argument " #num " to " #fcn "() must be a " #type))
 355
 356 static ex f_charpoly(const exprseq &e)
 357 {
 358         CHECK_ARG(0, matrix, charpoly);
 359         return ex_to<matrix>(e[0]).charpoly(e[1]);
 360 }
 361
 362 static ex f_coeff(const exprseq &e)
 363 {
 364         CHECK_ARG(2, numeric, coeff);
 365         return e[0].coeff(e[1], ex_to<numeric>(e[2]).to_int());
 366 }
 367
 368 static ex f_content(const exprseq &e)
 369 {
 370         return e[0].content(e[1]);
 371 }
 372
 373 static ex f_decomp_rational(const exprseq &e)
 374 {
 375         return decomp_rational(e[0], e[1]);
 376 }
 377
 378 static ex f_determinant(const exprseq &e)
 379 {
 380         CHECK_ARG(0, matrix, determinant);
 381         return ex_to<matrix>(e[0]).determinant();
 382 }
 383
 384 static ex f_diag(const exprseq &e)
 385 {
 386         size_t dim = e.nops();
 387         matrix &m = *new matrix(dim, dim);
 388         for (size_t i=0; i<dim; i++)
 389                 m.set(i, i, e.op(i));
 390         return m;
 391 }
 392
 393 static ex f_diff2(const exprseq &e)
 394 {
 395         CHECK_ARG(1, symbol, diff);
 396         return e[0].diff(ex_to<symbol>(e[1]));
 397 }
 398
 399 static ex f_diff3(const exprseq &e)
 400 {
 401         CHECK_ARG(1, symbol, diff);
 402         CHECK_ARG(2, numeric, diff);
 403         return e[0].diff(ex_to<symbol>(e[1]), ex_to<numeric>(e[2]).to_int());
 404 }
 405
 406 static ex f_divide(const exprseq &e)
 407 {
 408         ex q;
 409         if (divide(e[0], e[1], q))
 410                 return q;
 411         else
 412                 return fail();
 413 }
 414
 415 static ex f_eval2(const exprseq &e)
 416 {
 417         CHECK_ARG(1, numeric, eval);
 418         return e[0].eval(ex_to<numeric>(e[1]).to_int());
 419 }
 420
 421 static ex f_evalf2(const exprseq &e)
 422 {
 423         CHECK_ARG(1, numeric, evalf);
 424         return e[0].evalf(ex_to<numeric>(e[1]).to_int());
 425 }
 426
 427 static ex f_find(const exprseq &e)
 428 {
 429         exset found;
 430         e[0].find(e[1], found);
 431         lst l;
 432         for (exset::const_iterator i = found.begin(); i != found.end(); ++i)
 433                 l.append(*i);
 434         return l;
 435 }
 436
 437 static ex f_fsolve(const exprseq &e)
 438 {
 439         CHECK_ARG(1, symbol, fsolve);
 440         CHECK_ARG(2, numeric, fsolve);
 441         CHECK_ARG(3, numeric, fsolve);
 442         return fsolve(e[0], ex_to<symbol>(e[1]), ex_to<numeric>(e[2]), ex_to<numeric>(e[3]));
 443 }
 444
 445 static ex f_integer_content(const exprseq &e)
 446 {
 447         return e[0].expand().integer_content();
 448 }
 449
 450 static ex f_integral(const exprseq &e)
 451 {
 452         CHECK_ARG(0, symbol, integral);
 453         return integral(e[0], e[1], e[2], e[3]);
 454 }
 455
 456 static ex f_inverse(const exprseq &e)
 457 {
 458         CHECK_ARG(0, matrix, inverse);
 459         return ex_to<matrix>(e[0]).inverse();
 460 }
 461
 462 static ex f_is(const exprseq &e)
 463 {
 464         CHECK_ARG(0, relational, is);
 465         return (bool)ex_to<relational>(e[0]) ? ex(1) : ex(0);
 466 }
 467
 468 class apply_map_function : public map_function {
 469         ex apply;
 470 public:
 471         apply_map_function(const ex & a) : apply(a) {}
 472         virtual ~apply_map_function() {}
 473         ex operator()(const ex & e) { return apply.subs(wild() == e, true); }
 474 };
 475
 476 static ex f_map(const exprseq &e)
 477 {
 478         apply_map_function fcn(e[1]);
 479         return e[0].map(fcn);
 480 }
 481
 482 static ex f_match(const exprseq &e)
 483 {
 484         exmap repls;
 485         if (e[0].match(e[1], repls)) {
 486                 lst repl_lst;
 487                 for (exmap::const_iterator i = repls.begin(); i != repls.end(); ++i)
 488                         repl_lst.append(relational(i->first, i->second, relational::equal));
 489                 return repl_lst;
 490         }
 491         throw std::runtime_error("FAIL");
 492 }
 493
 494 static ex f_normal2(const exprseq &e)
 495 {
 496         CHECK_ARG(1, numeric, normal);
 497         return e[0].normal(ex_to<numeric>(e[1]).to_int());
 498 }
 499
 500 static ex f_op(const exprseq &e)
 501 {
 502         CHECK_ARG(1, numeric, op);
 503         int n = ex_to<numeric>(e[1]).to_int();
 504         if (n < 0 || n >= (int)e[0].nops())
 505                 throw(std::out_of_range("second argument to op() is out of range"));
 506         return e[0].op(n);
 507 }
 508
 509 static ex f_prem(const exprseq &e)
 510 {
 511         return prem(e[0], e[1], e[2]);
 512 }
 513
 514 static ex f_primpart(const exprseq &e)
 515 {
 516         return e[0].primpart(e[1]);
 517 }
 518
 519 static ex f_quo(const exprseq &e)
 520 {
 521         return quo(e[0], e[1], e[2]);
 522 }
 523
 524 static ex f_rank(const exprseq &e)
 525 {
 526         CHECK_ARG(0, matrix, rank);
 527         return ex_to<matrix>(e[0]).rank();
 528 }
 529
 530 static ex f_rem(const exprseq &e)
 531 {
 532         return rem(e[0], e[1], e[2]);
 533 }
 534
 535 static ex f_resultant(const exprseq &e)
 536 {
 537         CHECK_ARG(2, symbol, resultant);
 538         return resultant(e[0], e[1], ex_to<symbol>(e[2]));
 539 }
 540
 541 static ex f_series(const exprseq &e)
 542 {
 543         CHECK_ARG(2, numeric, series);
 544         return e[0].series(e[1], ex_to<numeric>(e[2]).to_int());
 545 }
 546
 547 static ex f_sprem(const exprseq &e)
 548 {
 549         return sprem(e[0], e[1], e[2]);
 550 }
 551
 552 static ex f_sqrfree2(const exprseq &e)
 553 {
 554         CHECK_ARG(1, lst, sqrfree);
 555         return sqrfree(e[0], ex_to<lst>(e[1]));
 556 }
 557
 558 static ex f_subs3(const exprseq &e)
 559 {
 560         CHECK_ARG(1, lst, subs);
 561         CHECK_ARG(2, lst, subs);
 562         return e[0].subs(ex_to<lst>(e[1]), ex_to<lst>(e[2]));
 563 }
 564
 565 static ex f_trace(const exprseq &e)
 566 {
 567         CHECK_ARG(0, matrix, trace);
 568         return ex_to<matrix>(e[0]).trace();
 569 }
 570
 571 static ex f_transpose(const exprseq &e)
 572 {
 573         CHECK_ARG(0, matrix, transpose);
 574         return ex_to<matrix>(e[0]).transpose();
 575 }
 576
 577 static ex f_unassign(const exprseq &e)
 578 {
 579         CHECK_ARG(0, symbol, unassign);
 580         exmap::iterator i = assigned_symbol_table.find(e[0]);
 581         if (i != assigned_symbol_table.end())
 582                 assigned_symbol_table.erase(i);
 583         return e[0];
 584 }
 585
 586 static ex f_unit(const exprseq &e)
 587 {
 588         return e[0].unit(e[1]);
 589 }
 590
 591 static ex f_dummy(const exprseq &e)
 592 {
 593         throw(std::logic_error("dummy function called (shouldn't happen)"));
 594 }
 595
 596 // Tables for initializing the "fcns" map and the function help topics
 597 struct fcn_init {
 598         const char *name;
 599         fcnp p;
 600         int num_params;
 601 };
 602
 603 static const fcn_init builtin_fcns[] = {
 604         {"charpoly", f_charpoly, 2},
 605         {"coeff", f_coeff, 3},
 606         {"collect", f_collect, 2},
 607         {"collect_common_factors", f_collect_common_factors, 1},
 608         {"collect_distributed", f_collect_distributed, 2},
 609         {"content", f_content, 2},
 610         {"convert_H_to_Li", f_convert_H_to_Li, 2},
 611         {"decomp_rational", f_decomp_rational, 2},
 612         {"degree", f_degree, 2},
 613         {"denom", f_denom, 1},
 614         {"determinant", f_determinant, 1},
 615         {"diag", f_diag, 0},
 616         {"diff", f_diff2, 2},
 617         {"diff", f_diff3, 3},
 618         {"divide", f_divide, 2},
 619         {"eval", f_eval1, 1},
 620         {"eval", f_eval2, 2},
 621         {"evalf", f_evalf1, 1},
 622         {"evalf", f_evalf2, 2},
 623         {"evalm", f_evalm, 1},
 624         {"eval_integ", f_eval_integ, 1},
 625         {"expand", f_expand, 1},
 626         {"factor", f_factor, 1},
 627         {"find", f_find, 2},
 628         {"fsolve", f_fsolve, 4},
 629         {"gcd", f_gcd, 2},
 630         {"has", f_has, 2},
 631         {"integer_content", f_integer_content, 1},
 632         {"integral", f_integral, 4},
 633         {"inverse", f_inverse, 1},
 634         {"iprint", f_dummy, 0},      // for Tab-completion
 635         {"is", f_is, 1},
 636         {"lcm", f_lcm, 2},
 637         {"lcoeff", f_lcoeff, 2},
 638         {"ldegree", f_ldegree, 2},
 639         {"lsolve", f_lsolve, 2},
 640         {"map", f_map, 2},
 641         {"match", f_match, 2},
 642         {"nops", f_nops, 1},
 643         {"normal", f_normal1, 1},
 644         {"normal", f_normal2, 2},
 645         {"numer", f_numer, 1},
 646         {"numer_denom", f_numer_denom, 1},
 647         {"op", f_op, 2},
 648         {"pow", f_pow, 2},
 649         {"prem", f_prem, 3},
 650         {"primpart", f_primpart, 2},
 651         {"print", f_dummy, 0},       // for Tab-completion
 652         {"print_csrc", f_dummy, 0},  // for Tab-completion
 653         {"print_latex", f_dummy, 0}, // for Tab-completion
 654         {"quo", f_quo, 3},
 655         {"rank", f_rank, 1},
 656         {"rem", f_rem, 3},
 657         {"resultant", f_resultant, 3},
 658         {"series", f_series, 3},
 659         {"sprem", f_sprem, 3},
 660         {"sqrfree", f_sqrfree1, 1},
 661         {"sqrfree", f_sqrfree2, 2},
 662         {"sqrt", f_sqrt, 1},
 663         {"subs", f_subs2, 2},
 664         {"subs", f_subs3, 3},
 665         {"tcoeff", f_tcoeff, 2},
 666         {"time", f_dummy, 0},        // for Tab-completion
 667         {"trace", f_trace, 1},
 668         {"transpose", f_transpose, 1},
 669         {"unassign", f_unassign, 1},
 670         {"unit", f_unit, 2},
 671         {NULL, f_dummy, 0}           // End marker
 672 };
 673
 674 struct fcn_help_init {
 675         const char *name;
 676         const char *help;
 677 };
 678
 679 static const fcn_help_init builtin_help[] = {
 680         {"acos", "inverse cosine function"},
 681         {"acosh", "inverse hyperbolic cosine function"},
 682         {"asin", "inverse sine function"},
 683         {"asinh", "inverse hyperbolic sine function"},
 684         {"atan", "inverse tangent function"},
 685         {"atan2", "inverse tangent function with two arguments"},
 686         {"atanh", "inverse hyperbolic tangent function"},
 687         {"beta", "Beta function"},
 688         {"binomial", "binomial function"},
 689         {"cos", "cosine function"},
 690         {"cosh", "hyperbolic cosine function"},
 691         {"exp", "exponential function"},
 692         {"factorial", "factorial function"},
 693         {"lgamma", "natural logarithm of Gamma function"},
 694         {"tgamma", "Gamma function"},
 695         {"log", "natural logarithm"},
 696         {"psi", "psi function\npsi(x) is the digamma function, psi(n,x) the nth polygamma function"},
 697         {"sin", "sine function"},
 698         {"sinh", "hyperbolic sine function"},
 699         {"tan", "tangent function"},
 700         {"tanh", "hyperbolic tangent function"},
 701         {"zeta", "zeta function\nzeta(x) is Riemann's zeta function, zetaderiv(n,x) its nth derivative.\nIf x is a GiNaC::lst, it is a multiple zeta value\nzeta(x,s) is an alternating Euler sum"},
 702         {"Li2", "dilogarithm"},
 703         {"Li3", "trilogarithm"},
 704         {"Li", "(multiple) polylogarithm"},
 705         {"S", "Nielsen's generalized polylogarithm"},
 706         {"H", "harmonic polylogarithm"},
 707         {"Order", "order term function (for truncated power series)"},
 708         {"Derivative", "inert differential operator"},
 709         {NULL, NULL}    // End marker
 710 };
 711
 712 #include "ginsh_extensions.h"
 713
 714
 715 /*
 716  *  Add functions to ginsh
 717  */
 718
 719 // Functions from fcn_init array
 720 static void insert_fcns(const fcn_init *p)
 721 {
 722         while (p->name) {
 723                 fcns.insert(make_pair(string(p->name), fcn_desc(p->p, p->num_params)));
 724                 p++;
 725         }
 726 }
 727
 728 static ex f_ginac_function(const exprseq &es, int serial)
 729 {
 730         return function(serial, es).eval(1);
 731 }
 732
 733 // All registered GiNaC functions
 734 namespace GiNaC {
 735 void ginsh_get_ginac_functions(void)
 736 {
 737         vector<function_options>::const_iterator i = function::registered_functions().begin(), end = function::registered_functions().end();
 738         unsigned serial = 0;
 739         while (i != end) {
 740                 fcns.insert(make_pair(i->get_name(), fcn_desc(f_ginac_function, i->get_nparams(), serial)));
 741                 ++i;
 742                 serial++;
 743         }
 744 }
 745 }
 746
 747
 748 /*
 749  *  Find a function given a name and number of parameters. Throw exceptions on error.
 750  */
 751
 752 static fcn_tab::const_iterator find_function(const ex &sym, int req_params)
 753 {
 754         const string &name = ex_to<symbol>(sym).get_name();
 755         typedef fcn_tab::const_iterator I;
 756         pair<I, I> b = fcns.equal_range(name);
 757         if (b.first == b.second)
 758                 throw(std::logic_error("unknown function '" + name + "'"));
 759         else {
 760                 for (I i=b.first; i!=b.second; i++)
 761                         if ((i->second.num_params == 0) || (i->second.num_params == req_params))
 762                                 return i;
 763         }
 764         throw(std::logic_error("invalid number of arguments to " + name + "()"));
 765 }
 766
 767
 768 /*
 769  *  Insert help strings
 770  */
 771
 772 // Normal help string
 773 static void insert_help(const char *topic, const char *str)
 774 {
 775         help.insert(make_pair(string(topic), string(str)));
 776 }
 777
 778 // Help string for functions, automatically generates synopsis
 779 static void insert_fcn_help(const char *name, const char *str)
 780 {
 781         typedef fcn_tab::const_iterator I;
 782         pair<I, I> b = fcns.equal_range(name);
 783         if (b.first != b.second) {
 784                 string help_str = string(name) + "(";
 785                 for (int i=0; i<b.first->second.num_params; i++) {
 786                         if (i)
 787                                 help_str += ", ";
 788                         help_str += "expression";
 789                 }
 790                 help_str += ") - ";
 791                 help_str += str;
 792                 help.insert(make_pair(string(name), help_str));
 793         }
 794 }
 795
 796 // Help strings for functions from fcn_help_init array
 797 static void insert_help(const fcn_help_init *p)
 798 {
 799         while (p->name) {
 800                 insert_fcn_help(p->name, p->help);
 801                 p++;
 802         }
 803 }
 804
 805
 806 /*
 807  *  Print help to cout
 808  */
 809
 810 // Help for a given topic
 811 static void print_help(const string &topic)
 812 {
 813         typedef help_tab::const_iterator I;
 814         pair<I, I> b = help.equal_range(topic);
 815         if (b.first == b.second)
 816                 cout << "no help for '" << topic << "'\n";
 817         else {
 818                 for (I i=b.first; i!=b.second; i++)
 819                         cout << i->second << endl;
 820         }
 821 }
 822
 823 // List of help topics
 824 static void print_help_topics(void)
 825 {
 826         cout << "Available help topics:\n";
 827         help_tab::const_iterator i;
 828         string last_name = string("*");
 829         int num = 0;
 830         for (i=help.begin(); i!=help.end(); i++) {
 831                 // Don't print duplicates
 832                 if (i->first != last_name) {
 833                         if (num)
 834                                 cout << ", ";
 835                         num++;
 836                         cout << i->first;
 837                         last_name = i->first;
 838                 }
 839         }
 840         cout << "\nTo get help for a certain topic, type ?topic\n";
 841 }
 842
 843
 844 /*
 845  *  Function name completion functions for readline
 846  */
 847
 848 static char *fcn_generator(const char *text, int state)
 849 {
 850         static int len;                         // Length of word to complete
 851         static fcn_tab::const_iterator index;   // Iterator to function being currently considered
 852
 853         // If this is a new word to complete, initialize now
 854         if (state == 0) {
 855                 index = fcns.begin();
 856                 len = strlen(text);
 857         }
 858
 859         // Return the next function which partially matches
 860         while (index != fcns.end()) {
 861                 const char *fcn_name = index->first.c_str();
 862                 ++index;
 863                 if (strncmp(fcn_name, text, len) == 0)
 864                         return strdup(fcn_name);
 865         }
 866         return NULL;
 867 }
 868
 869 #ifdef HAVE_LIBREADLINE
 870 static char **fcn_completion(const char *text, int start, int end)
 871 {
 872         if (rl_line_buffer[0] == '!') {
 873                 // For shell commands, revert back to filename completion
 874                 rl_completion_append_character = orig_completion_append_character;
 875                 rl_basic_word_break_characters = orig_basic_word_break_characters;
 876                 rl_completer_word_break_characters = GINAC_RL_COMPLETER_CAST(rl_basic_word_break_characters);
 877                 return rl_completion_matches(text, rl_filename_completion_function);
 878         } else {
 879                 // Otherwise, complete function names
 880                 rl_completion_append_character = '(';
 881                 rl_basic_word_break_characters = " \t\n\"#$%&'()*+,-./:;<=>?@[\\]^`{|}~";
 882                 rl_completer_word_break_characters = GINAC_RL_COMPLETER_CAST(rl_basic_word_break_characters);
 883                 return rl_completion_matches(text, fcn_generator);
 884         }
 885 }
 886 #endif // HAVE_LIBREADLINE
 887
 888 static void ginsh_readline_init(char* name)
 889 {
 890 #ifdef HAVE_LIBREADLINE
 891         // Init readline completer
 892         rl_readline_name = name;
 893         rl_attempted_completion_function = fcn_completion;
 894         orig_completion_append_character = rl_completion_append_character;
 895         orig_basic_word_break_characters = rl_basic_word_break_characters;
 896 #endif // HAVE_LIBREADLINE
 897 }
 898
 899 void greeting(void)
 900 {
 901     cout << "ginsh - GiNaC Interactive Shell (" << PACKAGE << " V" << VERSION << ")" << endl;
 902     cout << "  __,  _______  Copyright (C) 1999-2008 Johannes Gutenberg University Mainz,\n"
 903          << " (__) *       | Germany.  This is free software with ABSOLUTELY NO WARRANTY.\n"
 904          << "  ._) i N a C | You are welcome to redistribute it under certain conditions.\n"
 905          << "<-------------' For details type `warranty;'.\n" << endl;
 906     cout << "Type ?? for a list of help topics." << endl;
 907 }
 908
 909 /*
 910  *  Main program
 911  */
 912
 913 int main(int argc, char **argv)
 914 {
 915         // Print banner in interactive mode
 916         if (isatty(0))
 917                 greeting();
 918         assigned_symbol_table = exmap();
 919
 920         // Init function table
 921         insert_fcns(builtin_fcns);
 922         insert_fcns(extended_fcns);
 923         ginsh_get_ginac_functions();
 924
 925         // Init help for operators (automatically generated from man page)
 926         insert_help("operators", "Operators in falling order of precedence:");
 927 #include "ginsh_op_help.h"
 928
 929         // Init help for built-in functions (automatically generated from man page)
 930 #include "ginsh_fcn_help.h"
 931
 932         // Help for GiNaC functions is added manually
 933         insert_help(builtin_help);
 934         insert_help(extended_help);
 935
 936         // Help for other keywords
 937         insert_help("print", "print(expression) - dumps the internal structure of the given expression (for debugging)");
 938         insert_help("iprint", "iprint(expression) - prints the given integer expression in decimal, octal, and hexadecimal bases");
 939         insert_help("print_latex", "print_latex(expression) - prints a LaTeX representation of the given expression");
 940         insert_help("print_csrc", "print_csrc(expression) - prints a C source code representation of the given expression");
 941
 942         ginsh_readline_init(argv[0]);
 943
 944         // Init input file list, open first file
 945         num_files = argc - 1;
 946         file_list = argv + 1;
 947         if (num_files) {
 948                 yyin = fopen(*file_list, "r");
 949                 if (yyin == NULL) {
 950                         cerr << "Can't open " << *file_list << endl;
 951                         exit(1);
 952                 }
 953                 num_files--;
 954                 file_list++;
 955         }
 956
 957         // Parse input, catch all remaining exceptions
 958         int result;
 959 again:  try {
 960                 result = yyparse();
 961         } catch (exception &e) {
 962                 cerr << e.what() << endl;
 963                 goto again;
 964         }
 965         return result;
 966 }