CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.1)
   2 set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules")
   3
   4 project(GiNaC)
   5 file(STRINGS ${CMAKE_CURRENT_SOURCE_DIR}/ginac/version.h _ginac_vinfo REGEX "^#define[\t ]+GINACLIB_.*_VERSION.*")
   6 string(REGEX REPLACE "^.*GINACLIB_MAJOR_VERSION[ \t]+([0-9]+).*" "\\1" GINAC_MAJOR_VERSION "${_ginac_vinfo}")
   7 string(REGEX REPLACE "^.*GINACLIB_MINOR_VERSION[ \t]+([0-9]+).*" "\\1" GINAC_MINOR_VERSION "${_ginac_vinfo}")
   8 string(REGEX REPLACE "^.*GINACLIB_MICRO_VERSION[ \t]+([0-9]+).*" "\\1" GINAC_MICRO_VERSION "${_ginac_vinfo}")
   9 set(GINAC_VERSION "${GINAC_MAJOR_VERSION}.${GINAC_MINOR_VERSION}.${GINAC_MICRO_VERSION}")
  10
  11 # Library versioning info
  12 file(STRINGS ${CMAKE_CURRENT_SOURCE_DIR}/ginac/version.h _ginac_vinfo REGEX "^#define[\t ]+GINAC_LT_.*")
  13 string(REGEX REPLACE "^.*GINAC_LT_CURRENT[ \t]+([0-9]+).*" "\\1" ginac_lt_current "${_ginac_vinfo}")
  14 string(REGEX REPLACE "^.*GINAC_LT_AGE[ \t]+([0-9]+).*" "\\1" ginac_lt_age "${_ginac_vinfo}")
  15 string(REGEX REPLACE "^.*GINAC_LT_REVISION[ \t]+([0-9]+).*" "\\1" ginac_lt_revision "${_ginac_vinfo}")
  16 # XXX: it looks like we need to set this for every platform?
  17 math(EXPR ginaclib_soversion "${ginac_lt_current} - ${ginac_lt_age}")
  18 set(ginaclib_version ${ginaclib_soversion}.${ginac_lt_age}.${ginac_lt_revision})
  19
  20 include(GNUInstallDirs)
  21
  22 # make check
  23 enable_testing()
  24 if (NOT TARGET check)
  25         add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND})
  26 endif()
  27 if (NOT TARGET test_suite)
  28         add_custom_target(test_suite)
  29 endif()
  30 if (WIN32)
  31         if (NOT DEFINED CMAKE_RUNTIME_OUTPUT_DIRECTORY)
  32                 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/bin)
  33         endif()
  34 endif()
  35 # make info
  36 if (NOT TARGET info)
  37         add_custom_target(info ALL)
  38 endif()
  39 if (NOT TARGET html)
  40         add_custom_target(html)
  41 endif()
  42 if (NOT TARGET pdf)
  43         add_custom_target(pdf)
  44 endif()
  45
  46 set (CMAKE_CXX_STANDARD 11)
  47
  48 find_package(CLN 1.2.2 REQUIRED)
  49
  50 include(CheckIncludeFile)
  51 check_include_file("unistd.h" HAVE_UNISTD_H)
  52
  53 if (NOT DEFINED BUILD_SHARED_LIBS)
  54         if (NOT MSVC)
  55                 set(BUILD_SHARED_LIBS true)
  56         else()
  57                 set(BUILD_SHARED_LIBS false)
  58         endif()
  59 endif()
  60
  61 # Set proper rpath so tools will Just Work(TM) after make install.
  62 # Also take care to add -Wl,-rpath, stanza into the *.pc file so that
  63 #
  64 # g++ `pkg-config --cflags --libs ginac`
  65 #
  66 # will Just Work (TM), too.
  67 # Distro packagers should use -DCMAKE_INSTALL_RPATH="" to avoid
  68 # setting rpath on installed binaries.
  69
  70 # rpath for making binaries/libraries relocatable
  71 set(_ginac_rpath_reloc "$ORIGIN/../lib")
  72 set(_wl_rpath "${CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG}")
  73
  74 # rpath for the pkg-config meta-data.
  75 set(_ginaclib_rpath "${_wl_rpath}${_ginac_rpath_reloc}")
  76 list(FIND CMAKE_CXX_IMPLICIT_LINK_DIRECTORIES "${CMAKE_INSTALL_FULL_LIBDIR}" isSystemDir)
  77 if ("${isSystemDir}" STREQUAL "-1")
  78         list(APPEND _ginaclib_rpath "${_wl_rpath}\${libdir}")
  79 endif()
  80 set(GINACLIB_RPATH)
  81 if (NOT CMAKE_SKIP_RPATH)
  82         if (_wl_rpath)
  83                 set(GINACLIB_RPATH "${_ginaclib_rpath}")
  84         endif()
  85 endif()
  86
  87 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/ginac.pc.cmake ${CMAKE_CURRENT_BINARY_DIR}/ginac.pc @ONLY)
  88 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/ginac.pc DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
  89
  90 # rpath for libginac.so itself, ginsh, and friends
  91 set(_ginac_rpath ${_ginac_rpath_reloc})
  92 foreach(_d ${CLN_LIBRARY_DIRS} ${CMAKE_INSTALL_FULL_LIBDIR})
  93         list(FIND CMAKE_CXX_IMPLICIT_LINK_DIRECTORIES "${_d}" isSystemDir)
  94         if ("${isSystemDir}" STREQUAL "-1")
  95                 list(APPEND _ginac_rpath "${_d}")
  96         endif()
  97 endforeach()
  98 list(REMOVE_DUPLICATES _ginac_rpath)
  99 string(REPLACE ";" ":" ginac_rpath "${_ginac_rpath}")
 100
 101 if (NOT DEFINED CMAKE_INSTALL_RPATH_USE_LINK_RPATH)
 102         set(CMAKE_INSTALL_RPATH_USE_LINK_RPATH TRUE)
 103 endif()
 104 if (NOT DEFINED CMAKE_INSTALL_RPATH)
 105         set(CMAKE_INSTALL_RPATH ${ginac_rpath})
 106 endif()
 107 if (APPLE AND NOT DEFINED CMAKE_INSTALL_NAME_DIR)
 108         set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_FULL_LIBDIR})
 109 endif()
 110
 111 list(FIND CMAKE_CXX_IMPLICIT_LINK_DIRECTORIES "${CMAKE_INSTALL_FULL_LIBDIR}" isSystemDir)
 112 if ("${isSystemDir}" STREQUAL "-1")
 113         string(REPLACE ":" ";" _install_rpath "${CMAKE_INSTALL_RPATH}")
 114         list(FIND _install_rpath "${CMAKE_INSTALL_FULL_LIBDIR}" _is_rpath_consistent)
 115         if ("${_is_rpath_consistent}" STREQUAL "-1")
 116                 message(WARNING "the libginac.so library will be installed into "
 117                         "a non-standard directory (${CMAKE_INSTALL_FULL_LIBDIR}), "
 118                                 "however, the rpath (${_install_rpath}) "
 119                                 "does not contain that directory. Most likely "
 120                                 "things won't work without extra configuration "
 121                                 "(tweaking LD_LIBRARY_PATH, /etc/ld.so.conf, etc).")
 122         endif()
 123 endif()
 124
 125 include(CMakePackageConfigHelpers)
 126 write_basic_package_version_file(
 127         ${CMAKE_CURRENT_BINARY_DIR}/ginac-config-version.cmake
 128         VERSION ${GINAC_VERSION}
 129         COMPATIBILITY AnyNewerVersion
 130 )
 131
 132 configure_package_config_file(${CMAKE_CURRENT_LIST_DIR}/cmake/ginac-config.cmake.in
 133         ${CMAKE_CURRENT_BINARY_DIR}/ginac-config.cmake
 134         INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/ginac
 135 )
 136
 137 install(FILES
 138         ${CMAKE_CURRENT_BINARY_DIR}/ginac-config.cmake
 139         ${CMAKE_CURRENT_BINARY_DIR}/ginac-config-version.cmake
 140         DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/ginac
 141 )
 142
 143 include(FindFLEX)
 144 include(FindBISON)
 145 find_package(BISON)
 146 find_package(FLEX)
 147 find_package(Readline)
 148 if (READLINE_FOUND)
 149         set(HAVE_LIBREADLINE 1)
 150         set(HAVE_READLINE_READLINE_H 1)
 151         set(HAVE_READLINE_HISTORY_H 1)
 152 endif()
 153
 154 find_package(LibDL)
 155 if (LIBDL_FOUND)
 156         set(HAVE_LIBDL 1)
 157 endif()
 158
 159 find_program(MAKEINFO makeinfo)
 160 find_program(FIG2DEV fig2dev)
 161 find_program(PYTHON python)
 162 if (NOT PYTHON)
 163         find_program(PYTHON python3)
 164 endif()
 165 if (NOT PYTHON)
 166         message(FATAL_ERROR "Python version 3 or 2 is required")
 167 endif()
 168
 169
 170 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/config.cmake.in ${CMAKE_CURRENT_BINARY_DIR}/config.h)
 171
 172 if (NOT LIBEXECDIR)
 173         set (LIBEXECDIR "${CMAKE_INSTALL_PREFIX}/libexec")
 174 endif()
 175
 176 add_subdirectory(ginac)
 177 add_subdirectory(tools)
 178 add_subdirectory(check)
 179 if (BISON_FOUND AND FLEX_FOUND)
 180         add_subdirectory(ginsh)
 181 endif()
 182 if (MAKEINFO)
 183         add_subdirectory(doc)
 184 endif()
 185