Fixed some minor spelling errors.
[ginac.git] / ginsh / ginsh_lexer.ll
1 /** @file ginsh_lexer.ll
2  *
3  *  Lexical analyzer definition for ginsh.
4  *  This file must be processed with flex. */
5
6 /*
7  *  GiNaC Copyright (C) 1999-2008 Johannes Gutenberg University Mainz, Germany
8  *
9  *  This program is free software; you can redistribute it and/or modify
10  *  it under the terms of the GNU General Public License as published by
11  *  the Free Software Foundation; either version 2 of the License, or
12  *  (at your option) any later version.
13  *
14  *  This program is distributed in the hope that it will be useful,
15  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
16  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17  *  GNU General Public License for more details.
18  *
19  *  You should have received a copy of the GNU General Public License
20  *  along with this program; if not, write to the Free Software
21  *  Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA
22  */
23
24
25 /*
26  *  Definitions
27  */
28
29 %pointer
30
31 %{
32 #include "config.h"
33
34 #include "ginsh.h"
35 #include "ginsh_parser.h"
36
37 #define YY_INPUT(buf, result, max_size) (result = ginsh_input(buf, max_size))
38
39 // Table of all used symbols
40 sym_tab syms;
41
42 // Type of symbols to generate (real or complex)
43 unsigned symboltype = domain::complex;
44
45 // lex input function
46 static int ginsh_input(char *buf, int max_size);
47 %}
48
49         /* Abbreviations */
50 D       [0-9]
51 E       [elEL][-+]?{D}+
52 A       [a-zA-Z_]
53 AN      [0-9a-zA-Z_]
54
55
56 /*
57  *  Lexical rules
58  */
59
60 %%
61 [ \t\n]+                /* skip whitespace */
62 \\$                     /* skip line continuations */
63 "//".*                  /* skip comments starting with "//" */
64 ^"#".*                  /* skip lines starting with "#" */
65 ^"!".*                  system(yytext + 1);     /* execute shell command */
66
67                         /* special values */
68 Pi                      yylval = Pi; return T_LITERAL;
69 Euler                   yylval = Euler; return T_LITERAL;
70 Catalan                 yylval = Catalan; return T_LITERAL;
71 FAIL                    yylval = *new fail(); return T_LITERAL;
72 I                       yylval = I; return T_NUMBER;
73 Digits                  yylval = (long)Digits; return T_DIGITS;
74
75                         /* keywords */
76 quit|exit               return T_QUIT;
77 warranty                return T_WARRANTY;
78 print                   return T_PRINT;
79 iprint                  return T_IPRINT;
80 print_latex             return T_PRINTLATEX;
81 print_csrc              return T_PRINTCSRC;
82 time                    return T_TIME;
83 xyzzy                   return T_XYZZY;
84 inventory               return T_INVENTORY;
85 look                    return T_LOOK;
86 score                   return T_SCORE;
87 complex_symbols return T_COMPLEX_SYMBOLS;
88 real_symbols    return T_REAL_SYMBOLS;
89
90                         /* comparison */
91 "=="                    return T_EQUAL;
92 "!="                    return T_NOTEQ;
93 "<="                    return T_LESSEQ;
94 ">="                    return T_GREATEREQ;
95
96                         /* last 1..3 expressions */
97 \%                      return T_QUOTE;
98 \%\%                    return T_QUOTE2;
99 \%\%\%                  return T_QUOTE3;
100
101                         /* numbers */
102 {D}+                    |
103 "#"{D}+"R"{AN}+         |
104 "#b"([01])+             |
105 "#o"[0-7]+              |
106 "#x"[0-9a-fA-F]+        |
107 {D}+"."{D}*({E})?       |
108 {D}*"."{D}+({E})?       |
109 {D}+{E}                 yylval = numeric(yytext); return T_NUMBER;
110
111                         /* symbols */
112 {A}{AN}*                {
113                                 sym_tab::const_iterator i = syms.find(yytext);
114                                 if (i == syms.end()) {
115                                         if (symboltype == domain::complex) {
116                                                 symbol tmp(yytext);
117                                                 syms[yytext] = tmp;
118                                                 yylval = tmp;
119                                         } else {
120                                                 realsymbol tmp(yytext);
121                                                 syms[yytext] = tmp;
122                                                 yylval = tmp;
123                                         }
124                                 } else
125                                         yylval = i->second;
126                                 return T_SYMBOL;
127                         }
128
129                         /* wildcards */
130 \${D}+                  yylval = wild(atoi(yytext + 1)); return T_LITERAL;
131
132                         /* everything else */
133 .                       return *yytext;
134
135 %%
136
137
138 /*
139  *  Routines
140  */
141
142 static int line_length = 0;
143 static char *line_read = NULL;
144 static char *line_ptr;
145
146 // Input function that uses libreadline for interactive input
147 static int ginsh_input(char *buf, int max_size)
148 {
149         int result;
150 #if defined(YY_CURRENT_BUFFER)
151         if (YY_CURRENT_BUFFER->yy_is_interactive) {
152 #else
153         if (yy_current_buffer->yy_is_interactive) {
154 #endif
155 #ifdef HAVE_LIBREADLINE
156                 // Do we need to read a new line?
157                 int actual;
158                 if (line_length == 0) {
159
160                         // Free old line
161                         if (line_read)
162                                 free(line_read);
163
164                         // Read new line, prompt "> "
165                         line_read = line_ptr = readline("> ");
166
167                         // EOF?
168                         if (!line_read) {
169                                 line_length = 0;
170                                 return YY_NULL;
171                         }
172
173                         // Add non-empty lines to history
174                         line_length = strlen(line_read) + 1;
175                         if (line_length > 1)
176                                 add_history(line_read);
177
178                         // Reappend trailing '\n' which is stripped by readline()
179                         line_read[line_length - 1] = '\n';
180                 }
181
182                 // Copy data to lex buffer
183                 actual = line_length > max_size ? max_size : line_length;
184                 memcpy(buf, line_ptr, actual);
185                 line_length -= actual;
186                 line_ptr += actual;
187                 result = actual;
188 #else
189                 printf("> "); fflush(stdout);
190                 int c = '*', n;
191                 for (n = 0; n < max_size && (c = getc(yyin)) != EOF && c != '\n'; ++n)
192                         buf[n] = (char)c;
193                 if (c == '\n')
194                         buf[n++] = (char)c;
195                 if (c == EOF && ferror(yyin))
196                         YY_FATAL_ERROR("input in flex scanner failed");
197                 result = n;
198 #endif
199         } else if (((result = fread(buf, 1, max_size, yyin)) == 0) && ferror(yyin))
200                 YY_FATAL_ERROR("input in flex scanner failed");
201
202         return result;
203 }
204
205 // List of input files to be processed
206 int num_files = 0;
207 char **file_list = NULL;
208
209 // EOF encountered, connect to next file. If this was the last file,
210 // connect to stdin. If this was stdin, terminate the scanner.
211 int yywrap()
212 {
213         if (yyin == stdin)
214                 return 1;
215
216         fclose(yyin);
217         if (num_files) {
218                 yyin = fopen(*file_list, "r");
219                 if (yyin == NULL) {
220                         cerr << "Can't open " << *file_list << endl;
221                         return 1;
222                 }
223                 num_files--;
224                 file_list++;
225         } else
226                 yyin = stdin;
227         return 0;
228 }