ginsh/ginsh_lexer.ll

   1 /** @file ginsh_lexer.ll
   2  *
   3  *  Lexical analyzer definition for ginsh.
   4  *  This file must be processed with flex. */
   5
   6 /*
   7  *  GiNaC Copyright (C) 1999-2003 Johannes Gutenberg University Mainz, Germany
   8  *
   9  *  This program is free software; you can redistribute it and/or modify
  10  *  it under the terms of the GNU General Public License as published by
  11  *  the Free Software Foundation; either version 2 of the License, or
  12  *  (at your option) any later version.
  13  *
  14  *  This program is distributed in the hope that it will be useful,
  15  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  *  GNU General Public License for more details.
  18  *
  19  *  You should have received a copy of the GNU General Public License
  20  *  along with this program; if not, write to the Free Software
  21  *  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  22  */
  23
  24
  25 /*
  26  *  Definitions
  27  */
  28
  29 %{
  30 #include "config.h"
  31
  32 #include "ginsh.h"
  33 #include "ginsh_parser.h"
  34
  35 #define YY_INPUT(buf, result, max_size) (result = ginsh_input(buf, max_size))
  36
  37 // Table of all used symbols
  38 sym_tab syms;
  39
  40 // lex input function
  41 static int ginsh_input(char *buf, int max_size);
  42 %}
  43
  44         /* Abbreviations */
  45 D       [0-9]
  46 E       [elEL][-+]?{D}+
  47 A       [a-zA-Z_]
  48 AN      [0-9a-zA-Z_]
  49
  50
  51 /*
  52  *  Lexical rules
  53  */
  54
  55 %%
  56 [ \t\n]+                /* skip whitespace */
  57 \\$                     /* skip line continuations */
  58 "//".*                  /* skip comments starting with "//" */
  59 ^"#".*                  /* skip lines starting with "#" */
  60 ^"!".*                  system(yytext + 1);     /* execute shell command */
  61
  62                         /* special values */
  63 Pi                      yylval = Pi; return T_LITERAL;
  64 Euler                   yylval = Euler; return T_LITERAL;
  65 Catalan                 yylval = Catalan; return T_LITERAL;
  66 FAIL                    yylval = *new fail(); return T_LITERAL;
  67 I                       yylval = I; return T_NUMBER;
  68 Digits                  yylval = (long)Digits; return T_DIGITS;
  69
  70                         /* keywords */
  71 quit|exit               return T_QUIT;
  72 warranty                return T_WARRANTY;
  73 print                   return T_PRINT;
  74 iprint                  return T_IPRINT;
  75 print_latex             return T_PRINTLATEX;
  76 print_csrc              return T_PRINTCSRC;
  77 time                    return T_TIME;
  78 xyzzy                   return T_XYZZY;
  79 inventory               return T_INVENTORY;
  80 look                    return T_LOOK;
  81 score                   return T_SCORE;
  82
  83                         /* comparison */
  84 "=="                    return T_EQUAL;
  85 "!="                    return T_NOTEQ;
  86 "<="                    return T_LESSEQ;
  87 ">="                    return T_GREATEREQ;
  88
  89                         /* last 1..3 expressions */
  90 \%                      return T_QUOTE;
  91 \%\%                    return T_QUOTE2;
  92 \%\%\%                  return T_QUOTE3;
  93
  94                         /* numbers */
  95 {D}+                    |
  96 "#"{D}+"R"{AN}+         |
  97 "#b"([01])+             |
  98 "#o"[0-7]+              |
  99 "#x"[0-9a-fA-F]+        |
 100 {D}+"."{D}*({E})?       |
 101 {D}*"."{D}+({E})?       |
 102 {D}+{E}                 yylval = numeric(yytext); return T_NUMBER;
 103
 104                         /* symbols */
 105 {A}{AN}*                {
 106                                 sym_tab::const_iterator i = syms.find(yytext);
 107                                 if (i == syms.end()) {
 108                                         yylval = syms[yytext] = *(new symbol(yytext));
 109                                 } else
 110                                         yylval = i->second;
 111                                 return T_SYMBOL;
 112                         }
 113
 114                         /* wildcards */
 115 \${D}+                  yylval = wild(atoi(yytext + 1)); return T_LITERAL;
 116
 117                         /* everything else */
 118 .                       return *yytext;
 119
 120 %%
 121
 122
 123 /*
 124  *  Routines
 125  */
 126
 127 static int line_length = 0;
 128 static char *line_read = NULL;
 129 static char *line_ptr;
 130
 131 // Input function that uses libreadline for interactive input
 132 static int ginsh_input(char *buf, int max_size)
 133 {
 134         int result;
 135         if (yy_current_buffer->yy_is_interactive) {
 136 #ifdef HAVE_LIBREADLINE
 137                 // Do we need to read a new line?
 138                 int actual;
 139                 if (line_length == 0) {
 140
 141                         // Free old line
 142                         if (line_read)
 143                                 free(line_read);
 144
 145                         // Read new line, prompt "> "
 146                         line_read = line_ptr = readline("> ");
 147
 148                         // EOF?
 149                         if (!line_read) {
 150                                 line_length = 0;
 151                                 return YY_NULL;
 152                         }
 153
 154                         // Add non-empty lines to history
 155                         line_length = strlen(line_read) + 1;
 156                         if (line_length > 1)
 157                                 add_history(line_read);
 158
 159                         // Reappend trailing '\n' which is stripped by readline()
 160                         line_read[line_length - 1] = '\n';
 161                 }
 162
 163                 // Copy data to lex buffer
 164                 actual = line_length > max_size ? max_size : line_length;
 165                 memcpy(buf, line_ptr, actual);
 166                 line_length -= actual;
 167                 line_ptr += actual;
 168                 result = actual;
 169 #else
 170                 printf("> "); fflush(stdout);
 171                 int c = '*', n;
 172                 for (n = 0; n < max_size && (c = getc(yyin)) != EOF && c != '\n'; ++n)
 173                         buf[n] = (char)c;
 174                 if (c == '\n')
 175                         buf[n++] = (char)c;
 176                 if (c == EOF && ferror(yyin))
 177                         YY_FATAL_ERROR("input in flex scanner failed");
 178                 result = n;
 179 #endif
 180         } else if (((result = fread(buf, 1, max_size, yyin)) == 0) && ferror(yyin))
 181                 YY_FATAL_ERROR("input in flex scanner failed");
 182
 183         return result;
 184 }
 185
 186 // List of input files to be processed
 187 int num_files = 0;
 188 char **file_list = NULL;
 189
 190 // EOF encountered, connect to next file. If this was the last file,
 191 // connect to stdin. If this was stdin, terminate the scanner.
 192 int yywrap()
 193 {
 194         if (yyin == stdin)
 195                 return 1;
 196
 197         fclose(yyin);
 198         if (num_files) {
 199                 yyin = fopen(*file_list, "r");
 200                 if (yyin == NULL) {
 201                         cerr << "Can't open " << *file_list << endl;
 202                         return 1;
 203                 }
 204                 num_files--;
 205                 file_list++;
 206         } else
 207                 yyin = stdin;
 208         return 0;
 209 }