configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl GiNaC version number
   4 m4_define([ginac_major_version], [1])
   5 m4_define([ginac_minor_version], [5])
   6 m4_define([ginac_micro_version], [8])
   7 m4_define([ginac_version], [ginac_major_version.ginac_minor_version.ginac_micro_version])
   8 m4_define([ginac_release], [ginac_major_version.ginac_minor_version])
   9
  10 dnl GiNaC library version information. It has very little to do with GiNaC
  11 dnl version number. In particular, library version is OS dependent.
  12 dnl
  13 dnl When making releases, do
  14 dnl 1. Increment ginac_lt_revision
  15 dnl 2. If any interfaces have been added, removed, or changed since the last
  16 dnl    release, increment ginac_lt_current and set ginac_lt_revision to 0.
  17 dnl 3. If any interfaces have been added since the last release, increment
  18 dnl    ginac_lt_age.
  19 dnl 4. If any interfaces have been removed since the last release, set
  20 dnl    ginac_lt_age to 0.
  21 dnl
  22 dnl Please note: the libtool naming scheme cannot guarantee that on all
  23 dnl systems, the numbering is consecutive. It only guarantees that it is
  24 dnl increasing. This doesn't matter, though: there is not incurred cost
  25 dnl for numbers that are omitted, except for shrinking the available space
  26 dnl of leftover numbers. Not something we need to worry about yet. ;-)
  27 m4_define([ginac_lt_current], [2])
  28 m4_define([ginac_lt_revision], [0])
  29 m4_define([ginac_lt_age], [2])
  30
  31 AC_INIT([GiNaC], ginac_version, [ginac-list@ginac.de], [ginac], [http://www.ginac.de/])
  32 AC_PREREQ(2.59)
  33 AC_CONFIG_SRCDIR(ginac/basic.cpp)
  34 AC_CONFIG_AUX_DIR([config])
  35 AC_CONFIG_HEADERS([config/config.h ginac/version.h])
  36 AC_CONFIG_MACRO_DIR([m4])
  37 dnl This defines PACKAGE and VERSION.
  38 AM_INIT_AUTOMAKE([gnu 1.8 dist-bzip2])
  39
  40 dnl Process GiNaC version information
  41 AC_DEFINE([GINACLIB_MAJOR_VERSION], ginac_major_version, [Major version of GiNaC])
  42 AC_DEFINE([GINACLIB_MINOR_VERSION], ginac_minor_version, [Minor version of GiNaC])
  43 AC_DEFINE([GINACLIB_MICRO_VERSION], ginac_micro_version, [Micro version of GiNaC])
  44
  45 dnl GiNaC archive file version information.
  46 dnl
  47 dnl If properties have been added, ARCHIVE_VERSION += 1, ARCHIVE_AGE += 1.
  48 dnl If backwards compatibility has been broken, set ARCHIVE_AGE to 0.
  49 dnl
  50 dnl The version number in newly created archives will be ARCHIVE_VERSION.
  51 dnl Archives version (ARCHIVE_VERSION-ARCHIVE_AGE) thru ARCHIVE_VERSION can
  52 dnl be read by this version of the GiNaC library.
  53
  54 ARCHIVE_VERSION=3
  55 ARCHIVE_AGE=3
  56
  57 AC_SUBST(ARCHIVE_VERSION)
  58 AC_SUBST(ARCHIVE_AGE)
  59 AC_DEFINE_UNQUOTED(ARCHIVE_VERSION, $ARCHIVE_VERSION, [Current GiNaC archive file version number])
  60 AC_DEFINE_UNQUOTED(ARCHIVE_AGE, $ARCHIVE_AGE, [GiNaC archive file version age])
  61
  62 dnl libtool versioning
  63 LT_VERSION_INFO="ginac_lt_current:ginac_lt_revision:ginac_lt_age"
  64 dnl TODO: remove LT_RELEASE after ABI gets changed. We used to set
  65 dnl LT_RELEASE (for no good reason), omitting it right now would
  66 dnl result in a spurious SONAME change.
  67 LT_RELEASE="1.5"
  68
  69 AC_SUBST(LT_VERSION_INFO)
  70 AC_SUBST(LT_RELEASE)
  71
  72 dnl Check for the compiler and all the utilities needed for the build.
  73 AC_PROG_CXX
  74 AC_PROG_CXXCPP
  75 AC_PROG_INSTALL
  76 AM_PROG_LIBTOOL
  77 AC_PROG_LEX
  78 AC_PROG_YACC
  79 AC_PATH_PROG(YACCEXE, $YACC, "")
  80
  81 dnl Switch to C++ language mode for the following libraries and headers.
  82 AC_LANG([C++])
  83
  84 dnl Make sure all the necessary standard headers are installed on the system.
  85 GINAC_STD_CXX_HEADERS
  86
  87 dnl We need to have CLN installed.
  88 PKG_CHECK_MODULES(CLN, cln >= 1.2.2)
  89 AC_LIB_LINKFLAGS_FROM_LIBS([CLN_RPATH], [$CLN_LIBS], [1])
  90 LIBS="$LIBS $CLN_LIBS $CLN_RPATH"
  91 CPPFLAGS="$CPPFLAGS $CLN_CFLAGS"
  92 dnl Include proper rpath into pkg-config meta data, so
  93 dnl g++ `pkg-config --cflags --libs ginac`
  94 dnl actually works
  95 GINACLIB_LIBS='-L${libdir} -lginac'
  96 AC_LIB_LINKFLAGS_FROM_LIBS([GINACLIB_RPATH], [$GINACLIB_LIBS])
  97
  98 dnl Check for data types which are needed by the hash function
  99 dnl (golden_ratio_hash).
 100 AC_CHECK_TYPE(long long)
 101
 102 dnl Check for stuff needed for building the GiNaC interactive shell (ginsh).
 103 AC_CHECK_HEADERS(unistd.h)
 104 GINAC_HAVE_RUSAGE
 105 GINAC_READLINE
 106 AC_CHECK_FILE([ginsh/ginsh_parser.h], [],
 107                           [AS_IF([test -z "$YACCEXE"], [GINAC_WARNING([ginsh will not compile, because yacc/bison is missing.])])])
 108 AC_CHECK_FILE([ginsh/ginsh_lexer.cc], [],
 109                           [AS_IF([test x"$LEX" == x":"], [GINAC_WARNING([ginsh will not compile, because lex/flex is missing.])])])
 110
 111 dnl Check for dl library (needed for GiNaC::compile).
 112 GINAC_EXCOMPILER
 113 AM_CONDITIONAL(CONFIG_EXCOMPILER, [test "x${CONFIG_EXCOMPILER}" = "xyes"])
 114
 115 dnl Check for utilities needed by the different kinds of documentation.
 116 dnl Documentation needs only be built when extending it, so never mind if it
 117 dnl cannot find those helpers:
 118 AC_PATH_PROG(DOXYGEN, doxygen, "")
 119 AM_CONDITIONAL(CONFIG_DOXYGEN, [test ! -z "$DOXYGEN"])
 120 AC_PATH_PROG(LATEX, latex, "")
 121 AC_PATH_PROG(PDFLATEX, pdflatex, "")
 122 AC_PATH_PROG(MAKEINDEX, makeindex, "")
 123 AC_PATH_PROG(MAKEINFO, makeinfo, "")
 124 AC_PATH_PROG(DVIPS, dvips, "")
 125 AM_CONDITIONAL(CONFIG_TEX, [test ! \( -z "$LATEX" -o -z $"PDFLATEX" -o -z "$MAKEINDEX" -o -z "$DVIPS" \)])
 126 AC_PATH_PROG(FIG2DEV, fig2dev, "")
 127 AM_CONDITIONAL(CONFIG_FIG2DEV, [test ! -z "$FIG2DEV"])
 128 AS_IF([test -z "$FIG2DEV" -o -z "$MAKEINFO"],
 129           [GINAC_WARNING([Documentation may not build, because fig2dev/texinfo is missing.])])
 130 AS_IF([test -z "$DOXYGEN"],
 131           [GINAC_WARNING([Reference manual will not build, because doxygen is missing.])])
 132 AS_IF([test -z "$LATEX" -o -z "$PDFLATEX" -o -z "$DVIPS"],
 133           [GINAC_WARNING([Some documentation formats may not build, because latex/pdflatex/dvips is missing.])])
 134
 135 dnl generate boilerplate code for the (new) parser.
 136 dnl Only developers need this tool.
 137 AC_PATH_PROG(AUTOGEN, autogen, "")
 138 AC_CHECK_FILE([ginac/parser/builtin_fcns.cpp], [],
 139                           [AS_IF([test -z "$AUTOGEN"], [GINAC_ERROR([Source will not compile, because autogen is missing.])])])
 140
 141 dnl Output makefiles etc.
 142 AC_CONFIG_FILES([
 143 Makefile
 144 GiNaC.spec
 145 ginac.pc
 146 ginac/Makefile
 147 check/Makefile
 148 ginsh/Makefile
 149 ginsh/ginsh.1
 150 tools/Makefile
 151 tools/viewgar.1
 152 tools/ginac-excompiler
 153 doc/Makefile
 154 doc/examples/Makefile
 155 doc/tutorial/Makefile
 156 doc/reference/Makefile
 157 doc/reference/DoxyfileHTML
 158 doc/reference/DoxyfileTEX
 159 doc/reference/DoxyfilePDF
 160 doc/reference/Doxyfooter
 161 ])
 162 AC_OUTPUT
 163
 164 dnl Display a final warning if there has been a GINAC_ERROR or a GINAC_WARNING
 165 GINAC_CHECK_ERRORS