configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl GiNaC version number
   4 m4_define([ginac_major_version], [1])
   5 m4_define([ginac_minor_version], [5])
   6 m4_define([ginac_micro_version], [0])
   7 m4_define([ginac_version], [ginac_major_version.ginac_minor_version.ginac_micro_version])
   8 m4_define([ginac_release], [ginac_major_version.ginac_minor_version])
   9
  10 dnl GiNaC library version information. It has very little to do with GiNaC
  11 dnl version number. In particular, library version is OS dependent.
  12 dnl
  13 dnl When making releases, do
  14 dnl 1. Increment ginac_lt_revision
  15 dnl 2. If any interfaces have been added, removed, or changed since the last
  16 dnl    release, increment ginac_lt_current and set ginac_lt_revision to 0.
  17 dnl 3. If any interfaces have been removed since the last release, set
  18 dnl    ginac_lt_age to 0.
  19 dnl
  20 dnl Please note: the libtool naming scheme cannot guarantee that on all
  21 dnl systems, the numbering is consecutive. It only guarantees that it is
  22 dnl increasing. This doesn't matter, though: there is not incurred cost
  23 dnl for numbers that are omitted, except for shrinking the available space
  24 dnl of leftover numbers. Not something we need to worry about yet. ;-)
  25 m4_define([ginac_lt_current], [0])
  26 m4_define([ginac_lt_age], [0])
  27 m4_define([ginac_lt_revision], [0])
  28
  29 AC_INIT([GiNaC], ginac_version, [<ginac-list@ginac.de>])
  30 AC_PREREQ(2.59)
  31 AC_CONFIG_SRCDIR(ginac/basic.cpp)
  32 AC_CONFIG_AUX_DIR([config])
  33 AC_CONFIG_HEADERS([config/config.h])
  34 AC_CONFIG_MACRO_DIR([m4])
  35 dnl This defines PACKAGE and VERSION.
  36 AM_INIT_AUTOMAKE([gnu 1.7 dist-bzip2])
  37
  38 dnl Process GiNaC version information
  39 GINACLIB_MAJOR_VERSION=ginac_major_version
  40 GINACLIB_MINOR_VERSION=ginac_minor_version
  41 GINACLIB_MICRO_VERSION=ginac_micro_version
  42 GINACLIB_VERSION=ginac_version
  43 AC_SUBST(GINACLIB_MAJOR_VERSION)
  44 AC_SUBST(GINACLIB_MINOR_VERSION)
  45 AC_SUBST(GINACLIB_MICRO_VERSION)
  46 AC_SUBST(GINACLIB_VERSION)
  47
  48 dnl GiNaC archive file version information.
  49 dnl
  50 dnl If properties have been added, ARCHIVE_VERSION += 1, ARCHIVE_AGE += 1.
  51 dnl If backwards compatibility has been broken, set ARCHIVE_AGE to 0.
  52 dnl
  53 dnl The version number in newly created archives will be ARCHIVE_VERSION.
  54 dnl Archives version (ARCHIVE_VERSION-ARCHIVE_AGE) thru ARCHIVE_VERSION can
  55 dnl be read by this version of the GiNaC library.
  56
  57 ARCHIVE_VERSION=3
  58 ARCHIVE_AGE=3
  59
  60 AC_SUBST(ARCHIVE_VERSION)
  61 AC_SUBST(ARCHIVE_AGE)
  62 AC_DEFINE_UNQUOTED(ARCHIVE_VERSION, $ARCHIVE_VERSION, [Current GiNaC archive file version number])
  63 AC_DEFINE_UNQUOTED(ARCHIVE_AGE, $ARCHIVE_AGE, [GiNaC archive file version age])
  64
  65 dnl libtool versioning
  66 LT_VERSION_INFO="ginac_lt_current:ginac_lt_revision:ginac_lt_age"
  67 LT_RELEASE="ginac_release"
  68
  69 AC_SUBST(LT_VERSION_INFO)
  70 AC_SUBST(LT_RELEASE)
  71
  72
  73 dnl Check for the compiler and all the utilities needed for the build.
  74 AC_PROG_CXX
  75 AC_PROG_CXXCPP
  76 AC_PROG_INSTALL
  77 AM_PROG_LIBTOOL
  78 AM_PROG_LEX
  79 AC_PROG_YACC
  80
  81
  82 dnl Switch to C++ language mode for the following libraries and headers.
  83 AC_LANG([C++])
  84
  85 dnl Make sure all the necessary standard headers are installed on the system.
  86 GINAC_STD_CXX_HEADERS
  87
  88 dnl We need to have Bruno Haible's CLN installed.
  89 dnl (pkg-config must have installed pkg.m4 at a visible place, which provides
  90 dnl this macro. CLN >= 1.1.6 must have installed cln.pc at a visible place,
  91 dnl which provides the actual dependency information.)
  92 PKG_CHECK_MODULES(CLN, cln >= 1.1.6)
  93 AC_LIB_LINKFLAGS_FROM_LIBS([CLN_RPATH], [$CLN_LIBS], [1])
  94 LIBS="$LIBS $CLN_LIBS $CLN_RPATH"
  95 CPPFLAGS="$CPPFLAGS $CLN_CFLAGS"
  96 dnl Include proper rpath into pkg-config meta data, so
  97 dnl g++ `pkg-config --cflags --libs ginac`
  98 dnl actually works
  99 GINACLIB_LIBS='-L${libdir} -lginac'
 100 AC_LIB_LINKFLAGS_FROM_LIBS([GINACLIB_RPATH], [$GINACLIB_LIBS])
 101
 102 dnl Check for data types which are needed by the hash function
 103 dnl (golden_ratio_hash).
 104 AC_CHECK_TYPE(long long)
 105
 106 dnl Check for stuff needed for building the GiNaC interactive shell (ginsh).
 107 AC_CHECK_HEADERS(unistd.h)
 108 GINAC_HAVE_RUSAGE
 109 GINAC_READLINE
 110
 111 dnl Check for dl library (needed for GiNaC::compile).
 112 GINAC_EXCOMPILER
 113
 114 dnl Check for utilities needed by the different kinds of documentation.
 115 dnl Documentation needs only be built when extending it, so never mind if it
 116 dnl cannot find those helpers:
 117 AC_PATH_PROG(DOXYGEN, doxygen, "")
 118 AM_CONDITIONAL(CONFIG_DOXYGEN, [test ! -z "$DOXYGEN"])
 119 AC_PATH_PROG(LATEX, latex, "")
 120 AC_PATH_PROG(PDFLATEX, pdflatex, "")
 121 AC_PATH_PROG(MAKEINDEX, makeindex, "")
 122 AC_PATH_PROG(DVIPS, dvips, "")
 123 AM_CONDITIONAL(CONFIG_TEX, [test ! \( -z "$LATEX" -o -z $"PDFLATEX" -o -z "$MAKEINDEX" -o -z "$DVIPS" \)])
 124 AC_PATH_PROG(FIG2DEV, fig2dev, "")
 125 AM_CONDITIONAL(CONFIG_FIG2DEV, [test ! -z "$FIG2DEV"])
 126
 127 dnl generate boilerplate code for the (new) parser.
 128 dnl Only developers need this tool.
 129 AC_PATH_PROG(AUTOGEN, autogen, "")
 130
 131 dnl Output makefiles etc.
 132 AC_CONFIG_FILES([
 133 Makefile
 134 GiNaC.spec
 135 ginac.pc
 136 ginac/Makefile
 137 ginac/version.h
 138 check/Makefile
 139 ginsh/Makefile
 140 ginsh/ginsh.1
 141 tools/Makefile
 142 tools/viewgar.1
 143 tools/ginac-excompiler
 144 doc/Makefile
 145 doc/examples/Makefile
 146 doc/tutorial/Makefile
 147 doc/reference/Makefile
 148 doc/reference/DoxyfileHTML
 149 doc/reference/DoxyfileTEX
 150 doc/reference/DoxyfilePDF
 151 doc/reference/Doxyfooter
 152 ])
 153 AC_OUTPUT
 154 dnl Display a final warning if there has been a GINAC_ERROR or a GINAC_WARNING
 155 GINAC_CHECK_ERRORS