configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl GiNaC version number
   4 m4_define([ginac_major_version], [1])
   5 m4_define([ginac_minor_version], [5])
   6 m4_define([ginac_micro_version], [0])
   7 m4_define([ginac_version], [ginac_major_version.ginac_minor_version.ginac_micro_version])
   8 m4_define([ginac_release], [ginac_major_version.ginac_minor_version])
   9
  10 dnl GiNaC library version information. It has very little to do with GiNaC
  11 dnl version number. In particular, library version is OS dependent.
  12 dnl
  13 dnl When making releases, do
  14 dnl 1. Increment ginac_lt_revision
  15 dnl 2. If any interfaces have been added since the last release, increment
  16 dnl    ginac_lt_current and set ginac_lt_revision to 0.
  17 dnl 3. If any interfaces have been changed or removed since the last release,
  18 dnl    make sure you increment ginac_minor_version above and reset both
  19 dnl    ginac_lt_current and ginac_lt_revision to 0.
  20 dnl
  21 dnl Please note: the libtool naming scheme cannot guarantee that on all
  22 dnl systems, the numbering is consecutive. It only guarantees that it is
  23 dnl increasing. This doesn't matter, though: there is not incurred cost
  24 dnl for numbers that are omitted, except for shrinking the available space
  25 dnl of leftover numbers. Not something we need to worry about yet. ;-)
  26 m4_define([ginac_lt_current], [0])
  27 m4_define([ginac_lt_revision], [0])
  28
  29 AC_INIT([GiNaC], ginac_version, [ginac-list@ginac.de], [ginac], [http://www.ginac.de/])
  30 AC_PREREQ(2.59)
  31 AC_CONFIG_SRCDIR(ginac/basic.cpp)
  32 AC_CONFIG_AUX_DIR([config])
  33 AC_CONFIG_HEADERS([config/config.h ginac/version.h])
  34 AC_CONFIG_MACRO_DIR([m4])
  35 dnl This defines PACKAGE and VERSION.
  36 AM_INIT_AUTOMAKE([gnu 1.8 dist-bzip2])
  37
  38 dnl Process GiNaC version information
  39 AC_DEFINE([GINACLIB_MAJOR_VERSION], ginac_major_version, [Major version of GiNaC])
  40 AC_DEFINE([GINACLIB_MINOR_VERSION], ginac_minor_version, [Minor version of GiNaC])
  41 AC_DEFINE([GINACLIB_MICRO_VERSION], ginac_micro_version, [Micro version of GiNaC])
  42
  43 dnl GiNaC archive file version information.
  44 dnl
  45 dnl If properties have been added, ARCHIVE_VERSION += 1, ARCHIVE_AGE += 1.
  46 dnl If backwards compatibility has been broken, set ARCHIVE_AGE to 0.
  47 dnl
  48 dnl The version number in newly created archives will be ARCHIVE_VERSION.
  49 dnl Archives version (ARCHIVE_VERSION-ARCHIVE_AGE) thru ARCHIVE_VERSION can
  50 dnl be read by this version of the GiNaC library.
  51
  52 ARCHIVE_VERSION=3
  53 ARCHIVE_AGE=3
  54
  55 AC_SUBST(ARCHIVE_VERSION)
  56 AC_SUBST(ARCHIVE_AGE)
  57 AC_DEFINE_UNQUOTED(ARCHIVE_VERSION, $ARCHIVE_VERSION, [Current GiNaC archive file version number])
  58 AC_DEFINE_UNQUOTED(ARCHIVE_AGE, $ARCHIVE_AGE, [GiNaC archive file version age])
  59
  60 dnl libtool versioning (We don't use libtool's age numbering since we promise
  61 dnl to keep the binary interface compatible if only ginac_micro_version changes.
  62 dnl In effect, age==current.)
  63 LT_VERSION_INFO="ginac_lt_current:ginac_lt_revision:ginac_lt_current"
  64 LT_RELEASE="ginac_release"
  65
  66 AC_SUBST(LT_VERSION_INFO)
  67 AC_SUBST(LT_RELEASE)
  68
  69
  70 dnl Check for the compiler and all the utilities needed for the build.
  71 AC_PROG_CXX
  72 AC_PROG_CXXCPP
  73 AC_PROG_INSTALL
  74 AM_PROG_LIBTOOL
  75 AM_PROG_LEX
  76 AC_PROG_YACC
  77
  78
  79 dnl Switch to C++ language mode for the following libraries and headers.
  80 AC_LANG([C++])
  81
  82 dnl Make sure all the necessary standard headers are installed on the system.
  83 GINAC_STD_CXX_HEADERS
  84
  85 dnl We need to have CLN installed.
  86 PKG_CHECK_MODULES(CLN, cln >= 1.2.2)
  87 AC_LIB_LINKFLAGS_FROM_LIBS([CLN_RPATH], [$CLN_LIBS], [1])
  88 LIBS="$LIBS $CLN_LIBS $CLN_RPATH"
  89 CPPFLAGS="$CPPFLAGS $CLN_CFLAGS"
  90 dnl Include proper rpath into pkg-config meta data, so
  91 dnl g++ `pkg-config --cflags --libs ginac`
  92 dnl actually works
  93 GINACLIB_LIBS='-L${libdir} -lginac'
  94 AC_LIB_LINKFLAGS_FROM_LIBS([GINACLIB_RPATH], [$GINACLIB_LIBS])
  95
  96 dnl Check for data types which are needed by the hash function
  97 dnl (golden_ratio_hash).
  98 AC_CHECK_TYPE(long long)
  99
 100 dnl Check for stuff needed for building the GiNaC interactive shell (ginsh).
 101 AC_CHECK_HEADERS(unistd.h)
 102 GINAC_HAVE_RUSAGE
 103 GINAC_READLINE
 104
 105 dnl Check for dl library (needed for GiNaC::compile).
 106 GINAC_EXCOMPILER
 107 AM_CONDITIONAL(CONFIG_EXCOMPILER, [test "x${CONFIG_EXCOMPILER}" = "xyes"])
 108
 109 dnl Check for utilities needed by the different kinds of documentation.
 110 dnl Documentation needs only be built when extending it, so never mind if it
 111 dnl cannot find those helpers:
 112 AC_PATH_PROG(DOXYGEN, doxygen, "")
 113 AM_CONDITIONAL(CONFIG_DOXYGEN, [test ! -z "$DOXYGEN"])
 114 AC_PATH_PROG(LATEX, latex, "")
 115 AC_PATH_PROG(PDFLATEX, pdflatex, "")
 116 AC_PATH_PROG(MAKEINDEX, makeindex, "")
 117 AC_PATH_PROG(DVIPS, dvips, "")
 118 AM_CONDITIONAL(CONFIG_TEX, [test ! \( -z "$LATEX" -o -z $"PDFLATEX" -o -z "$MAKEINDEX" -o -z "$DVIPS" \)])
 119 AC_PATH_PROG(FIG2DEV, fig2dev, "")
 120 AM_CONDITIONAL(CONFIG_FIG2DEV, [test ! -z "$FIG2DEV"])
 121
 122 dnl Output makefiles etc.
 123 AC_CONFIG_FILES([
 124 Makefile
 125 GiNaC.spec
 126 ginac.pc
 127 ginac/Makefile
 128 check/Makefile
 129 ginsh/Makefile
 130 ginsh/ginsh.1
 131 tools/Makefile
 132 tools/viewgar.1
 133 tools/ginac-excompiler
 134 doc/Makefile
 135 doc/examples/Makefile
 136 doc/tutorial/Makefile
 137 doc/reference/Makefile
 138 doc/reference/DoxyfileHTML
 139 doc/reference/DoxyfileTEX
 140 doc/reference/DoxyfilePDF
 141 doc/reference/Doxyfooter
 142 ])
 143 AC_OUTPUT
 144 dnl Display a final warning if there has been a GINAC_ERROR or a GINAC_WARNING
 145 GINAC_CHECK_ERRORS