ginsh/ginsh_parser.yy

   1 /** @file ginsh_parser.yy
   2  *
   3  *  Input grammar definition for ginsh.
   4  *  This file must be processed with yacc/bison. */
   5
   6 /*
   7  *  GiNaC Copyright (C) 1999-2008 Johannes Gutenberg University Mainz, Germany
   8  *
   9  *  This program is free software; you can redistribute it and/or modify
  10  *  it under the terms of the GNU General Public License as published by
  11  *  the Free Software Foundation; either version 2 of the License, or
  12  *  (at your option) any later version.
  13  *
  14  *  This program is distributed in the hope that it will be useful,
  15  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  *  GNU General Public License for more details.
  18  *
  19  *  You should have received a copy of the GNU General Public License
  20  *  along with this program; if not, write to the Free Software
  21  *  Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA
  22  */
  23
  24
  25 /*
  26  *  Definitions
  27  */
  28
  29 %{
  30 #include "config.h"
  31 #ifdef HAVE_RUSAGE
  32 #include <sys/resource.h>
  33 #else
  34 #include <ctime>
  35 #endif
  36
  37 #if HAVE_UNISTD_H
  38 #include <sys/types.h>
  39 #include <unistd.h>
  40 #endif
  41
  42 #include <stdexcept>
  43
  44 #include "ginsh.h"
  45
  46 #define YYERROR_VERBOSE 1
  47
  48 #ifdef HAVE_LIBREADLINE
  49 // Original readline settings
  50 static int orig_completion_append_character;
  51 static const char *orig_basic_word_break_characters;
  52
  53 #if (RL_VERSION_MAJOR >= 5)
  54 #define GINAC_RL_COMPLETER_CAST(a) const_cast<char *>((a))
  55 #else
  56 #define GINAC_RL_COMPLETER_CAST(a) (a)
  57 #endif
  58 #endif // HAVE_LIBREADLINE
  59
  60 // Expression stack for %, %% and %%%
  61 static void push(const ex &e);
  62 static ex exstack[3];
  63
  64 // Start and end time for the time() function
  65 #ifdef HAVE_RUSAGE
  66 static struct rusage start_time, end_time;
  67 #define START_TIMER getrusage(RUSAGE_SELF, &start_time);
  68 #define STOP_TIMER getrusage(RUSAGE_SELF, &end_time);
  69 #define PRINT_TIME_USED cout << \
  70    (end_time.ru_utime.tv_sec - start_time.ru_utime.tv_sec) + \
  71        (end_time.ru_stime.tv_sec - start_time.ru_stime.tv_sec) + \
  72        double(end_time.ru_utime.tv_usec - start_time.ru_utime.tv_usec) / 1e6 + \
  73        double(end_time.ru_stime.tv_usec - start_time.ru_stime.tv_usec) / 1e6 \
  74                        << 's' << endl;
  75 #else
  76 static std::clock_t start_time, end_time;
  77 #define START_TIMER start_time = std::clock();
  78 #define STOP_TIMER end_time = std::clock();
  79 #define PRINT_TIME_USED \
  80   cout << double(end_time - start_time)/CLOCKS_PER_SEC << 's' << endl;
  81 #endif
  82
  83 // Table of functions (a multimap, because one function may appear with different
  84 // numbers of parameters)
  85 typedef ex (*fcnp)(const exprseq &e);
  86 typedef ex (*fcnp2)(const exprseq &e, int serial);
  87
  88 struct fcn_desc {
  89         fcn_desc() : p(NULL), num_params(0), is_ginac(false), serial(0) {}
  90         fcn_desc(fcnp func, int num) : p(func), num_params(num), is_ginac(false), serial(0) {}
  91         fcn_desc(fcnp2 func, int num, int ser) : p((fcnp)func), num_params(num), is_ginac(true), serial(ser) {}
  92
  93         fcnp p;         // Pointer to function
  94         int num_params; // Number of parameters (0 = arbitrary)
  95         bool is_ginac;  // Flag: function is GiNaC function
  96         int serial;     // GiNaC function serial number (if is_ginac == true)
  97 };
  98
  99 typedef multimap<string, fcn_desc> fcn_tab;
 100 static fcn_tab fcns;
 101
 102 static fcn_tab::const_iterator find_function(const ex &sym, int req_params);
 103
 104 // Table to map help topics to help strings
 105 typedef multimap<string, string> help_tab;
 106 static help_tab help;
 107
 108 static void insert_fcn_help(const char *name, const char *str);
 109 static void print_help(const string &topic);
 110 static void print_help_topics(void);
 111 %}
 112
 113 /* Tokens (T_LITERAL means a literal value returned by the parser, but not
 114    of class numeric or symbol (e.g. a constant or the FAIL object)) */
 115 %token T_NUMBER T_SYMBOL T_LITERAL T_DIGITS T_QUOTE T_QUOTE2 T_QUOTE3
 116 %token T_EQUAL T_NOTEQ T_LESSEQ T_GREATEREQ
 117
 118 %token T_QUIT T_WARRANTY T_PRINT T_IPRINT T_PRINTLATEX T_PRINTCSRC T_TIME
 119 %token T_XYZZY T_INVENTORY T_LOOK T_SCORE T_COMPLEX_SYMBOLS T_REAL_SYMBOLS
 120
 121 /* Operator precedence and associativity */
 122 %right '='
 123 %left T_EQUAL T_NOTEQ
 124 %left '<' '>' T_LESSEQ T_GREATEREQ
 125 %left '+' '-'
 126 %left '*' '/'
 127 %nonassoc NEG
 128 %right '^'
 129 %nonassoc '!'
 130
 131 %start input
 132
 133
 134 /*
 135  *  Grammar rules
 136  */
 137
 138 %%
 139 input   : /* empty */
 140         | input line
 141         ;
 142
 143 line    : ';'
 144         | exp ';' {
 145                 try {
 146                         cout << $1 << endl;
 147                         push($1);
 148                 } catch (exception &e) {
 149                         cerr << e.what() << endl;
 150                         YYERROR;
 151                 }
 152         }
 153         | exp ':' {
 154                 try {
 155                         push($1);
 156                 } catch (exception &e) {
 157                         std::cerr << e.what() << endl;
 158                         YYERROR;
 159                 }
 160         }
 161         | T_PRINT '(' exp ')' ';' {
 162                 try {
 163                         $3.print(print_tree(std::cout));
 164                 } catch (exception &e) {
 165                         std::cerr << e.what() << endl;
 166                         YYERROR;
 167                 }
 168         }
 169         | T_IPRINT '(' exp ')' ';' {
 170                 try {
 171                         ex e = $3;
 172                         if (!e.info(info_flags::integer))
 173                                 throw (std::invalid_argument("argument to iprint() must be an integer"));
 174                         long i = ex_to<numeric>(e).to_long();
 175                         cout << i << endl;
 176                         cout << "#o" << oct << i << endl;
 177                         cout << "#x" << hex << i << dec << endl;
 178                 } catch (exception &e) {
 179                         cerr << e.what() << endl;
 180                         YYERROR;
 181                 }
 182         }
 183         | T_PRINTLATEX '(' exp ')' ';' {
 184                 try {
 185                         $3.print(print_latex(std::cout)); cout << endl;
 186                 } catch (exception &e) {
 187                         std::cerr << e.what() << endl;
 188                         YYERROR;
 189                 }
 190         }
 191         | T_PRINTCSRC '(' exp ')' ';' {
 192                 try {
 193                         $3.print(print_csrc_double(std::cout)); cout << endl;
 194                 } catch (exception &e) {
 195                         std::cerr << e.what() << endl;
 196                         YYERROR;
 197                 }
 198         }
 199         | '?' T_SYMBOL          {print_help(ex_to<symbol>($2).get_name());}
 200         | '?' T_TIME            {print_help("time");}
 201         | '?' T_PRINT           {print_help("print");}
 202         | '?' T_IPRINT          {print_help("iprint");}
 203         | '?' T_PRINTLATEX      {print_help("print_latex");}
 204         | '?' T_PRINTCSRC       {print_help("print_csrc");}
 205         | '?' '?'               {print_help_topics();}
 206         | T_QUIT                {YYACCEPT;}
 207         | T_WARRANTY {
 208                 cout << "This program is free software; you can redistribute it and/or modify it under\n";
 209                 cout << "the terms of the GNU General Public License as published by the Free Software\n";
 210                 cout << "Foundation; either version 2 of the License, or (at your option) any later\n";
 211                 cout << "version.\n";
 212                 cout << "This program is distributed in the hope that it will be useful, but WITHOUT\n";
 213                 cout << "ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS\n";
 214                 cout << "FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more\n";
 215                 cout << "details.\n";
 216                 cout << "You should have received a copy of the GNU General Public License along with\n";
 217                 cout << "this program. If not, write to the Free Software Foundation, 675 Mass Ave,\n";
 218                 cout << "Cambridge, MA 02139, USA.\n";
 219         }
 220         | T_XYZZY               {cout << "Nothing happens.\n";}
 221         | T_INVENTORY           {cout << "You're not carrying anything.\n";}
 222         | T_LOOK                {cout << "You're in a twisty little maze of passages, all alike.\n";}
 223         | T_SCORE {
 224                 cout << "If you were to quit now, you would score ";
 225                 cout << (syms.size() > 350 ? 350 : syms.size());
 226                 cout << " out of a possible 350.\n";
 227         }
 228         | T_REAL_SYMBOLS { symboltype = domain::real; }
 229         | T_COMPLEX_SYMBOLS { symboltype = domain::complex; }
 230         | T_TIME { START_TIMER } '(' exp ')' { STOP_TIMER PRINT_TIME_USED }
 231         | error ';'             {yyclearin; yyerrok;}
 232         | error ':'             {yyclearin; yyerrok;}
 233         ;
 234
 235 exp     : T_NUMBER              {$$ = $1;}
 236         | T_SYMBOL              {$$ = $1.eval();}
 237         | '\'' T_SYMBOL '\''    {$$ = $2;}
 238         | T_LITERAL             {$$ = $1;}
 239         | T_DIGITS              {$$ = $1;}
 240         | T_QUOTE               {$$ = exstack[0];}
 241         | T_QUOTE2              {$$ = exstack[1];}
 242         | T_QUOTE3              {$$ = exstack[2];}
 243         | T_SYMBOL '(' exprseq ')' {
 244                 fcn_tab::const_iterator i = find_function($1, $3.nops());
 245                 if (i->second.is_ginac) {
 246                         $$ = ((fcnp2)(i->second.p))(ex_to<exprseq>($3), i->second.serial);
 247                 } else {
 248                         $$ = (i->second.p)(ex_to<exprseq>($3));
 249                 }
 250         }
 251         | T_DIGITS '=' T_NUMBER {$$ = $3; Digits = ex_to<numeric>($3).to_int();}
 252         | T_SYMBOL '=' exp      {$$ = $3; const_cast<symbol&>(ex_to<symbol>($1)).assign($3);}
 253         | exp T_EQUAL exp       {$$ = $1 == $3;}
 254         | exp T_NOTEQ exp       {$$ = $1 != $3;}
 255         | exp '<' exp           {$$ = $1 < $3;}
 256         | exp T_LESSEQ exp      {$$ = $1 <= $3;}
 257         | exp '>' exp           {$$ = $1 > $3;}
 258         | exp T_GREATEREQ exp   {$$ = $1 >= $3;}
 259         | exp '+' exp           {$$ = $1 + $3;}
 260         | exp '-' exp           {$$ = $1 - $3;}
 261         | exp '*' exp           {$$ = $1 * $3;}
 262         | exp '/' exp           {$$ = $1 / $3;}
 263         | '-' exp %prec NEG     {$$ = -$2;}
 264         | '+' exp %prec NEG     {$$ = $2;}
 265         | exp '^' exp           {$$ = power($1, $3);}
 266         | exp '!'               {$$ = factorial($1);}
 267         | '(' exp ')'           {$$ = $2;}
 268         | '{' list_or_empty '}' {$$ = $2;}
 269         | '[' matrix ']'        {$$ = lst_to_matrix(ex_to<lst>($2));}
 270         ;
 271
 272 exprseq : exp                   {$$ = exprseq($1);}
 273         | exprseq ',' exp       {exprseq es(ex_to<exprseq>($1)); $$ = es.append($3);}
 274         ;
 275
 276 list_or_empty: /* empty */      {$$ = *new lst;}
 277         | list                  {$$ = $1;}
 278         ;
 279
 280 list    : exp                   {$$ = lst($1);}
 281         | list ',' exp          {lst l(ex_to<lst>($1)); $$ = l.append($3);}
 282         ;
 283
 284 matrix  : '[' row ']'           {$$ = lst($2);}
 285         | matrix ',' '[' row ']' {lst l(ex_to<lst>($1)); $$ = l.append($4);}
 286         ;
 287
 288 row     : exp                   {$$ = lst($1);}
 289         | row ',' exp           {lst l(ex_to<lst>($1)); $$ = l.append($3);}
 290         ;
 291
 292
 293 /*
 294  *  Routines
 295  */
 296
 297 %%
 298 // Error print routine
 299 int yyerror(char *s)
 300 {
 301         cerr << s << " at " << yytext << endl;
 302         return 0;
 303 }
 304
 305 // Push expression "e" onto the expression stack (for ", "" and """)
 306 static void push(const ex &e)
 307 {
 308         exstack[2] = exstack[1];
 309         exstack[1] = exstack[0];
 310         exstack[0] = e;
 311 }
 312
 313
 314 /*
 315  *  Built-in functions
 316  */
 317
 318 static ex f_collect(const exprseq &e) {return e[0].collect(e[1]);}
 319 static ex f_collect_distributed(const exprseq &e) {return e[0].collect(e[1], true);}
 320 static ex f_collect_common_factors(const exprseq &e) {return collect_common_factors(e[0]);}
 321 static ex f_convert_H_to_Li(const exprseq &e) {return convert_H_to_Li(e[0], e[1]);}
 322 static ex f_degree(const exprseq &e) {return e[0].degree(e[1]);}
 323 static ex f_denom(const exprseq &e) {return e[0].denom();}
 324 static ex f_eval1(const exprseq &e) {return e[0].eval();}
 325 static ex f_evalf1(const exprseq &e) {return e[0].evalf();}
 326 static ex f_evalm(const exprseq &e) {return e[0].evalm();}
 327 static ex f_eval_integ(const exprseq &e) {return e[0].eval_integ();}
 328 static ex f_expand(const exprseq &e) {return e[0].expand();}
 329 static ex f_gcd(const exprseq &e) {return gcd(e[0], e[1]);}
 330 static ex f_has(const exprseq &e) {return e[0].has(e[1]) ? ex(1) : ex(0);}
 331 static ex f_lcm(const exprseq &e) {return lcm(e[0], e[1]);}
 332 static ex f_lcoeff(const exprseq &e) {return e[0].lcoeff(e[1]);}
 333 static ex f_ldegree(const exprseq &e) {return e[0].ldegree(e[1]);}
 334 static ex f_lsolve(const exprseq &e) {return lsolve(e[0], e[1]);}
 335 static ex f_nops(const exprseq &e) {return e[0].nops();}
 336 static ex f_normal1(const exprseq &e) {return e[0].normal();}
 337 static ex f_numer(const exprseq &e) {return e[0].numer();}
 338 static ex f_numer_denom(const exprseq &e) {return e[0].numer_denom();}
 339 static ex f_pow(const exprseq &e) {return pow(e[0], e[1]);}
 340 static ex f_sqrt(const exprseq &e) {return sqrt(e[0]);}
 341 static ex f_sqrfree1(const exprseq &e) {return sqrfree(e[0]);}
 342 static ex f_subs2(const exprseq &e) {return e[0].subs(e[1]);}
 343 static ex f_tcoeff(const exprseq &e) {return e[0].tcoeff(e[1]);}
 344
 345 #define CHECK_ARG(num, type, fcn) if (!is_a<type>(e[num])) throw(std::invalid_argument("argument " #num " to " #fcn "() must be a " #type))
 346
 347 static ex f_charpoly(const exprseq &e)
 348 {
 349         CHECK_ARG(0, matrix, charpoly);
 350         return ex_to<matrix>(e[0]).charpoly(e[1]);
 351 }
 352
 353 static ex f_coeff(const exprseq &e)
 354 {
 355         CHECK_ARG(2, numeric, coeff);
 356         return e[0].coeff(e[1], ex_to<numeric>(e[2]).to_int());
 357 }
 358
 359 static ex f_content(const exprseq &e)
 360 {
 361         return e[0].content(e[1]);
 362 }
 363
 364 static ex f_decomp_rational(const exprseq &e)
 365 {
 366         return decomp_rational(e[0], e[1]);
 367 }
 368
 369 static ex f_determinant(const exprseq &e)
 370 {
 371         CHECK_ARG(0, matrix, determinant);
 372         return ex_to<matrix>(e[0]).determinant();
 373 }
 374
 375 static ex f_diag(const exprseq &e)
 376 {
 377         size_t dim = e.nops();
 378         matrix &m = *new matrix(dim, dim);
 379         for (size_t i=0; i<dim; i++)
 380                 m.set(i, i, e.op(i));
 381         return m;
 382 }
 383
 384 static ex f_diff2(const exprseq &e)
 385 {
 386         CHECK_ARG(1, symbol, diff);
 387         return e[0].diff(ex_to<symbol>(e[1]));
 388 }
 389
 390 static ex f_diff3(const exprseq &e)
 391 {
 392         CHECK_ARG(1, symbol, diff);
 393         CHECK_ARG(2, numeric, diff);
 394         return e[0].diff(ex_to<symbol>(e[1]), ex_to<numeric>(e[2]).to_int());
 395 }
 396
 397 static ex f_divide(const exprseq &e)
 398 {
 399         ex q;
 400         if (divide(e[0], e[1], q))
 401                 return q;
 402         else
 403                 return fail();
 404 }
 405
 406 static ex f_eval2(const exprseq &e)
 407 {
 408         CHECK_ARG(1, numeric, eval);
 409         return e[0].eval(ex_to<numeric>(e[1]).to_int());
 410 }
 411
 412 static ex f_evalf2(const exprseq &e)
 413 {
 414         CHECK_ARG(1, numeric, evalf);
 415         return e[0].evalf(ex_to<numeric>(e[1]).to_int());
 416 }
 417
 418 static ex f_find(const exprseq &e)
 419 {
 420         lst found;
 421         e[0].find(e[1], found);
 422         return found;
 423 }
 424
 425 static ex f_fsolve(const exprseq &e)
 426 {
 427         CHECK_ARG(1, symbol, fsolve);
 428         CHECK_ARG(2, numeric, fsolve);
 429         CHECK_ARG(3, numeric, fsolve);
 430         return fsolve(e[0], ex_to<symbol>(e[1]), ex_to<numeric>(e[2]), ex_to<numeric>(e[3]));
 431 }
 432
 433 static ex f_integer_content(const exprseq &e)
 434 {
 435         return e[0].expand().integer_content();
 436 }
 437
 438 static ex f_integral(const exprseq &e)
 439 {
 440         CHECK_ARG(0, symbol, integral);
 441         return integral(e[0], e[1], e[2], e[3]);
 442 }
 443
 444 static ex f_inverse(const exprseq &e)
 445 {
 446         CHECK_ARG(0, matrix, inverse);
 447         return ex_to<matrix>(e[0]).inverse();
 448 }
 449
 450 static ex f_is(const exprseq &e)
 451 {
 452         CHECK_ARG(0, relational, is);
 453         return (bool)ex_to<relational>(e[0]) ? ex(1) : ex(0);
 454 }
 455
 456 class apply_map_function : public map_function {
 457         ex apply;
 458 public:
 459         apply_map_function(const ex & a) : apply(a) {}
 460         virtual ~apply_map_function() {}
 461         ex operator()(const ex & e) { return apply.subs(wild() == e, true); }
 462 };
 463
 464 static ex f_map(const exprseq &e)
 465 {
 466         apply_map_function fcn(e[1]);
 467         return e[0].map(fcn);
 468 }
 469
 470 static ex f_match(const exprseq &e)
 471 {
 472         lst repl_lst;
 473         if (e[0].match(e[1], repl_lst))
 474                 return repl_lst;
 475         else
 476                 return fail();
 477 }
 478
 479 static ex f_normal2(const exprseq &e)
 480 {
 481         CHECK_ARG(1, numeric, normal);
 482         return e[0].normal(ex_to<numeric>(e[1]).to_int());
 483 }
 484
 485 static ex f_op(const exprseq &e)
 486 {
 487         CHECK_ARG(1, numeric, op);
 488         int n = ex_to<numeric>(e[1]).to_int();
 489         if (n < 0 || n >= (int)e[0].nops())
 490                 throw(std::out_of_range("second argument to op() is out of range"));
 491         return e[0].op(n);
 492 }
 493
 494 static ex f_prem(const exprseq &e)
 495 {
 496         return prem(e[0], e[1], e[2]);
 497 }
 498
 499 static ex f_primpart(const exprseq &e)
 500 {
 501         return e[0].primpart(e[1]);
 502 }
 503
 504 static ex f_quo(const exprseq &e)
 505 {
 506         return quo(e[0], e[1], e[2]);
 507 }
 508
 509 static ex f_rank(const exprseq &e)
 510 {
 511         CHECK_ARG(0, matrix, rank);
 512         return ex_to<matrix>(e[0]).rank();
 513 }
 514
 515 static ex f_rem(const exprseq &e)
 516 {
 517         return rem(e[0], e[1], e[2]);
 518 }
 519
 520 static ex f_resultant(const exprseq &e)
 521 {
 522         CHECK_ARG(2, symbol, resultant);
 523         return resultant(e[0], e[1], ex_to<symbol>(e[2]));
 524 }
 525
 526 static ex f_series(const exprseq &e)
 527 {
 528         CHECK_ARG(2, numeric, series);
 529         return e[0].series(e[1], ex_to<numeric>(e[2]).to_int());
 530 }
 531
 532 static ex f_sprem(const exprseq &e)
 533 {
 534         return sprem(e[0], e[1], e[2]);
 535 }
 536
 537 static ex f_sqrfree2(const exprseq &e)
 538 {
 539         CHECK_ARG(1, lst, sqrfree);
 540         return sqrfree(e[0], ex_to<lst>(e[1]));
 541 }
 542
 543 static ex f_subs3(const exprseq &e)
 544 {
 545         CHECK_ARG(1, lst, subs);
 546         CHECK_ARG(2, lst, subs);
 547         return e[0].subs(ex_to<lst>(e[1]), ex_to<lst>(e[2]));
 548 }
 549
 550 static ex f_trace(const exprseq &e)
 551 {
 552         CHECK_ARG(0, matrix, trace);
 553         return ex_to<matrix>(e[0]).trace();
 554 }
 555
 556 static ex f_transpose(const exprseq &e)
 557 {
 558         CHECK_ARG(0, matrix, transpose);
 559         return ex_to<matrix>(e[0]).transpose();
 560 }
 561
 562 static ex f_unassign(const exprseq &e)
 563 {
 564         CHECK_ARG(0, symbol, unassign);
 565         const_cast<symbol&>(ex_to<symbol>(e[0])).unassign();
 566         return e[0];
 567 }
 568
 569 static ex f_unit(const exprseq &e)
 570 {
 571         return e[0].unit(e[1]);
 572 }
 573
 574 static ex f_dummy(const exprseq &e)
 575 {
 576         throw(std::logic_error("dummy function called (shouldn't happen)"));
 577 }
 578
 579 // Tables for initializing the "fcns" map and the function help topics
 580 struct fcn_init {
 581         const char *name;
 582         fcnp p;
 583         int num_params;
 584 };
 585
 586 static const fcn_init builtin_fcns[] = {
 587         {"charpoly", f_charpoly, 2},
 588         {"coeff", f_coeff, 3},
 589         {"collect", f_collect, 2},
 590         {"collect_common_factors", f_collect_common_factors, 1},
 591         {"collect_distributed", f_collect_distributed, 2},
 592         {"content", f_content, 2},
 593         {"convert_H_to_Li", f_convert_H_to_Li, 2},
 594         {"decomp_rational", f_decomp_rational, 2},
 595         {"degree", f_degree, 2},
 596         {"denom", f_denom, 1},
 597         {"determinant", f_determinant, 1},
 598         {"diag", f_diag, 0},
 599         {"diff", f_diff2, 2},
 600         {"diff", f_diff3, 3},
 601         {"divide", f_divide, 2},
 602         {"eval", f_eval1, 1},
 603         {"eval", f_eval2, 2},
 604         {"evalf", f_evalf1, 1},
 605         {"evalf", f_evalf2, 2},
 606         {"evalm", f_evalm, 1},
 607         {"eval_integ", f_eval_integ, 1},
 608         {"expand", f_expand, 1},
 609         {"find", f_find, 2},
 610         {"fsolve", f_fsolve, 4},
 611         {"gcd", f_gcd, 2},
 612         {"has", f_has, 2},
 613         {"integer_content", f_integer_content, 1},
 614         {"integral", f_integral, 4},
 615         {"inverse", f_inverse, 1},
 616         {"iprint", f_dummy, 0},      // for Tab-completion
 617         {"is", f_is, 1},
 618         {"lcm", f_lcm, 2},
 619         {"lcoeff", f_lcoeff, 2},
 620         {"ldegree", f_ldegree, 2},
 621         {"lsolve", f_lsolve, 2},
 622         {"map", f_map, 2},
 623         {"match", f_match, 2},
 624         {"nops", f_nops, 1},
 625         {"normal", f_normal1, 1},
 626         {"normal", f_normal2, 2},
 627         {"numer", f_numer, 1},
 628         {"numer_denom", f_numer_denom, 1},
 629         {"op", f_op, 2},
 630         {"pow", f_pow, 2},
 631         {"prem", f_prem, 3},
 632         {"primpart", f_primpart, 2},
 633         {"print", f_dummy, 0},       // for Tab-completion
 634         {"print_csrc", f_dummy, 0},  // for Tab-completion
 635         {"print_latex", f_dummy, 0}, // for Tab-completion
 636         {"quo", f_quo, 3},
 637         {"rank", f_rank, 1},
 638         {"rem", f_rem, 3},
 639         {"resultant", f_resultant, 3},
 640         {"series", f_series, 3},
 641         {"sprem", f_sprem, 3},
 642         {"sqrfree", f_sqrfree1, 1},
 643         {"sqrfree", f_sqrfree2, 2},
 644         {"sqrt", f_sqrt, 1},
 645         {"subs", f_subs2, 2},
 646         {"subs", f_subs3, 3},
 647         {"tcoeff", f_tcoeff, 2},
 648         {"time", f_dummy, 0},        // for Tab-completion
 649         {"trace", f_trace, 1},
 650         {"transpose", f_transpose, 1},
 651         {"unassign", f_unassign, 1},
 652         {"unit", f_unit, 2},
 653         {NULL, f_dummy, 0}           // End marker
 654 };
 655
 656 struct fcn_help_init {
 657         const char *name;
 658         const char *help;
 659 };
 660
 661 static const fcn_help_init builtin_help[] = {
 662         {"acos", "inverse cosine function"},
 663         {"acosh", "inverse hyperbolic cosine function"},
 664         {"asin", "inverse sine function"},
 665         {"asinh", "inverse hyperbolic sine function"},
 666         {"atan", "inverse tangent function"},
 667         {"atan2", "inverse tangent function with two arguments"},
 668         {"atanh", "inverse hyperbolic tangent function"},
 669         {"beta", "Beta function"},
 670         {"binomial", "binomial function"},
 671         {"cos", "cosine function"},
 672         {"cosh", "hyperbolic cosine function"},
 673         {"exp", "exponential function"},
 674         {"factorial", "factorial function"},
 675         {"lgamma", "natural logarithm of Gamma function"},
 676         {"tgamma", "Gamma function"},
 677         {"log", "natural logarithm"},
 678         {"psi", "psi function\npsi(x) is the digamma function, psi(n,x) the nth polygamma function"},
 679         {"sin", "sine function"},
 680         {"sinh", "hyperbolic sine function"},
 681         {"tan", "tangent function"},
 682         {"tanh", "hyperbolic tangent function"},
 683         {"zeta", "zeta function\nzeta(x) is Riemann's zeta function, zetaderiv(n,x) its nth derivative.\nIf x is a GiNaC::lst, it is a multiple zeta value\nzeta(x,s) is an alternating Euler sum"},
 684         {"Li2", "dilogarithm"},
 685         {"Li3", "trilogarithm"},
 686         {"Li", "(multiple) polylogarithm"},
 687         {"S", "Nielsen's generalized polylogarithm"},
 688         {"H", "harmonic polylogarithm"},
 689         {"Order", "order term function (for truncated power series)"},
 690         {"Derivative", "inert differential operator"},
 691         {NULL, NULL}    // End marker
 692 };
 693
 694 #include "ginsh_extensions.h"
 695
 696
 697 /*
 698  *  Add functions to ginsh
 699  */
 700
 701 // Functions from fcn_init array
 702 static void insert_fcns(const fcn_init *p)
 703 {
 704         while (p->name) {
 705                 fcns.insert(make_pair(string(p->name), fcn_desc(p->p, p->num_params)));
 706                 p++;
 707         }
 708 }
 709
 710 static ex f_ginac_function(const exprseq &es, int serial)
 711 {
 712         return function(serial, es).eval(1);
 713 }
 714
 715 // All registered GiNaC functions
 716 namespace GiNaC {
 717 void ginsh_get_ginac_functions(void)
 718 {
 719         vector<function_options>::const_iterator i = function::registered_functions().begin(), end = function::registered_functions().end();
 720         unsigned serial = 0;
 721         while (i != end) {
 722                 fcns.insert(make_pair(i->get_name(), fcn_desc(f_ginac_function, i->get_nparams(), serial)));
 723                 ++i;
 724                 serial++;
 725         }
 726 }
 727 }
 728
 729
 730 /*
 731  *  Find a function given a name and number of parameters. Throw exceptions on error.
 732  */
 733
 734 static fcn_tab::const_iterator find_function(const ex &sym, int req_params)
 735 {
 736         const string &name = ex_to<symbol>(sym).get_name();
 737         typedef fcn_tab::const_iterator I;
 738         pair<I, I> b = fcns.equal_range(name);
 739         if (b.first == b.second)
 740                 throw(std::logic_error("unknown function '" + name + "'"));
 741         else {
 742                 for (I i=b.first; i!=b.second; i++)
 743                         if ((i->second.num_params == 0) || (i->second.num_params == req_params))
 744                                 return i;
 745         }
 746         throw(std::logic_error("invalid number of arguments to " + name + "()"));
 747 }
 748
 749
 750 /*
 751  *  Insert help strings
 752  */
 753
 754 // Normal help string
 755 static void insert_help(const char *topic, const char *str)
 756 {
 757         help.insert(make_pair(string(topic), string(str)));
 758 }
 759
 760 // Help string for functions, automatically generates synopsis
 761 static void insert_fcn_help(const char *name, const char *str)
 762 {
 763         typedef fcn_tab::const_iterator I;
 764         pair<I, I> b = fcns.equal_range(name);
 765         if (b.first != b.second) {
 766                 string help_str = string(name) + "(";
 767                 for (int i=0; i<b.first->second.num_params; i++) {
 768                         if (i)
 769                                 help_str += ", ";
 770                         help_str += "expression";
 771                 }
 772                 help_str += ") - ";
 773                 help_str += str;
 774                 help.insert(make_pair(string(name), help_str));
 775         }
 776 }
 777
 778 // Help strings for functions from fcn_help_init array
 779 static void insert_help(const fcn_help_init *p)
 780 {
 781         while (p->name) {
 782                 insert_fcn_help(p->name, p->help);
 783                 p++;
 784         }
 785 }
 786
 787
 788 /*
 789  *  Print help to cout
 790  */
 791
 792 // Help for a given topic
 793 static void print_help(const string &topic)
 794 {
 795         typedef help_tab::const_iterator I;
 796         pair<I, I> b = help.equal_range(topic);
 797         if (b.first == b.second)
 798                 cout << "no help for '" << topic << "'\n";
 799         else {
 800                 for (I i=b.first; i!=b.second; i++)
 801                         cout << i->second << endl;
 802         }
 803 }
 804
 805 // List of help topics
 806 static void print_help_topics(void)
 807 {
 808         cout << "Available help topics:\n";
 809         help_tab::const_iterator i;
 810         string last_name = string("*");
 811         int num = 0;
 812         for (i=help.begin(); i!=help.end(); i++) {
 813                 // Don't print duplicates
 814                 if (i->first != last_name) {
 815                         if (num)
 816                                 cout << ", ";
 817                         num++;
 818                         cout << i->first;
 819                         last_name = i->first;
 820                 }
 821         }
 822         cout << "\nTo get help for a certain topic, type ?topic\n";
 823 }
 824
 825
 826 /*
 827  *  Function name completion functions for readline
 828  */
 829
 830 static char *fcn_generator(const char *text, int state)
 831 {
 832         static int len;                         // Length of word to complete
 833         static fcn_tab::const_iterator index;   // Iterator to function being currently considered
 834
 835         // If this is a new word to complete, initialize now
 836         if (state == 0) {
 837                 index = fcns.begin();
 838                 len = strlen(text);
 839         }
 840
 841         // Return the next function which partially matches
 842         while (index != fcns.end()) {
 843                 const char *fcn_name = index->first.c_str();
 844                 ++index;
 845                 if (strncmp(fcn_name, text, len) == 0)
 846                         return strdup(fcn_name);
 847         }
 848         return NULL;
 849 }
 850
 851 #ifdef HAVE_LIBREADLINE
 852 static char **fcn_completion(const char *text, int start, int end)
 853 {
 854         if (rl_line_buffer[0] == '!') {
 855                 // For shell commands, revert back to filename completion
 856                 rl_completion_append_character = orig_completion_append_character;
 857                 rl_basic_word_break_characters = orig_basic_word_break_characters;
 858                 rl_completer_word_break_characters = GINAC_RL_COMPLETER_CAST(rl_basic_word_break_characters);
 859                 return rl_completion_matches(text, rl_filename_completion_function);
 860         } else {
 861                 // Otherwise, complete function names
 862                 rl_completion_append_character = '(';
 863                 rl_basic_word_break_characters = " \t\n\"#$%&'()*+,-./:;<=>?@[\\]^`{|}~";
 864                 rl_completer_word_break_characters = GINAC_RL_COMPLETER_CAST(rl_basic_word_break_characters);
 865                 return rl_completion_matches(text, fcn_generator);
 866         }
 867 }
 868 #endif // HAVE_LIBREADLINE
 869
 870 static void ginsh_readline_init(char* name)
 871 {
 872 #ifdef HAVE_LIBREADLINE
 873         // Init readline completer
 874         rl_readline_name = name;
 875         rl_attempted_completion_function = fcn_completion;
 876         orig_completion_append_character = rl_completion_append_character;
 877         orig_basic_word_break_characters = rl_basic_word_break_characters;
 878 #endif // HAVE_LIBREADLINE
 879 }
 880
 881 void greeting(void)
 882 {
 883     cout << "ginsh - GiNaC Interactive Shell (" << PACKAGE << " V" << VERSION << ")" << endl;
 884     cout << "  __,  _______  Copyright (C) 1999-2008 Johannes Gutenberg University Mainz,\n"
 885          << " (__) *       | Germany.  This is free software with ABSOLUTELY NO WARRANTY.\n"
 886          << "  ._) i N a C | You are welcome to redistribute it under certain conditions.\n"
 887          << "<-------------' For details type `warranty;'.\n" << endl;
 888     cout << "Type ?? for a list of help topics." << endl;
 889 }
 890
 891 /*
 892  *  Main program
 893  */
 894
 895 int main(int argc, char **argv)
 896 {
 897         // Print banner in interactive mode
 898         if (isatty(0))
 899                 greeting();
 900
 901         // Init function table
 902         insert_fcns(builtin_fcns);
 903         insert_fcns(extended_fcns);
 904         ginsh_get_ginac_functions();
 905
 906         // Init help for operators (automatically generated from man page)
 907         insert_help("operators", "Operators in falling order of precedence:");
 908 #include "ginsh_op_help.h"
 909
 910         // Init help for built-in functions (automatically generated from man page)
 911 #include "ginsh_fcn_help.h"
 912
 913         // Help for GiNaC functions is added manually
 914         insert_help(builtin_help);
 915         insert_help(extended_help);
 916
 917         // Help for other keywords
 918         insert_help("print", "print(expression) - dumps the internal structure of the given expression (for debugging)");
 919         insert_help("iprint", "iprint(expression) - prints the given integer expression in decimal, octal, and hexadecimal bases");
 920         insert_help("print_latex", "print_latex(expression) - prints a LaTeX representation of the given expression");
 921         insert_help("print_csrc", "print_csrc(expression) - prints a C source code representation of the given expression");
 922
 923         ginsh_readline_init(argv[0]);
 924
 925         // Init input file list, open first file
 926         num_files = argc - 1;
 927         file_list = argv + 1;
 928         if (num_files) {
 929                 yyin = fopen(*file_list, "r");
 930                 if (yyin == NULL) {
 931                         cerr << "Can't open " << *file_list << endl;
 932                         exit(1);
 933                 }
 934                 num_files--;
 935                 file_list++;
 936         }
 937
 938         // Parse input, catch all remaining exceptions
 939         int result;
 940 again:  try {
 941                 result = yyparse();
 942         } catch (exception &e) {
 943                 cerr << e.what() << endl;
 944                 goto again;
 945         }
 946         return result;
 947 }