configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl GiNaC library version information.
   4 dnl
   5 dnl Making releases:
   6 dnl   ginac_micro_version += 1;
   7 dnl   ginac_interface_age += 1;
   8 dnl   ginac_binary_age += 1;
   9 dnl if any functions have been added, set ginac_interface_age to 0.
  10 dnl if backwards compatibility has been broken,
  11 dnl set ginac_binary_age and ginac_interface_age to 0.
  12
  13 m4_define([ginac_major_version], [1])
  14 m4_define([ginac_minor_version], [5])
  15 m4_define([ginac_micro_version], [0])
  16 m4_define([ginac_version], [ginac_major_version.ginac_minor_version.ginac_micro_version])
  17 m4_define([ginac_release], [ginac_major_version.ginac_minor_version])
  18 m4_define([ginac_interface_age], [0])
  19 m4_define([ginac_binary_age], [0])
  20
  21 AC_INIT([GiNaC], ginac_version, [<ginac-list@ginac.de>])
  22 AC_PREREQ(2.59)
  23 AC_CONFIG_SRCDIR(ginac/basic.cpp)
  24 AC_CONFIG_AUX_DIR([config])
  25 AC_CONFIG_HEADERS([config/config.h])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 dnl This defines PACKAGE and VERSION.
  28 AM_INIT_AUTOMAKE([gnu 1.7 dist-bzip2])
  29
  30 dnl Process GiNaC version information
  31 GINACLIB_MAJOR_VERSION=ginac_major_version
  32 GINACLIB_MINOR_VERSION=ginac_minor_version
  33 GINACLIB_MICRO_VERSION=ginac_micro_version
  34 GINACLIB_VERSION=ginac_version
  35 AC_SUBST(GINACLIB_MAJOR_VERSION)
  36 AC_SUBST(GINACLIB_MINOR_VERSION)
  37 AC_SUBST(GINACLIB_MICRO_VERSION)
  38 AC_SUBST(GINACLIB_VERSION)
  39
  40 dnl GiNaC archive file version information.
  41 dnl
  42 dnl If properties have been added, ARCHIVE_VERSION += 1, ARCHIVE_AGE += 1.
  43 dnl If backwards compatibility has been broken, set ARCHIVE_AGE to 0.
  44 dnl
  45 dnl The version number in newly created archives will be ARCHIVE_VERSION.
  46 dnl Archives version (ARCHIVE_VERSION-ARCHIVE_AGE) thru ARCHIVE_VERSION can
  47 dnl be read by this version of the GiNaC library.
  48
  49 ARCHIVE_VERSION=3
  50 ARCHIVE_AGE=3
  51
  52 AC_SUBST(ARCHIVE_VERSION)
  53 AC_SUBST(ARCHIVE_AGE)
  54 AC_DEFINE_UNQUOTED(ARCHIVE_VERSION, $ARCHIVE_VERSION, [Current GiNaC archive file version number])
  55 AC_DEFINE_UNQUOTED(ARCHIVE_AGE, $ARCHIVE_AGE, [GiNaC archive file version age])
  56
  57 dnl libtool versioning
  58 m4_define([lt_revision], [ginac_interface_age])
  59 m4_define([lt_current], [m4_eval(ginac_micro_version - ginac_interface_age)])
  60 m4_define([lt_age], [m4_eval(ginac_binary_age - ginac_interface_age)])
  61 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
  62 LT_RELEASE="ginac_release"
  63
  64 AC_SUBST(LT_VERSION_INFO)
  65 AC_SUBST(LT_RELEASE)
  66
  67
  68 dnl Check for the compiler and all the utilities needed for the build.
  69 AC_PROG_CXX
  70 AC_PROG_CXXCPP
  71 AC_PROG_INSTALL
  72 AM_PROG_LIBTOOL
  73 AM_PROG_LEX
  74 AC_PROG_YACC
  75
  76
  77 dnl Switch to C++ language mode for the following libraries and headers.
  78 AC_LANG([C++])
  79
  80 dnl Make sure all the necessary standard headers are installed on the system.
  81 GINAC_STD_CXX_HEADERS
  82
  83 dnl We need to have Bruno Haible's CLN installed.
  84 dnl (pkg-config must have installed pkg.m4 at a visible place, which provides
  85 dnl this macro. CLN >= 1.1.6 must have installed cln.pc at a visible place,
  86 dnl which provides the actual dependency information.)
  87 PKG_CHECK_MODULES(CLN, cln >= 1.1.6)
  88 AC_LIB_LINKFLAGS_FROM_LIBS([CLN_RPATH], [$CLN_LIBS], [1])
  89 LIBS="$LIBS $CLN_LIBS $CLN_RPATH"
  90 CPPFLAGS="$CPPFLAGS $CLN_CFLAGS"
  91 dnl Include proper rpath into pkg-config meta data, so
  92 dnl g++ `pkg-config --cflags --libs ginac`
  93 dnl actually works
  94 GINACLIB_LIBS='-L${libdir} -lginac'
  95 AC_LIB_LINKFLAGS_FROM_LIBS([GINACLIB_RPATH], [$GINACLIB_LIBS])
  96
  97 dnl Check for data types which are needed by the hash function
  98 dnl (golden_ratio_hash).
  99 AC_CHECK_TYPE(long long)
 100
 101 dnl Check for stuff needed for building the GiNaC interactive shell (ginsh).
 102 AC_CHECK_HEADERS(unistd.h)
 103 GINAC_HAVE_RUSAGE
 104 GINAC_READLINE
 105
 106 dnl Check for dl library (needed for GiNaC::compile).
 107 GINAC_EXCOMPILER
 108
 109 dnl Check for utilities needed by the different kinds of documentation.
 110 dnl Documentation needs only be built when extending it, so never mind if it
 111 dnl cannot find those helpers:
 112 AC_PATH_PROG(DOXYGEN, doxygen, "")
 113 AM_CONDITIONAL(CONFIG_DOXYGEN, [test ! -z "$DOXYGEN"])
 114 AC_PATH_PROG(LATEX, latex, "")
 115 AC_PATH_PROG(PDFLATEX, pdflatex, "")
 116 AC_PATH_PROG(MAKEINDEX, makeindex, "")
 117 AC_PATH_PROG(DVIPS, dvips, "")
 118 AM_CONDITIONAL(CONFIG_TEX, [test ! \( -z "$LATEX" -o -z $"PDFLATEX" -o -z "$MAKEINDEX" -o -z "$DVIPS" \)])
 119 AC_PATH_PROG(FIG2DEV, fig2dev, "")
 120 AM_CONDITIONAL(CONFIG_FIG2DEV, [test ! -z "$FIG2DEV"])
 121
 122 dnl generate boilerplate code for the (new) parser.
 123 dnl Only developers need this tool.
 124 AC_PATH_PROG(AUTOGEN, autogen, "")
 125
 126 dnl Output makefiles etc.
 127 AC_CONFIG_FILES([
 128 Makefile
 129 GiNaC.spec
 130 ginac.pc
 131 ginac/Makefile
 132 ginac/version.h
 133 check/Makefile
 134 ginsh/Makefile
 135 ginsh/ginsh.1
 136 tools/Makefile
 137 tools/viewgar.1
 138 tools/ginac-excompiler
 139 doc/Makefile
 140 doc/examples/Makefile
 141 doc/tutorial/Makefile
 142 doc/reference/Makefile
 143 doc/reference/DoxyfileHTML
 144 doc/reference/DoxyfileTEX
 145 doc/reference/DoxyfilePDF
 146 doc/reference/Doxyfooter
 147 ])
 148 AC_OUTPUT
 149 dnl Display a final warning if there has been a GINAC_ERROR or a GINAC_WARNING
 150 GINAC_CHECK_ERRORS