ginsh/ginsh_lexer.ll

   1 /** @file ginsh_lexer.ll
   2  *
   3  *  Lexical analyzer definition for ginsh.
   4  *  This file must be processed with flex. */
   5
   6 /*
   7  *  GiNaC Copyright (C) 1999-2001 Johannes Gutenberg University Mainz, Germany
   8  *
   9  *  This program is free software; you can redistribute it and/or modify
  10  *  it under the terms of the GNU General Public License as published by
  11  *  the Free Software Foundation; either version 2 of the License, or
  12  *  (at your option) any later version.
  13  *
  14  *  This program is distributed in the hope that it will be useful,
  15  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  *  GNU General Public License for more details.
  18  *
  19  *  You should have received a copy of the GNU General Public License
  20  *  along with this program; if not, write to the Free Software
  21  *  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  22  */
  23
  24
  25 /*
  26  *  Definitions
  27  */
  28
  29 %{
  30 #include "config.h"
  31
  32 #include "ginsh.h"
  33 #include "ginsh_parser.h"
  34
  35 #define YY_INPUT(buf, result, max_size) (result = ginsh_input(buf, max_size))
  36
  37 // Table of all used symbols
  38 sym_tab syms;
  39
  40 // lex input function
  41 static int ginsh_input(char *buf, int max_size);
  42 %}
  43
  44         /* Abbreviations */
  45 D       [0-9]
  46 E       [elEL][-+]?{D}+
  47 A       [a-zA-Z_]
  48 AN      [0-9a-zA-Z_]
  49
  50
  51 /*
  52  *  Lexical rules
  53  */
  54
  55 %%
  56 [ \t\n]+                /* skip whitespace */
  57 \\$                     /* skip line continuations */
  58 "//".*                  /* skip comments starting with "//" */
  59 ^"#".*                  /* skip lines starting with "#" */
  60 ^"!".*                  system(yytext + 1);     /* execute shell command */
  61
  62                         /* special values */
  63 Pi                      yylval = Pi; return T_LITERAL;
  64 Euler                   yylval = Euler; return T_LITERAL;
  65 Catalan                 yylval = Catalan; return T_LITERAL;
  66 FAIL                    yylval = *new fail(); return T_LITERAL;
  67 I                       yylval = I; return T_NUMBER;
  68 Digits                  yylval = (long)Digits; return T_DIGITS;
  69
  70                         /* keywords */
  71 quit|exit               return T_QUIT;
  72 warranty                return T_WARRANTY;
  73 print                   return T_PRINT;
  74 iprint                  return T_IPRINT;
  75 time                    return T_TIME;
  76 xyzzy                   return T_XYZZY;
  77 inventory               return T_INVENTORY;
  78 look                    return T_LOOK;
  79 score                   return T_SCORE;
  80
  81                         /* comparison */
  82 "=="                    return T_EQUAL;
  83 "!="                    return T_NOTEQ;
  84 "<="                    return T_LESSEQ;
  85 ">="                    return T_GREATEREQ;
  86
  87                         /* last 1..3 expressions */
  88 \"                      return T_QUOTE;
  89 \"\"                    return T_QUOTE2;
  90 \"\"\"                  return T_QUOTE3;
  91
  92                         /* matrix delimiters */
  93 \[\[                    return T_MATRIX_BEGIN;
  94 \]\]                    return T_MATRIX_END;
  95
  96                         /* numbers */
  97 {D}+                    |
  98 "#"{D}+"R"{AN}+         |
  99 "#b"([01])+             |
 100 "#o"[0-7]+              |
 101 "#x"[0-9a-fA-F]+        |
 102 {D}+"."{D}*({E})?       |
 103 {D}*"."{D}+({E})?       |
 104 {D}+{E}                 yylval = numeric(yytext); return T_NUMBER;
 105
 106                         /* symbols */
 107 {A}{AN}*                {
 108                                 sym_tab::const_iterator i = syms.find(yytext);
 109                                 if (i == syms.end()) {
 110                                         yylval = syms[yytext] = *(new symbol(yytext));
 111                                 } else
 112                                         yylval = i->second;
 113                                 return T_SYMBOL;
 114                         }
 115
 116                         /* everything else */
 117 .                       return *yytext;
 118
 119 %%
 120
 121
 122 /*
 123  *  Routines
 124  */
 125
 126 static int line_length = 0;
 127 static char *line_read = NULL;
 128 static char *line_ptr;
 129
 130 // Input function that uses libreadline for interactive input
 131 static int ginsh_input(char *buf, int max_size)
 132 {
 133         int result;
 134         if (yy_current_buffer->yy_is_interactive) {
 135 #ifdef HAVE_LIBREADLINE
 136                 // Do we need to read a new line?
 137                 int actual;
 138                 if (line_length == 0) {
 139
 140                         // Free old line
 141                         if (line_read)
 142                                 free(line_read);
 143
 144                         // Read new line, prompt "> "
 145                         line_read = line_ptr = readline("> ");
 146
 147                         // EOF?
 148                         if (!line_read) {
 149                                 line_length = 0;
 150                                 return YY_NULL;
 151                         }
 152
 153                         // Add non-empty lines to history
 154                         line_length = strlen(line_read) + 1;
 155                         if (line_length > 1)
 156                                 add_history(line_read);
 157
 158                         // Reappend trailing '\n' which is stripped by readline()
 159                         line_read[line_length - 1] = '\n';
 160                 }
 161
 162                 // Copy data to lex buffer
 163                 actual = line_length > max_size ? max_size : line_length;
 164                 memcpy(buf, line_ptr, actual);
 165                 line_length -= actual;
 166                 line_ptr += actual;
 167                 result = actual;
 168 #else
 169                 printf("> "); fflush(stdout);
 170                 int c = '*', n;
 171                 for (n = 0; n < max_size && (c = getc(yyin)) != EOF && c != '\n'; ++n)
 172                         buf[n] = (char)c;
 173                 if (c == '\n')
 174                         buf[n++] = (char)c;
 175                 if (c == EOF && ferror(yyin))
 176                         YY_FATAL_ERROR("input in flex scanner failed");
 177                 result = n;
 178 #endif
 179         } else if (((result = fread(buf, 1, max_size, yyin)) == 0) && ferror(yyin))
 180                 YY_FATAL_ERROR("input in flex scanner failed");
 181
 182         return result;
 183 }
 184
 185 // List of input files to be processed
 186 int num_files = 0;
 187 char **file_list = NULL;
 188
 189 // EOF encountered, connect to next file. If this was the last file,
 190 // connect to stdin. If this was stdin, terminate the scanner.
 191 int yywrap()
 192 {
 193         if (yyin == stdin)
 194                 return 1;
 195
 196         fclose(yyin);
 197         if (num_files) {
 198                 yyin = fopen(*file_list, "r");
 199                 if (yyin == NULL) {
 200                         cerr << "Can't open " << *file_list << endl;
 201                         return 1;
 202                 }
 203                 num_files--;
 204                 file_list++;
 205         } else
 206                 yyin = stdin;
 207         return 0;
 208 }