configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl GiNaC version number
   4 m4_define([ginac_major_version], [1])
   5 m4_define([ginac_minor_version], [5])
   6 m4_define([ginac_micro_version], [1])
   7 m4_define([ginac_version], [ginac_major_version.ginac_minor_version.ginac_micro_version])
   8 m4_define([ginac_release], [ginac_major_version.ginac_minor_version])
   9
  10 dnl GiNaC library version information. It has very little to do with GiNaC
  11 dnl version number. In particular, library version is OS dependent.
  12 dnl
  13 dnl When making releases, do
  14 dnl 1. Increment ginac_lt_revision
  15 dnl 2. If any interfaces have been added, removed, or changed since the last
  16 dnl    release, increment ginac_lt_current and set ginac_lt_revision to 0.
  17 dnl 3. If any interfaces have been added since the last release, increment
  18 dnl    ginac_lt_age.
  19 dnl 4. If any interfaces have been removed since the last release, set
  20 dnl    ginac_lt_age to 0.
  21 dnl
  22 dnl Please note: the libtool naming scheme cannot guarantee that on all
  23 dnl systems, the numbering is consecutive. It only guarantees that it is
  24 dnl increasing. This doesn't matter, though: there is not incurred cost
  25 dnl for numbers that are omitted, except for shrinking the available space
  26 dnl of leftover numbers. Not something we need to worry about yet. ;-)
  27 m4_define([ginac_lt_current], [0])
  28 m4_define([ginac_lt_age], [0])
  29 m4_define([ginac_lt_revision], [1])
  30
  31 AC_INIT([GiNaC], ginac_version, [<ginac-list@ginac.de>])
  32 AC_PREREQ(2.59)
  33 AC_CONFIG_SRCDIR(ginac/basic.cpp)
  34 AC_CONFIG_AUX_DIR([config])
  35 AC_CONFIG_HEADERS([config/config.h ginac/version.h])
  36 AC_CONFIG_MACRO_DIR([m4])
  37 dnl This defines PACKAGE and VERSION.
  38 AM_INIT_AUTOMAKE([gnu 1.8 dist-bzip2])
  39
  40 dnl Process GiNaC version information
  41 AC_DEFINE([GINACLIB_MAJOR_VERSION], ginac_major_version, [Major version of GiNaC])
  42 AC_DEFINE([GINACLIB_MINOR_VERSION], ginac_minor_version, [Minor version of GiNaC])
  43 AC_DEFINE([GINACLIB_MICRO_VERSION], ginac_micro_version, [Micro version of GiNaC])
  44
  45 dnl GiNaC archive file version information.
  46 dnl
  47 dnl If properties have been added, ARCHIVE_VERSION += 1, ARCHIVE_AGE += 1.
  48 dnl If backwards compatibility has been broken, set ARCHIVE_AGE to 0.
  49 dnl
  50 dnl The version number in newly created archives will be ARCHIVE_VERSION.
  51 dnl Archives version (ARCHIVE_VERSION-ARCHIVE_AGE) thru ARCHIVE_VERSION can
  52 dnl be read by this version of the GiNaC library.
  53
  54 ARCHIVE_VERSION=3
  55 ARCHIVE_AGE=3
  56
  57 AC_SUBST(ARCHIVE_VERSION)
  58 AC_SUBST(ARCHIVE_AGE)
  59 AC_DEFINE_UNQUOTED(ARCHIVE_VERSION, $ARCHIVE_VERSION, [Current GiNaC archive file version number])
  60 AC_DEFINE_UNQUOTED(ARCHIVE_AGE, $ARCHIVE_AGE, [GiNaC archive file version age])
  61
  62 dnl libtool versioning
  63 LT_VERSION_INFO="ginac_lt_current:ginac_lt_revision:ginac_lt_age"
  64 LT_RELEASE="ginac_release"
  65
  66 AC_SUBST(LT_VERSION_INFO)
  67 AC_SUBST(LT_RELEASE)
  68
  69
  70 dnl Check for the compiler and all the utilities needed for the build.
  71 AC_PROG_CXX
  72 AC_PROG_CXXCPP
  73 AC_PROG_INSTALL
  74 AM_PROG_LIBTOOL
  75 AM_PROG_LEX
  76 AC_PROG_YACC
  77
  78
  79 dnl Switch to C++ language mode for the following libraries and headers.
  80 AC_LANG([C++])
  81
  82 dnl Make sure all the necessary standard headers are installed on the system.
  83 GINAC_STD_CXX_HEADERS
  84
  85 dnl We need to have Bruno Haible's CLN installed.
  86 dnl (pkg-config must have installed pkg.m4 at a visible place, which provides
  87 dnl this macro. CLN >= 1.1.6 must have installed cln.pc at a visible place,
  88 dnl which provides the actual dependency information.)
  89 PKG_CHECK_MODULES(CLN, cln >= 1.2.2)
  90 AC_LIB_LINKFLAGS_FROM_LIBS([CLN_RPATH], [$CLN_LIBS], [1])
  91 LIBS="$LIBS $CLN_LIBS $CLN_RPATH"
  92 CPPFLAGS="$CPPFLAGS $CLN_CFLAGS"
  93 dnl Include proper rpath into pkg-config meta data, so
  94 dnl g++ `pkg-config --cflags --libs ginac`
  95 dnl actually works
  96 GINACLIB_LIBS='-L${libdir} -lginac'
  97 AC_LIB_LINKFLAGS_FROM_LIBS([GINACLIB_RPATH], [$GINACLIB_LIBS])
  98
  99 dnl Check for data types which are needed by the hash function
 100 dnl (golden_ratio_hash).
 101 AC_CHECK_TYPE(long long)
 102
 103 dnl Check for stuff needed for building the GiNaC interactive shell (ginsh).
 104 AC_CHECK_HEADERS(unistd.h)
 105 GINAC_HAVE_RUSAGE
 106 GINAC_READLINE
 107
 108 dnl Check for dl library (needed for GiNaC::compile).
 109 GINAC_EXCOMPILER
 110
 111 dnl Check for utilities needed by the different kinds of documentation.
 112 dnl Documentation needs only be built when extending it, so never mind if it
 113 dnl cannot find those helpers:
 114 AC_PATH_PROG(DOXYGEN, doxygen, "")
 115 AM_CONDITIONAL(CONFIG_DOXYGEN, [test ! -z "$DOXYGEN"])
 116 AC_PATH_PROG(LATEX, latex, "")
 117 AC_PATH_PROG(PDFLATEX, pdflatex, "")
 118 AC_PATH_PROG(MAKEINDEX, makeindex, "")
 119 AC_PATH_PROG(DVIPS, dvips, "")
 120 AM_CONDITIONAL(CONFIG_TEX, [test ! \( -z "$LATEX" -o -z $"PDFLATEX" -o -z "$MAKEINDEX" -o -z "$DVIPS" \)])
 121 AC_PATH_PROG(FIG2DEV, fig2dev, "")
 122 AM_CONDITIONAL(CONFIG_FIG2DEV, [test ! -z "$FIG2DEV"])
 123
 124 dnl generate boilerplate code for the (new) parser.
 125 dnl Only developers need this tool.
 126 AC_PATH_PROG(AUTOGEN, autogen, "")
 127
 128 dnl Output makefiles etc.
 129 AC_CONFIG_FILES([
 130 Makefile
 131 GiNaC.spec
 132 ginac.pc
 133 ginac/Makefile
 134 check/Makefile
 135 ginsh/Makefile
 136 ginsh/ginsh.1
 137 tools/Makefile
 138 tools/viewgar.1
 139 tools/ginac-excompiler
 140 doc/Makefile
 141 doc/examples/Makefile
 142 doc/tutorial/Makefile
 143 doc/reference/Makefile
 144 doc/reference/DoxyfileHTML
 145 doc/reference/DoxyfileTEX
 146 doc/reference/DoxyfilePDF
 147 doc/reference/Doxyfooter
 148 ])
 149 AC_OUTPUT
 150 dnl Display a final warning if there has been a GINAC_ERROR or a GINAC_WARNING
 151 GINAC_CHECK_ERRORS