- expressions can now be read from streams; the input expression can contain
[ginac.git] / ginsh / ginsh_lexer.ll
1 /** @file ginsh_lexer.ll
2  *
3  *  Lexical analyzer definition for ginsh.
4  *  This file must be processed with flex. */
5
6 /*
7  *  GiNaC Copyright (C) 1999-2000 Johannes Gutenberg University Mainz, Germany
8  *
9  *  This program is free software; you can redistribute it and/or modify
10  *  it under the terms of the GNU General Public License as published by
11  *  the Free Software Foundation; either version 2 of the License, or
12  *  (at your option) any later version.
13  *
14  *  This program is distributed in the hope that it will be useful,
15  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
16  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17  *  GNU General Public License for more details.
18  *
19  *  You should have received a copy of the GNU General Public License
20  *  along with this program; if not, write to the Free Software
21  *  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
22  */
23
24
25 /*
26  *  Definitions
27  */
28
29 %{
30 #include "config.h"
31
32 #include "ginsh.h"
33 #include "ginsh_parser.h"
34
35 #define YY_INPUT(buf, result, max_size) (result = ginsh_input(buf, max_size))
36
37 // Table of all used symbols
38 sym_tab syms;
39
40 // lex input function
41 static int ginsh_input(char *buf, int max_size);
42 %}
43
44         /* Abbreviations */
45 D       [0-9]
46 E       [elEL][-+]?{D}+
47 A       [a-zA-Z_]
48 AN      [0-9a-zA-Z_]
49
50
51 /*
52  *  Lexical rules
53  */
54
55 %%
56 [ \t\n]+                /* skip whitespace */
57 \\$                     /* skip line continuations */
58 "#".*                   /* skip comments starting with "#" */
59 ^"!".*                  system(yytext + 1);     /* execute shell command */
60
61                         /* special values */
62 Pi                      yylval = Pi; return T_LITERAL;
63 gamma                   yylval = gamma; return T_LITERAL;
64 Catalan                 yylval = Catalan; return T_LITERAL;
65 FAIL                    yylval = *new fail(); return T_LITERAL;
66 I                       yylval = I; return T_NUMBER;
67 Digits                  yylval = (long)Digits; return T_DIGITS;
68
69                         /* keywords */
70 quit|exit               return T_QUIT;
71 warranty                return T_WARRANTY;
72 print                   return T_PRINT;
73 read                    return T_READ;
74 write                   return T_WRITE;
75 time                    return T_TIME;
76 xyzzy                   return T_XYZZY;
77 inventory               return T_INVENTORY;
78 look                    return T_LOOK;
79 score                   return T_SCORE;
80
81                         /* comparison */
82 "=="                    return T_EQUAL;
83 "!="                    return T_NOTEQ;
84 "<="                    return T_LESSEQ;
85 ">="                    return T_GREATEREQ;
86
87                         /* last 1..3 expressions */
88 \"                      return T_QUOTE;
89 \"\"                    return T_QUOTE2;
90 \"\"\"                  return T_QUOTE3;
91
92                         /* matrix delimiters */
93 \[\[                    return T_MATRIX_BEGIN;
94 \]\]                    return T_MATRIX_END;
95
96                         /* numbers */
97 {D}+                    |
98 {D}+"."{D}*({E})?       |
99 {D}*"."{D}+({E})?       |
100 {D}+{E}                 yylval = numeric(yytext); return T_NUMBER;
101
102                         /* symbols */
103 {A}{AN}*                {
104                                 if (syms.find(yytext) == syms.end())
105                                         syms[yytext] = *(new symbol(yytext));
106                                 yylval = syms[yytext];
107                                 return T_SYMBOL;
108                         }
109
110                         /* everything else */
111 .                       return *yytext;
112
113 %%
114
115
116 /*
117  *  Routines
118  */
119
120 static int line_length = 0;
121 static char *line_read = NULL;
122 static char *line_ptr;
123
124 // Input function that uses libreadline for interactive input
125 static int ginsh_input(char *buf, int max_size)
126 {
127         int result;
128         if (yy_current_buffer->yy_is_interactive) {
129 #ifdef HAVE_LIBREADLINE
130                 // Do we need to read a new line?
131                 int actual;
132                 if (line_length == 0) {
133
134                         // Free old line
135                         if (line_read)
136                                 free(line_read);
137
138                         // Read new line, prompt "> "
139                         line_read = line_ptr = readline("> ");
140
141                         // EOF?
142                         if (!line_read) {
143                                 line_length = 0;
144                                 return YY_NULL;
145                         }
146
147                         // Add non-empty lines to history
148                         line_length = strlen(line_read) + 1;
149                         if (line_length > 1)
150                                 add_history(line_read);
151
152                         // Reappend trailing '\n' which is stripped by readline()
153                         line_read[line_length - 1] = '\n';
154                 }
155
156                 // Copy data to lex buffer
157                 actual = line_length > max_size ? max_size : line_length;
158                 memcpy(buf, line_ptr, actual);
159                 line_length -= actual;
160                 line_ptr += actual;
161                 result = actual;
162 #else
163                 printf("> "); fflush(stdout);
164                 int c = '*', n;
165                 for (n = 0; n < max_size && (c = getc(yyin)) != EOF && c != '\n'; ++n)
166                         buf[n] = (char)c;
167                 if (c == '\n')
168                         buf[n++] = (char)c;
169                 if (c == EOF && ferror(yyin))
170                         YY_FATAL_ERROR("input in flex scanner failed");
171                 result = n;
172 #endif
173         } else if (((result = fread(buf, 1, max_size, yyin)) == 0) && ferror(yyin))
174                 YY_FATAL_ERROR("input in flex scanner failed");
175
176         return result;
177 }
178
179 // List of input files to be processed
180 int num_files = 0;
181 char **file_list = NULL;
182
183 // EOF encountered, connect to next file. If this was the last file,
184 // connect to stdin. If this was stdin, terminate the scanner.
185 int yywrap()
186 {
187         if (yyin == stdin)
188                 return 1;
189
190         fclose(yyin);
191         if (num_files) {
192                 yyin = fopen(*file_list, "r");
193                 if (yyin == NULL) {
194                         cerr << "Can't open " << *file_list << endl;
195                         return 1;
196                 }
197                 num_files--;
198                 file_list++;
199         } else
200                 yyin = stdin;
201         return 0;
202 }