prepared for 1.0.13 release
[ginac.git] / ginsh / ginsh_lexer.ll
1 /** @file ginsh_lexer.ll
2  *
3  *  Lexical analyzer definition for ginsh.
4  *  This file must be processed with flex. */
5
6 /*
7  *  GiNaC Copyright (C) 1999-2003 Johannes Gutenberg University Mainz, Germany
8  *
9  *  This program is free software; you can redistribute it and/or modify
10  *  it under the terms of the GNU General Public License as published by
11  *  the Free Software Foundation; either version 2 of the License, or
12  *  (at your option) any later version.
13  *
14  *  This program is distributed in the hope that it will be useful,
15  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
16  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17  *  GNU General Public License for more details.
18  *
19  *  You should have received a copy of the GNU General Public License
20  *  along with this program; if not, write to the Free Software
21  *  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
22  */
23
24
25 /*
26  *  Definitions
27  */
28
29 %{
30 #include "config.h"
31
32 #include "ginsh.h"
33 #include "ginsh_parser.h"
34
35 #define YY_INPUT(buf, result, max_size) (result = ginsh_input(buf, max_size))
36
37 // Table of all used symbols
38 sym_tab syms;
39
40 // lex input function
41 static int ginsh_input(char *buf, int max_size);
42 %}
43
44         /* Abbreviations */
45 D       [0-9]
46 E       [elEL][-+]?{D}+
47 A       [a-zA-Z_]
48 AN      [0-9a-zA-Z_]
49
50
51 /*
52  *  Lexical rules
53  */
54
55 %%
56 [ \t\n]+                /* skip whitespace */
57 \\$                     /* skip line continuations */
58 "//".*                  /* skip comments starting with "//" */
59 ^"#".*                  /* skip lines starting with "#" */
60 ^"!".*                  system(yytext + 1);     /* execute shell command */
61
62                         /* special values */
63 Pi                      yylval = Pi; return T_LITERAL;
64 Euler                   yylval = Euler; return T_LITERAL;
65 Catalan                 yylval = Catalan; return T_LITERAL;
66 FAIL                    yylval = *new fail(); return T_LITERAL;
67 I                       yylval = I; return T_NUMBER;
68 Digits                  yylval = (long)Digits; return T_DIGITS;
69
70                         /* keywords */
71 quit|exit               return T_QUIT;
72 warranty                return T_WARRANTY;
73 print                   return T_PRINT;
74 iprint                  return T_IPRINT;
75 print_latex             return T_PRINTLATEX;
76 print_csrc              return T_PRINTCSRC;
77 time                    return T_TIME;
78 xyzzy                   return T_XYZZY;
79 inventory               return T_INVENTORY;
80 look                    return T_LOOK;
81 score                   return T_SCORE;
82
83                         /* comparison */
84 "=="                    return T_EQUAL;
85 "!="                    return T_NOTEQ;
86 "<="                    return T_LESSEQ;
87 ">="                    return T_GREATEREQ;
88
89                         /* last 1..3 expressions */
90 \"                      return T_QUOTE;
91 \"\"                    return T_QUOTE2;
92 \"\"\"                  return T_QUOTE3;
93 \%                      return T_QUOTE;
94 \%\%                    return T_QUOTE2;
95 \%\%\%                  return T_QUOTE3;
96
97                         /* numbers */
98 {D}+                    |
99 "#"{D}+"R"{AN}+         |
100 "#b"([01])+             |
101 "#o"[0-7]+              |
102 "#x"[0-9a-fA-F]+        |
103 {D}+"."{D}*({E})?       |
104 {D}*"."{D}+({E})?       |
105 {D}+{E}                 yylval = numeric(yytext); return T_NUMBER;
106
107                         /* symbols */
108 {A}{AN}*                {
109                                 sym_tab::const_iterator i = syms.find(yytext);
110                                 if (i == syms.end()) {
111                                         yylval = syms[yytext] = *(new symbol(yytext));
112                                 } else
113                                         yylval = i->second;
114                                 return T_SYMBOL;
115                         }
116
117                         /* wildcards */
118 \${D}+                  yylval = wild(atoi(yytext + 1)); return T_LITERAL;
119
120                         /* everything else */
121 .                       return *yytext;
122
123 %%
124
125
126 /*
127  *  Routines
128  */
129
130 static int line_length = 0;
131 static char *line_read = NULL;
132 static char *line_ptr;
133
134 // Input function that uses libreadline for interactive input
135 static int ginsh_input(char *buf, int max_size)
136 {
137         int result;
138         if (yy_current_buffer->yy_is_interactive) {
139 #ifdef HAVE_LIBREADLINE
140                 // Do we need to read a new line?
141                 int actual;
142                 if (line_length == 0) {
143
144                         // Free old line
145                         if (line_read)
146                                 free(line_read);
147
148                         // Read new line, prompt "> "
149                         line_read = line_ptr = readline("> ");
150
151                         // EOF?
152                         if (!line_read) {
153                                 line_length = 0;
154                                 return YY_NULL;
155                         }
156
157                         // Add non-empty lines to history
158                         line_length = strlen(line_read) + 1;
159                         if (line_length > 1)
160                                 add_history(line_read);
161
162                         // Reappend trailing '\n' which is stripped by readline()
163                         line_read[line_length - 1] = '\n';
164                 }
165
166                 // Copy data to lex buffer
167                 actual = line_length > max_size ? max_size : line_length;
168                 memcpy(buf, line_ptr, actual);
169                 line_length -= actual;
170                 line_ptr += actual;
171                 result = actual;
172 #else
173                 printf("> "); fflush(stdout);
174                 int c = '*', n;
175                 for (n = 0; n < max_size && (c = getc(yyin)) != EOF && c != '\n'; ++n)
176                         buf[n] = (char)c;
177                 if (c == '\n')
178                         buf[n++] = (char)c;
179                 if (c == EOF && ferror(yyin))
180                         YY_FATAL_ERROR("input in flex scanner failed");
181                 result = n;
182 #endif
183         } else if (((result = fread(buf, 1, max_size, yyin)) == 0) && ferror(yyin))
184                 YY_FATAL_ERROR("input in flex scanner failed");
185
186         return result;
187 }
188
189 // List of input files to be processed
190 int num_files = 0;
191 char **file_list = NULL;
192
193 // EOF encountered, connect to next file. If this was the last file,
194 // connect to stdin. If this was stdin, terminate the scanner.
195 int yywrap()
196 {
197         if (yyin == stdin)
198                 return 1;
199
200         fclose(yyin);
201         if (num_files) {
202                 yyin = fopen(*file_list, "r");
203                 if (yyin == NULL) {
204                         cerr << "Can't open " << *file_list << endl;
205                         return 1;
206                 }
207                 num_files--;
208                 file_list++;
209         } else
210                 yyin = stdin;
211         return 0;
212 }