configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl GiNaC library version information.
   4 dnl
   5 dnl Making releases:
   6 dnl   ginac_micro_version += 1;
   7 dnl   ginac_interface_age += 1;
   8 dnl   ginac_binary_age += 1;
   9 dnl if any functions have been added, set ginac_interface_age to 0.
  10 dnl if backwards compatibility has been broken,
  11 dnl set ginac_binary_age and ginac_interface_age to 0.
  12
  13 m4_define([ginac_major_version], [1])
  14 m4_define([ginac_minor_version], [5])
  15 m4_define([ginac_micro_version], [0])
  16 m4_define([ginac_version], [ginac_major_version.ginac_minor_version.ginac_micro_version])
  17 m4_define([ginac_release], [ginac_major_version.ginac_minor_version])
  18 m4_define([ginac_interface_age], [0])
  19 m4_define([ginac_binary_age], [0])
  20
  21 AC_INIT([GiNaC], ginac_version, [<ginac-list@ginac.de>])
  22 AC_PREREQ(2.59)
  23 AC_CONFIG_SRCDIR(ginac/basic.cpp)
  24 AC_CONFIG_HEADERS(config.h)
  25 dnl This defines PACKAGE and VERSION.
  26 AM_INIT_AUTOMAKE([gnu 1.7 dist-bzip2])
  27
  28 dnl Process GiNaC version information
  29 GINACLIB_MAJOR_VERSION=ginac_major_version
  30 GINACLIB_MINOR_VERSION=ginac_minor_version
  31 GINACLIB_MICRO_VERSION=ginac_micro_version
  32 GINACLIB_VERSION=ginac_version
  33 AC_SUBST(GINACLIB_MAJOR_VERSION)
  34 AC_SUBST(GINACLIB_MINOR_VERSION)
  35 AC_SUBST(GINACLIB_MICRO_VERSION)
  36 AC_SUBST(GINACLIB_VERSION)
  37
  38 dnl GiNaC archive file version information.
  39 dnl
  40 dnl If properties have been added, ARCHIVE_VERSION += 1, ARCHIVE_AGE += 1.
  41 dnl If backwards compatibility has been broken, set ARCHIVE_AGE to 0.
  42 dnl
  43 dnl The version number in newly created archives will be ARCHIVE_VERSION.
  44 dnl Archives version (ARCHIVE_VERSION-ARCHIVE_AGE) thru ARCHIVE_VERSION can
  45 dnl be read by this version of the GiNaC library.
  46
  47 ARCHIVE_VERSION=3
  48 ARCHIVE_AGE=3
  49
  50 AC_SUBST(ARCHIVE_VERSION)
  51 AC_SUBST(ARCHIVE_AGE)
  52 AC_DEFINE_UNQUOTED(ARCHIVE_VERSION, $ARCHIVE_VERSION, [Current GiNaC archive file version number])
  53 AC_DEFINE_UNQUOTED(ARCHIVE_AGE, $ARCHIVE_AGE, [GiNaC archive file version age])
  54
  55 dnl libtool versioning
  56 m4_define([lt_revision], [ginac_interface_age])
  57 m4_define([lt_current], [m4_eval(ginac_micro_version - ginac_interface_age)])
  58 m4_define([lt_age], [m4_eval(ginac_binary_age - ginac_interface_age)])
  59 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
  60 LT_RELEASE="ginac_release"
  61
  62 AC_SUBST(LT_VERSION_INFO)
  63 AC_SUBST(LT_RELEASE)
  64
  65
  66 dnl Check for the compiler and all the utilities needed for the build.
  67 AC_PROG_CXX
  68 AC_PROG_CXXCPP
  69 AC_PROG_INSTALL
  70 AM_PROG_LIBTOOL
  71 AM_PROG_LEX
  72 AC_PROG_YACC
  73
  74 dnl Check for data types which are needed by the hash function
  75 dnl (golden_ratio_hash).
  76 AC_CHECK_SIZEOF(int)
  77 AC_CHECK_SIZEOF(long)
  78 AC_CHECK_SIZEOF(long long)
  79 AC_CHECK_SIZEOF(void *)
  80
  81 dnl Switch to C++ language mode for the following libraries and headers.
  82 AC_LANG([C++])
  83
  84 dnl Make sure all the necessary standard headers are installed on the system.
  85 GINAC_STD_CXX_HEADERS
  86
  87 dnl Check for stuff needed for building the GiNaC interactive shell (ginsh).
  88 AC_CHECK_HEADERS(unistd.h)
  89 GINAC_HAVE_RUSAGE
  90 GINAC_READLINE
  91
  92 DL_LIBS=""
  93 dnl Check for dl library (needed for GiNaC::compile).
  94 AC_CHECK_LIB(dl, dlopen,
  95         [
  96                 DL_LIBS="-ldl"
  97                 AC_DEFINE(HAVE_LIBDL, 1, [set to 1 if you have a working libdl installed.])
  98         ],
  99         GINAC_WARNING([libdl not found. GiNaC::compile will be disabled.]))
 100 AC_SUBST(DL_LIBS)
 101
 102 dnl We need to have Bruno Haible's CLN installed.
 103 dnl (pkg-config must have installed pkg.m4 at a visible place, which provides
 104 dnl this macro. CLN >= 1.1.6 must have installed cln.pc at a visible place,
 105 dnl which provides the actual dependency information.)
 106 PKG_CHECK_MODULES(CLN, cln >= 1.1.6)
 107 LIBS="$LIBS $CLN_LIBS"
 108 CPPFLAGS="$CPPFLAGS $CLN_CFLAGS"
 109
 110 dnl Check for utilities needed by the different kinds of documentation.
 111 dnl Documentation needs only be built when extending it, so never mind if it
 112 dnl cannot find those helpers:
 113 AC_PATH_PROG(DOXYGEN, doxygen, "")
 114 AM_CONDITIONAL(CONFIG_DOXYGEN, [test ! -z "$DOXYGEN"])
 115 AC_PATH_PROG(LATEX, latex, "")
 116 AC_PATH_PROG(PDFLATEX, pdflatex, "")
 117 AC_PATH_PROG(MAKEINDEX, makeindex, "")
 118 AC_PATH_PROG(DVIPS, dvips, "")
 119 AM_CONDITIONAL(CONFIG_TEX, [test ! \( -z "$LATEX" -o -z $"PDFLATEX" -o -z "$MAKEINDEX" -o -z "$DVIPS" \)])
 120 AC_PATH_PROG(FIG2DEV, fig2dev, "")
 121 AM_CONDITIONAL(CONFIG_FIG2DEV, [test ! -z "$FIG2DEV"])
 122
 123 dnl generate boilerplate code for the (new) parser.
 124 dnl Only developers need this tool.
 125 AC_PATH_PROG(AUTOGEN, autogen, "")
 126
 127 dnl Output makefiles etc.
 128 AC_CONFIG_FILES([
 129 Makefile
 130 GiNaC.spec
 131 ginac.pc
 132 ginac/Makefile
 133 ginac/version.h
 134 check/Makefile
 135 ginsh/Makefile
 136 ginsh/ginsh.1
 137 tools/Makefile
 138 tools/viewgar.1
 139 tools/ginac-excompiler
 140 doc/Makefile
 141 doc/examples/Makefile
 142 doc/tutorial/Makefile
 143 doc/reference/Makefile
 144 doc/reference/DoxyfileHTML
 145 doc/reference/DoxyfileTEX
 146 doc/reference/DoxyfilePDF
 147 doc/reference/Doxyfooter
 148 ])
 149 AC_OUTPUT
 150 dnl Display a final warning if there has been a GINAC_ERROR or a GINAC_WARNING
 151 GINAC_CHECK_ERRORS