configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl GiNaC library version information.
   4 dnl
   5 dnl Making releases:
   6 dnl   ginac_micro_version += 1;
   7 dnl   ginac_interface_age += 1;
   8 dnl   ginac_binary_age += 1;
   9 dnl if any functions have been added, set ginac_interface_age to 0.
  10 dnl if backwards compatibility has been broken,
  11 dnl set ginac_binary_age and ginac_interface_age to 0.
  12
  13 m4_define([ginac_major_version], [1])
  14 m4_define([ginac_minor_version], [5])
  15 m4_define([ginac_micro_version], [0])
  16 m4_define([ginac_version], [ginac_major_version.ginac_minor_version.ginac_micro_version])
  17 m4_define([ginac_release], [ginac_major_version.ginac_minor_version])
  18 m4_define([ginac_interface_age], [0])
  19 m4_define([ginac_binary_age], [0])
  20
  21 AC_INIT([GiNaC], ginac_version, [<ginac-list@ginac.de>])
  22 AC_PREREQ(2.59)
  23 AC_CONFIG_SRCDIR(ginac/basic.cpp)
  24 AC_CONFIG_AUX_DIR([config])
  25 AC_CONFIG_HEADERS([config/config.h])
  26 dnl This defines PACKAGE and VERSION.
  27 AM_INIT_AUTOMAKE([gnu 1.7 dist-bzip2])
  28
  29 dnl Process GiNaC version information
  30 GINACLIB_MAJOR_VERSION=ginac_major_version
  31 GINACLIB_MINOR_VERSION=ginac_minor_version
  32 GINACLIB_MICRO_VERSION=ginac_micro_version
  33 GINACLIB_VERSION=ginac_version
  34 AC_SUBST(GINACLIB_MAJOR_VERSION)
  35 AC_SUBST(GINACLIB_MINOR_VERSION)
  36 AC_SUBST(GINACLIB_MICRO_VERSION)
  37 AC_SUBST(GINACLIB_VERSION)
  38
  39 dnl GiNaC archive file version information.
  40 dnl
  41 dnl If properties have been added, ARCHIVE_VERSION += 1, ARCHIVE_AGE += 1.
  42 dnl If backwards compatibility has been broken, set ARCHIVE_AGE to 0.
  43 dnl
  44 dnl The version number in newly created archives will be ARCHIVE_VERSION.
  45 dnl Archives version (ARCHIVE_VERSION-ARCHIVE_AGE) thru ARCHIVE_VERSION can
  46 dnl be read by this version of the GiNaC library.
  47
  48 ARCHIVE_VERSION=3
  49 ARCHIVE_AGE=3
  50
  51 AC_SUBST(ARCHIVE_VERSION)
  52 AC_SUBST(ARCHIVE_AGE)
  53 AC_DEFINE_UNQUOTED(ARCHIVE_VERSION, $ARCHIVE_VERSION, [Current GiNaC archive file version number])
  54 AC_DEFINE_UNQUOTED(ARCHIVE_AGE, $ARCHIVE_AGE, [GiNaC archive file version age])
  55
  56 dnl libtool versioning
  57 m4_define([lt_revision], [ginac_interface_age])
  58 m4_define([lt_current], [m4_eval(ginac_micro_version - ginac_interface_age)])
  59 m4_define([lt_age], [m4_eval(ginac_binary_age - ginac_interface_age)])
  60 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
  61 LT_RELEASE="ginac_release"
  62
  63 AC_SUBST(LT_VERSION_INFO)
  64 AC_SUBST(LT_RELEASE)
  65
  66
  67 dnl Check for the compiler and all the utilities needed for the build.
  68 AC_PROG_CXX
  69 AC_PROG_CXXCPP
  70 AC_PROG_INSTALL
  71 AM_PROG_LIBTOOL
  72 AM_PROG_LEX
  73 AC_PROG_YACC
  74
  75
  76 dnl Switch to C++ language mode for the following libraries and headers.
  77 AC_LANG([C++])
  78
  79 dnl Make sure all the necessary standard headers are installed on the system.
  80 GINAC_STD_CXX_HEADERS
  81
  82 dnl We need to have Bruno Haible's CLN installed.
  83 dnl (pkg-config must have installed pkg.m4 at a visible place, which provides
  84 dnl this macro. CLN >= 1.1.6 must have installed cln.pc at a visible place,
  85 dnl which provides the actual dependency information.)
  86 PKG_CHECK_MODULES(CLN, cln >= 1.1.6)
  87 LIBS="$LIBS $CLN_LIBS"
  88 CPPFLAGS="$CPPFLAGS $CLN_CFLAGS"
  89
  90 dnl Check for data types which are needed by the hash function
  91 dnl (golden_ratio_hash).
  92 AC_CHECK_TYPE(long long)
  93
  94 dnl Check for stuff needed for building the GiNaC interactive shell (ginsh).
  95 AC_CHECK_HEADERS(unistd.h)
  96 GINAC_HAVE_RUSAGE
  97 GINAC_READLINE
  98
  99 dnl Check for dl library (needed for GiNaC::compile).
 100 GINAC_EXCOMPILER
 101
 102 dnl Check for utilities needed by the different kinds of documentation.
 103 dnl Documentation needs only be built when extending it, so never mind if it
 104 dnl cannot find those helpers:
 105 AC_PATH_PROG(DOXYGEN, doxygen, "")
 106 AM_CONDITIONAL(CONFIG_DOXYGEN, [test ! -z "$DOXYGEN"])
 107 AC_PATH_PROG(LATEX, latex, "")
 108 AC_PATH_PROG(PDFLATEX, pdflatex, "")
 109 AC_PATH_PROG(MAKEINDEX, makeindex, "")
 110 AC_PATH_PROG(DVIPS, dvips, "")
 111 AM_CONDITIONAL(CONFIG_TEX, [test ! \( -z "$LATEX" -o -z $"PDFLATEX" -o -z "$MAKEINDEX" -o -z "$DVIPS" \)])
 112 AC_PATH_PROG(FIG2DEV, fig2dev, "")
 113 AM_CONDITIONAL(CONFIG_FIG2DEV, [test ! -z "$FIG2DEV"])
 114
 115 dnl generate boilerplate code for the (new) parser.
 116 dnl Only developers need this tool.
 117 AC_PATH_PROG(AUTOGEN, autogen, "")
 118
 119 dnl Output makefiles etc.
 120 AC_CONFIG_FILES([
 121 Makefile
 122 GiNaC.spec
 123 ginac.pc
 124 ginac/Makefile
 125 ginac/version.h
 126 check/Makefile
 127 ginsh/Makefile
 128 ginsh/ginsh.1
 129 tools/Makefile
 130 tools/viewgar.1
 131 tools/ginac-excompiler
 132 doc/Makefile
 133 doc/examples/Makefile
 134 doc/tutorial/Makefile
 135 doc/reference/Makefile
 136 doc/reference/DoxyfileHTML
 137 doc/reference/DoxyfileTEX
 138 doc/reference/DoxyfilePDF
 139 doc/reference/Doxyfooter
 140 ])
 141 AC_OUTPUT
 142 dnl Display a final warning if there has been a GINAC_ERROR or a GINAC_WARNING
 143 GINAC_CHECK_ERRORS